想用代码删除“系”，但“系统”及“体系”中的系不删除

413191246se · 发表于 2020-12-23 01:40

* 楼主，确实如你所说，代码并非完美！
* 经过试验，如果直接在替换框中键入代码，则“系系系”删除不掉；并且，随后我的 Word2019 也崩溃了。
* 这次我重新认真地用 VBA 宏重新编程，确信达到了你想要的效果；而且，用程序代码不会引起崩溃。
* 测试文本：
系字替换
发发发系统，系统，关系，体系，系统，系达到效果，地方，辅导费派系，辅导辅导辅导达到防盗，系达到效果，系达到效果，系系系。

Sub aaaa系字替换()
'体系/关系/派系//系统/系列
Dim a$, b$
a = InputBox("禁止删除的前词，如：体系/关系/派系", "请输入禁止删除的前词关键字！（直接按<确定>亦可）", "体关派")
If a = "" Then Exit Sub
a = Replace(a, "系", "")
b = InputBox("禁止删除的后词，如：系统/系列", "请输入禁止删除的后词关键字！（直接按<确定>亦可）", "统列")
If b = "" Then Exit Sub
b = Replace(b, "系", "")
With Selection
.HomeKey 6
.InsertParagraphBefore
.HomeKey 6
With .Find
.ClearFormatting
.Text = "系"
.Replacement.Text = ""
.Forward = True
.MatchWildcards = True
Do While .Execute
With .Parent
.Font.Color = wdColorRed
If .Previous Like "[!" & a & "]" And .Next Like "[!" & b & "]" Then .Delete
End With
Loop
End With
End With
ActiveDocument.Paragraphs(1).Range.Delete
End Sub

复制代码

maoecr1 · 发表于 2020-12-23 09:19

413191246se 发表于 2020-12-23 01:40
* 楼主，确实如你所说，代码并非完美！
* 经过试验，如果直接在替换框中键入代码，则“系系系”删除不掉； ...

Sub test22()

'体系/关系/派系//系统/系列
Dim a$, b$
a = "体关派"
b = "统列"
   With Selection
      .HomeKey 6
      .InsertParagraphBefore
      .HomeKey 6
      With .Find
         .ClearFormatting
         .Text = "系"
         .Replacement.Text = ""
         .Forward = True
         .MatchWildcards = True
         Do While .Execute
            With .Parent
                  If .Previous Like "[!" & a & "]" And .Next Like "[!" & b & "]" Then .Delete
            End With
         Loop
      End With
End With
ActiveDocument.Paragraphs(1).Range.Delete

End Sub
按照您的代码及我自己的使用目的，略微修改了一下，很好用，谢谢
另外，想请问一下，代码里好像是在开始插入了一个段落后来又删除了，这是为什么呢，另外HomeKey 6是啥意思啊

maoecr1 · 发表于 2020-12-23 10:09

413191246se 发表于 2020-12-23 01:40
* 楼主，确实如你所说，代码并非完美！
* 经过试验，如果直接在替换框中键入代码，则“系系系”删除不掉； ...

感激不尽，非常好用，另外，想请教一下，代码里好像有个插入段落及删除段落的操作，这是什么目的呀？.HomeKey 6是什么意思啊，百度了一下也没查到

413191246se · 发表于 2020-12-23 11:07

因为示例文档“系字替换”顶格，找到”系“字后，要判断它的前一个字符，如果没有可能会出错，所以必须插入一个字符，用的是回车符，过后要删除，这没有什么。“.HomeKey 6”相当于“.HomeKey Unit:=wdStory”，在代码运行过程中，“Unit:=wdStory”的值是 6，这是一种代码简写，意思是“将光标定位于文首”。

maoecr1 · 发表于 2020-12-24 16:03

maoecr1 发表于 2020-12-23 09:19
Sub test22()

'体系/关系/派系//系统/系列

老师，我想把文件中所有的“之”替换为“的”，但是像“其中之一”，“之中”，“之前”，“之后”等有一些词语的之不希望被替换，我稍微改了一下您的代码，但是运行不成功，您帮我看看，代码运行后“.Replacement.Text = "的"这句被标成了黄色
Sub zhi() '之的的替换
Dim b$
b = "一间前后中外用处"
   With Selection
      .HomeKey 6
      .InsertParagraphBefore
      .HomeKey 6
      With .Find
         .ClearFormatting
         .Text = "之"
         .Replacement.Text = "的"
         .Forward = True
         .MatchWildcards = True
         Do While .Execute
            With .Parent
                  If .Next Like "[!" & b & "]" Then .Replacement.Text = "的"
            End With
         Loop
      End With
End With
ActiveDocument.Paragraphs(1).Range.Delete
End Sub

413191246se · 发表于 2020-12-25 01:23

* 示例文档：（如果想有些前词如“取而代之”中的“之”不被替换，请将代码中的两行注释语句取消注释即可，就是将行首的小撇儿字符“`”删除）

之字替换
老师，我想把文件中所有的“之”替换为“的”，但是像
“其中之一”，“之中”，“之前”，“之后”等有一些
词语的之不希望被替换，我稍微改了一下您的代码，但是运行不成功，您帮我看看，代码运行后“.Replacement.Text = "的"这句被标成了黄色。
之所以如此，取而代之。
历史之最！之之之。之大，之新，之奇。

Sub zhi2() '之的替换
Dim a$, b$
a = "代" '如果“取而代之”不希望被替换的前词
b = "一间前后中外用处" '不希望被替换的后词
With Selection
.HomeKey 6
.InsertParagraphBefore
.HomeKey 6
With .Find
.ClearFormatting
.Text = "之"
.Replacement.Text = ""
.Forward = True
.MatchWildcards = True
Do While .Execute
With .Parent
If .Next Like "[!" & b & "]" Then
' If .Previous Like "[!代]" Then'取消注释/删除行前小撇儿即可
.Text = "的"
.Font.ColorIndex = wdRed
' End If'取消注释/删除行前小撇儿即可
Else
.Font.ColorIndex = wdPink
End If
.Start = .End
End With
Loop
End With
.HomeKey 6
End With
ActiveDocument.Paragraphs(1).Range.Delete
End Sub

复制代码

maoecr1 · 发表于 2020-12-25 08:54

413191246se 发表于 2020-12-25 01:23
* 示例文档：（如果想有些前词如“取而代之”中的“之”不被替换，请将代码中的两行注释语句取消注释即可， ...

老师，测试时，关闭修订模式，可以正常替换，但是一在修订模式下执行就会卡死

413191246se · 发表于 2020-12-25 15:05

修订模式我不懂。。。

		自动登录	找回密码
密码			免费注册