批量打印加页码

czjdc

在批量打印论文时，有时第一页封面或第二页目录不要加页码。我想在已有的代码中增加一个输入指定页窗口，这样所有文件都从指定页向后加页码。即文章指定页前没有页码，从指定页后加：第1页共  X页；第2页共X页的形式，其中X代表文件夹的一篇文档指定页以后的总页数，如何修改代码呢，您抽时间看看，先谢谢了.

lss001

Sub CommandButton1_Click()
    Dim x, y%, r, p, oDoc
    Application.ScreenUpdating = False
    With Application.FileDialog(msoFileDialogFilePicker)
        .Filters.Clear
        .Filters.Add "所有Word文件", "*.doc,*.docx", 1
        .AllowMultiSelect = True
        If .Show = -1 Then
            For Each oFile In .SelectedItems
                Set oDoc = Word.Documents.Open(FileName:=oFile, Visible:=False)
                x = oDoc.ComputeStatistics(wdStatisticPages)
                p = InputBox("请输入开始编码的起始页, 数字范围：1-" & x)
                If p = "" Then y = 0 Else y = p
                If y < 1 Or y > x Then
                    oDoc.Close SaveChanges:=False
                    Set oDoc = Nothing: Exit Sub
                End If
                oDoc.Activate
                For Each fs In oDoc.Sections: fs.Footers(1).Range.Delete: Next
                Selection.GoTo(wdGoToPage, wdGoToAbsolute, p). _
                Bookmarks("\page").Range.InsertBreak wdSectionBreakNextPage
                With oDoc.Sections(2).Footers(wdHeaderFooterPrimary)
                    .LinkToPrevious = False '不链接
                    .PageNumbers.RestartNumberingAtSection = True '不连续
                    .PageNumbers.StartingNumber = 1 '起始编号
                    Set r = .Range: r.Font.Name = "微软雅黑": r.Font.Size = 10
                    r.Text = "第 ": r.Collapse 0
                    oDoc.Fields.Add r, wdFieldPage, "Page"
                    Set r = .Range: r.Collapse 0
                    r.Text = " 页 / 共 ": r.Collapse 0
                    oDoc.Fields.Add r, wdFieldEmpty, "SectionPages"
                    Set r = .Range: r.Collapse 0: r.Text = " 页 "
                    .Range.Fields.Update
                    .Range.ParagraphFormat.Alignment = wdAlignParagraphCenter
                End With
                oDoc.Close SaveChanges:=True: Set oDoc = Nothing
            Next
        End If
    End With
    Application.ScreenUpdating = True
    MsgBox "文档已处理！"
End Sub