将多工作表中的数据汇总到“汇总表”

hhpEXCEL

我的目的是将除汇总表外的子表数据汇总到“汇总表”，在汇总时不汇总标题行。如果多列可以自行修改代码即可。
汇总代码：
Sub Hebgzb()
     '把各班成绩表中的记录合并到"成绩表"工作表中
     Dim sht As Worksheet
     Set sht = Worksheets("汇总表") '将"汇总表"工作表赋值给sht对象，在VBA中，给对象赋值，前面必须加Set关键字
     sht.Rows("2:" & sht.Rows.Count).Clear '删除(Clear)汇总表中的原有记录\\sht.rows.count表示sht工作表总共有多少行；
                                           '在VBA中，Rows表示工作表或某个区域中所有行组成的集合。Rows("2:3")表示选中工作表的第2行到第3行。
     Dim wt As Worksheet, xrow As Integer, rng As Range
     For Each wt In Worksheets  '循环处理工作簿中的每张工作表\\wt代表工作表集合中的一个工作表，随着循环变换。
         If wt.Name <> "汇总表" Then
             Set rng = sht.Range("A1048576").End(xlUp).Offset(1, 0) '表示sht工作表中数据A列下面的第一个空单元格。
                                                                    'Range("A1048576")表示工作表最下面一个单元格。
                                                                    'Range对象的End属性返回包含指定单元格的区域最尾端的单元格，
                                                                    '返回结果等同于在单元格中按【End+方向键】(上、下、左、右方向键)组合键得到的单元格。
                                                                    'Offset(1, 0)表示单元格下面一个单元格。
             xrow = wt.Range("A1").CurrentRegion.Rows.Count - 1 '表示A1单元格所在当前区域的行数减1?(CurrentRegion表示当前对象所属区域)
             wt.Range("B2").Resize(xrow, 4).Copy rng  '表示将子表中的数据复制到汇总表的空白区域。（Resize（行，列）表示调整指定区域大小）
                                                    'Range对象的Resize属性将指定的单元格区域有目的地扩大或缩小，得到一个新的单元格区域。
                                                    'Range("B2").Resize(5,4).Select表示将B2单元格扩展为一个5行4列的单元格区域。
         End If
     Next
End Sub

uniquevip

点击“合并工作表”按钮后，跳出：运行时错误1004， 方法‘Range‘作用于对象’_worksheet'进失败。
Set rng = sht.Range("A1048576").End(xlUp).Offset(1, 0)。
我是office2003,A1048576改了A65536后就行了，有什么代码能破除版本不同带来的问题吗？

f8b1987

不具备通用性，Range("A1").CurrentRegion这一句，当1:2行均为空白时，无法取得正常范围

f8b1987

uniquevip 发表于 2020-6-6 11:43
点击“合并工作表”按钮后，跳出：运行时错误1004， 方法‘Range‘作用于对象’_worksheet'进失败。
Set r ...

1. If Right(ThisWorkbook.Name, 4) = ".xls" Then
   
2.         maxrng = "A65536"
   
3. Else
   
4.         maxrng = "A1048576"
   
5. End If
   
6. Set Rng = sht.Range(maxrng).End(xlUp).Offset(1, 0)

复制代码