单独保存一个sheet (复制型)

学VBA的小星星

一个工作簿, 有A,B,C,D,E等不同的sheet.
要求: 每次单独将 一个 sheet (例如sheet A) 单独导出为一个xls的格式的工作簿,
并且文件命名按照SHEET名. 注意是复制的那种单独导出,原sheet的文件还是会保留在工作簿里不变.

比如sheetA 单独导出,文件名为SHEET A.
但是工作簿里ABCDE还是都在的.

求大神给个代码或者告知那个语法句可以解决这个问题?

小马爱会计

这个简单呐

学VBA的小星星

有没有大神帮帮忙呀!!!

xiangbaoan

学VBA的小星星 发表于 2019-5-31 15:31
有没有大神帮帮忙呀!!!

Sub test()
Dim sh As Worksheet, p$, f$
Application.ScreenUpdating = False
Application.DisplayAlerts = False
p = ThisWorkbook.Path & "\"
For Each sh In Worksheets
    f = p & sh.Name & ".xlsx"
    sh.Copy
    With ActiveWorkbook
        .SaveAs f, 51
        .Close
    End With
Next
Application.DisplayAlerts = True
Application.ScreenUpdating = True
End Sub

学VBA的小星星

xiangbaoan 发表于 2019-5-31 18:58
Sub test()
Dim sh As Worksheet, p$, f$
Application.ScreenUpdating = False

大神你好,
SaveAs f, 51
这个51是个啥意思呀?没看懂,请指教

学VBA的小星星

xiangbaoan 发表于 2019-5-31 18:58
Sub test()
Dim sh As Worksheet, p$, f$
Application.ScreenUpdating = False

主要是...
不需要全部sheet都单独的列出来.
我只要将活动sheet copy出来就好了..

xiangbaoan

学VBA的小星星 发表于 2019-5-31 20:55
大神你好,
SaveAs f, 51
这个51是个啥意思呀?没看懂,请指教

SaveAs f, 51
这里等同于
SaveAs f, xlopenxmlworkbook
也就是高版本的Excel，这里属手写，省了好几个字符。

……………………
补充，两问一起回
Sub test()
Dim f$
Application.ScreenUpdating = False
Application.DisplayAlerts = False
f = ThisWorkbook.Path & "\" & ActiveSheet.Name & ".xlsx"
ActiveSheet.Copy
With ActiveWorkbook
    .SaveAs f, xlopenxmlworkbook
    .Close
End With
Application.DisplayAlerts = True
Application.ScreenUpdating = True
End Sub

学VBA的小星星

xiangbaoan 发表于 2019-5-31 21:04
SaveAs f, 51
这里等同于
SaveAs f, xlopenxmlworkbook

牛逼呀!!!谢谢啦

学VBA的小星星

xiangbaoan 发表于 2019-5-31 21:04
SaveAs f, 51
这里等同于
SaveAs f, xlopenxmlworkbook

666666!!!
非常感谢!