怎么设置访问网页的延迟时间

xufc2014

要获取1000条IP地址的信息，实际只能获得几条，我估计是这个函数访问太快了，麻烦大神指导下  

= Web.Page(Web.Contents("http://ip.taobao.com/service/getIpInfo.php?ip=" & IP地址))

zpy2

有离线的ip地址库

PowerBI极客

可以加延迟，但是比较复杂，你可以看下这篇文章 https://blog.crossjoin.co.uk/201 ... ter-in-power-query/

下面这段是可以设置间隔时长和自动重试的代码
let
    Value.WaitFor = (producer as function, interval as function, optional count as number) as any =>
        let
            list = List.Generate(
                () => {0, null},
                (state) => state{0} <> null and (count = null or state{0} < count),
                (state) => if state{1} <> null
                    then {null, state{1}}
                    else {1 + state{0}, Function.InvokeAfter(() => producer(state{0}), interval(state{0}))},
                (state) => state{1})
        in
            List.Last(list),
    Web.ContentsCustomRetry = (url as text, optional options as record) => Value.WaitFor(
        (i) =>
            let
                options2 = if options = null then [] else options,
                options3 = if i=0 then options2 else options2 & [IsRetry=true],
                result = Web.Contents(url, options3 & [ManualStatusHandling={429}]),
                buffered = Binary.Buffer(result), /* avoid risk of double request */
                status = if buffered = null then 0 else Value.Metadata(result)[Response.Status],
                actualResult = if status = 429 then null else buffered
            in
                actualResult,
        (i) => #duration(0, 0, 0, i*0.1))
in
    Web.ContentsCustomRetry("http://www.bing.com")