MID和FIND结合求乘积

Alan.Pan · 发表于 2022-9-8 18:33

求助，下面的三组数据中，如何利用公式提取每组数据并相乘？MID和FIND结合用的不是太熟，求大神指教！！！

数据一：L 102.0 CM / W 15.0 CM / H 19.5 CM，要求实现：102.0×15.0×19.5的乘积。
数据二：L 102.0 CM / W 115.0 CM / H 19.5 CM，要求实现：102.0×115.0×19.5的乘积。
数据三：L 102.0 CM / W 15.0 CM / H 109.5 CM，要求实现：102.0×15.0×109.5的乘积。

良良 · 发表于 2022-9-8 20:50

B1=PRODUCT(--MID(TRIM(MID(SUBSTITUTE(A1&" / ","CM / ",REPT(" ",50)),(ROW($1:$3)-1)*50+1,50)),3,99))，数组三键。

E不是拿来玩的 · 发表于 2022-9-8 21:28

=PRODUCT(FILTERXML("<a><b>"&SUBSTITUTE(MID(A1,3,LEN(A1)-5)," ","</b><b>")&"</b></a>","//b"))
三键

alan57 · 发表于 2022-9-21 12:59

=PRODUCT(LET(_a,--TEXTSPLIT(A1,CHAR(ROW(65:90)),,1),FILTER(_a,--ISERROR(_a)=0)))

复制代码

xbq · 发表于 2022-9-22 15:37

=MAP(A1:A3,LAMBDA(_A,LET(_X,IFERROR(TEXTSPLIT(_A,CHAR(ROW(65:90)),,1)*1,0),PRODUCT(FILTER(_X,_X<>0)))))

mx54865 · 发表于 2022-9-26 12:44

本帖最后由 mx54865 于 2022-9-26 12:48 编辑

=LET(_X,TEXTSPLIT(A1," "),
INDEX(_X,2)* INDEX(_X,6)* INDEX(_X,10)
)
你既然是365版本就不需要那么麻烦的嵌套公式了

大猫不吃鱼 · 发表于 2022-10-8 20:16

=PRODUCT(TRIM(MID(SUBSTITUTE(A1," ",REPT(" ",50)),{2,6,10}*50-49,50))/1)

大猫不吃鱼 · 发表于 2022-10-8 20:19

大猫不吃鱼发表于 2022-10-8 20:16
=PRODUCT(TRIM(MID(SUBSTITUTE(A1," ",REPT(" ",50)),{2,6,10}*50-49,50))/1)

=PRODUCT(MID(SUBSTITUTE(A1," ",REPT(" ",50)),{2,6,10}*50-49,50)/1)

		自动登录	找回密码
密码			免费注册

[求助] MID和FIND结合求乘积

浏览过的版块