.OutlineLevel = wdOutlineLevel3不起作用，

GONG2816 · 发表于 2021-3-4 09:00

老师好！
录制的查找替换代码，录制时设置了大纲级别，但再次运行该代码时，其他的部分都有效，唯独大纲级别的设置“  .OutlineLevel = wdOutlineLevel3”不起作用，不知道是什么原因，请老师指点
Sub 宏3()'
Selection.Find.ClearFormatting
Selection.Find.Replacement.ClearFormatting
With Selection.Find.Replacement.ParagraphFormat
      .LeftIndent = CentimetersToPoints(0.09)
      .RightIndent = CentimetersToPoints(0.18)
      .SpaceBefore = 17.5
      .SpaceBeforeAuto = False
      .SpaceAfter = 22.5
      .SpaceAfterAuto = False
      .LineSpacingRule = wdLineSpaceMultiple
      .LineSpacing = LinesToPoints(2.25)
      .Alignment = wdAlignParagraphLeft
      .FirstLineIndent = CentimetersToPoints(0.44)
      .OutlineLevel = wdOutlineLevel3
      .CharacterUnitLeftIndent = 0.5
      .CharacterUnitRightIndent = 1
      .CharacterUnitFirstLineIndent = 2.5
      .LineUnitBefore = 3.5
      .LineUnitAfter = 4.5
      .WordWrap = True
End With
With Selection.Find
      .Text = "^13一、*^13"
      .Replacement.Text = "^&"
      .Forward = True
      .Wrap = wdFindContinue
      .Format = True
      .MatchCase = False
      .MatchWholeWord = False
      .MatchByte = False
      .MatchAllWordForms = False
      .MatchSoundsLike = False
      .MatchWildcards = True
End With
Selection.Find.Execute Replace:=wdReplaceAll
End Sub

413191246se · 发表于 2021-3-4 15:26

楼主，大纲级别并不能改变标题级别，必须用“wdstyleheading3”或"标题 3"来设置它的标题级别，大纲级别才会改变；另外，自动排版是个系统工程，在排版标题之前要做一些初始化工作。

Sub 标题三()
Dim t As Table
With ActiveDocument
.Content.Find.Execute "[^13^l]", , , 1, , , , , , "^p", 2
For Each t In .Tables
With t.Range.Rows
.WrapAroundText = False
.Alignment = wdAlignRowCenter
End With
Next
.Select
End With
CommandBars.FindControl(ID:=122).Execute
CommandBars.FindControl(ID:=123).Execute
With Selection.ParagraphFormat
.CharacterUnitFirstLineIndent = 0
.FirstLineIndent = CentimetersToPoints(0)
End With
Dim i As Paragraph
For Each i In ActiveDocument.Paragraphs
With i.Range
If .Text Like "[一二三四五六七八九十]、*" Or _
.Text Like "[一二三四五六七八九十][一二三四五六七八九十]、*" Or _
.Text Like "[一二三四五六七八九十]十[一二三四五六七八九十]、*" Then
.Style = wdStyleHeading3
With .ParagraphFormat
.LeftIndent = CentimetersToPoints(0.09)
.RightIndent = CentimetersToPoints(0.18)
.SpaceBefore = 17.5
.SpaceBeforeAuto = False
.SpaceAfter = 22.5
.SpaceAfterAuto = False
.LineSpacingRule = wdLineSpaceMultiple
.LineSpacing = LinesToPoints(2.25)
.Alignment = wdAlignParagraphLeft
.FirstLineIndent = CentimetersToPoints(0.44)
' .OutlineLevel = wdOutlineLevel3
.CharacterUnitLeftIndent = 0.5
.CharacterUnitRightIndent = 1
.CharacterUnitFirstLineIndent = 2.5
.LineUnitBefore = 3.5
.LineUnitAfter = 4.5
End With
End If
End With
Next
End Sub

复制代码

GONG2816 · 发表于 2021-3-4 22:49

老师，下面两行代码没有看懂，网上也没有搜到，麻烦指导一下：
CommandBars.FindControl(ID:=122).Execute

CommandBars.FindControl(ID:=123).Execute

413191246se · 发表于 2021-3-4 23:07

122：这行代码，意思是“居中”，相当于打开文档后，全选，再按工具栏上的“居中”按钮。
123：这行代码，意思是“两端对齐”，相当于打开文档后，全选，再按工具栏上的“两端对齐”按钮。
必须选中全文或部分文字后，才能应用这两行代码。它们联合起来的功能是：删除段落首尾空格。
但在此前，必须将全文的回车符(^13，分真假回车符)和手动换行符(^11或^l)全部替换为段落标记(^p)，起到初始化段落的作用，否则有可能全文是一个段落。
这实际上还没有涉及到表格，表格必须全部循环遍历使其取消文字环绕，确定其位置，才能开始排版。
*** 楼主，我有《自动排版宏》（2020国庆珍藏版），你有时间可以下载试用一下，参考一下里面的自动排版代码是如何运作的（可打开 VBE 将光标放在代码行中按 F8 键逐条语句调试，观察运行结果）。
链接：http://club.excelhome.net/thread-1558189-1-1.html

GONG2816 · 发表于 2021-3-5 06:57

非常感谢您的耐心解答

		自动登录	找回密码
密码			免费注册