新年快乐，求助用VBA实现相同数据递增编号

anyunti

编号                                         想要实现的
N210220_156                        N210220_156
N210220_158                        N210220_158
N210220_159                        N210220_159
W210220_002                        W210220_002-1
W210220_002                        W210220_002-2
W210220_002                        W210220_002-3
W210220_002                        W210220_002-4
W210220_002                        W210220_002-5
W210220_002                        W210220_002-6
W210220_003                        W210220_003-1
W210220_003                        W210220_003-2
W210220_003                        W210220_003-3
W210220_003                        W210220_003-4

一把小刀闯天下

Option Explicit

Sub test()
  Dim arr, i, j, p, n
  arr = [a1].CurrentRegion.Offset(1).Value
  For i = 1 To UBound(arr, 1) - 1
    If arr(i, 1) <> arr(i + 1, 1) Then
      If i - p > 1 Then
        For j = p + 1 To i
          n = n + 1
          arr(j, 1) = arr(j, 1) & "-" & n
        Next
      End If
      p = i: n = 0
    End If
  Next
  [d2].Resize(UBound(arr, 1) - 1) = arr
End Sub

anyunti

一把小刀闯天下 发表于 2021-2-21 18:12
Option Explicit

Sub test()

hahah哈哈哈谢谢哦，完全能实现，侠圣大人这个能用字典实现吗？想学学

一把小刀闯天下

anyunti 发表于 2021-2-21 18:18
hahah哈哈哈谢谢哦，完全能实现，侠圣大人这个能用字典实现吗？想学学

'当数据无序时才会用字典，给你凑了一个满足一下你的好奇心

'还有什么其它的想法吗，上个思路可以继续给你敲点代码，直到你没有想法为止，，，

Option Explicit

Sub test()
  Dim arr, i, dic
  Set dic = CreateObject("scripting.dictionary")
  arr = [a1].CurrentRegion.Offset(1).Value
  For i = 1 To UBound(arr, 1) - 1
    dic(arr(i, 1)) = dic(arr(i, 1)) + 1
  Next
  For i = 1 To UBound(arr, 1) - 1
    If dic(arr(i, 1)) = 1 Then dic(arr(i, 1)) = 0
  Next
  For i = UBound(arr, 1) - 1 To 1 Step -1
    If dic.exists(arr(i, 1)) Then
      If dic(arr(i, 1)) > 0 Then
        dic(arr(i, 1)) = dic(arr(i, 1)) - 1
        arr(i, 1) = arr(i, 1) & "-" & dic(arr(i, 1)) + 1
      End If
    End If
  Next
  [d2].Resize(UBound(arr, 1) - 1) = arr
End Sub

anyunti

一把小刀闯天下 发表于 2021-2-21 18:40
'当数据无序时才会用字典，给你凑了一个满足一下你的好奇心

'还有什么其它的想法吗，上个思路可以继续 ...

谢谢谢谢，没了，脑子里就这俩想法

anyunti

anyunti 发表于 2021-2-21 20:05
谢谢谢谢，没了，脑子里就这俩想法

因为我感觉字典更容易懂，但不是很会写代码

冰叶雕翎

一把小刀闯天下 发表于 2021-2-21 18:40
'当数据无序时才会用字典，给你凑了一个满足一下你的好奇心

'还有什么其它的想法吗，上个思路可以继续 ...

老师好，我想实现的是只标注序号，不重复数据的全部标注序号为1应该怎么修改，谢谢