求如何选中合并单元格后的第一行

wks9527

Sub 统一设置表格格式()
Dim oTbl As Table

For Each oTbl In ActiveDocument.Tables
    'oTbl.Rows(1).Shading.BackgroundPatternColor = wdColorGray15
    oTbl.Range.Style = ActiveDocument.Styles("正文")
    oTbl.Range.ParagraphFormat.Alignment = wdAlignParagraphCenter
    oTbl.Range.Cells.VerticalAlignment = wdCellAlignVerticalCenter
    oTbl.Range.Font.Name = "宋体"
    oTbl.Range.Font.Size = 10
Next oTbl
End sub

大家谁知道第二行如何处理下，运行时提示因为有纵向合并的单元格，无法访问此集合中单独的行，求高手指教。

zmj9151

象这样的提问,不带附件,还要模拟数据,太不认真了.随口一说的事,难办

wks9527

这需要附件啊，都是投标文件，几百兆的文件，我去找个文档

wks9527

Sub 自动调整所有表格()
Dim oTbl As Table
On Error Resume Next '因为有纵向合并单元格，某些表格标题栏重复无法运行，需越过此错误，随后手动执行标题栏重复
Application.DisplayAlerts = wdAlertsNone '禁用警告提示
For Each oTbl In ActiveDocument.Tables
    oTbl.Cell(1, 1).Select
    With Selection
        .SelectRow
        .Cells.Shading.BackgroundPatternColor = wdColorGray15 '注意有合并单元格的标题栏底纹颜色要手动处理
    End With
    oTbl.Rows(1).HeadingFormat = True '标题栏重复，有合并单元格标题栏需手动处理
    oTbl.Range.Style = ActiveDocument.Styles("正文") '为了防止表格中文字有缩进，需先更改无缩进文字格式
    oTbl.AutoFitBehavior (wdAutoFitWindow) '表格宽度自动适应页面宽度
    oTbl.Range.ParagraphFormat.Alignment = wdAlignParagraphCenter '水平居中
    oTbl.Range.Cells.VerticalAlignment = wdCellAlignVerticalCenter '垂直居中
    oTbl.Range.Font.Name = "宋体"
    oTbl.Range.Font.Size = 10
Next oTbl
Application.DisplayAlerts = wdAlertsAll '恢复警告提示
End Sub
不用帮忙了， 研究了一下午，问题总算解决了

cuanju

请测试代码。
***************************************************
Sub 统一设置表格格式5()
    On Error Resume Next
    Dim oTbl As Table
    For Each oTbl In ActiveDocument.Tables
        oTbl.Rows(1).Shading.BackgroundPatternColor = wdColorGray15
        '==================================
        '**以下为表格含合并单元格的首行处理**
        oTbl.Cell(1, 1).Select
        Selection.SelectRow
        With Selection
            .Shading.BackgroundPatternColor = wdColorGray15
        End With
        '==================================
        oTbl.Range.Style = ActiveDocument.Styles("正文")
        oTbl.Range.ParagraphFormat.Alignment = wdAlignParagraphCenter
        oTbl.Range.Cells.VerticalAlignment = wdCellAlignVerticalCenter
        oTbl.Range.Font.Name = "宋体"
        oTbl.Range.Font.Size = 10
    Next oTbl
End Sub

cuanju

你好。所有word表格第一行标示底纹（如果第一行含合并单元格，则前两行标示底纹）？

wks9527

cuanju 发表于 2019-12-1 09:06
你好。所有word表格第一行标示底纹（如果第一行含合并单元格，则前两行标示底纹）？

没有这样设定，我只是百度的方法，通过一个一个查第一行的单元格数量来定位第一行，谁知道把合并单元格旁所有的单元格都给标上颜色了，word的合并单元格真是麻烦