请各位大大帮我看看，我写代码究竟错在哪里？

琴风弦月

各位大神，如何通过VBA在同一文件夹中将所有的word文档里面的"位置"，"设备名称"，"情况"，"描述"相对应的数字，使得可以分别填写到ExcelA列、B列、C列、D列单元格中？

zhjlgaojuan

Sub FileDir()
    Dim p$, f$, k&, arr(), i%, n%, wdApp, y&
    With Application.FileDialog(msoFileDialogFolderPicker)
        If .Show Then p = .SelectedItems(1) Else Exit Sub
    End With
    If Right(p, 1) <> "\" Then p = p & "\"
    f = Dir(p & "*.docx")
    ReDim arr(1 To 4, 1 To 1000)
    Set wdApp = CreateObject("word.application")
    wdApp.Visible = False
    y = 0
    Do While f <> ""
        With wdApp.Documents.Open(p & f)
            For Each tb In .tables
                y = y + 1
                If y > UBound(arr, 2) Then ReDim Preserve arr(1 To 4, 1 To UBound(arr, 2) + 1000)
                arr(1, y) = Replace(tb.Cell(1, 2).Range.Text, Chr(7), "")
                arr(2, y) = Replace(tb.Cell(1, 4).Range.Text, Chr(7), "")
                arr(3, y) = Replace(tb.Cell(2, 2).Range.Text, Chr(7), "")
                arr(4, y) = Replace(tb.Cell(3, 2).Range.Text, Chr(7), "")
            Next
            .Close
        End With
        f = Dir
    Loop
    Sheet1.Range("A" & 2).Resize(y, 4) = WorksheetFunction.Transpose(arr)
    wdApp.Quit
End Sub
你源代码中,打开文档的时候需要使用完整路径加文件名

琴风弦月

zhjlgaojuan 发表于 2018-9-11 08:54
Sub FileDir()
    Dim p$, f$, k&, arr(), i%, n%, wdApp, y&
    With Application.FileDialog(msoFile ...

谢谢，想请问一下如何指定文档第3页才开始录取数据呢？

zhjlgaojuan

For Each tb In .tables
修改为
for  i=3 to .tables.count
set tb=.tables(i)

应该就可以了吧,没测试...

琴风弦月

zhjlgaojuan 发表于 2018-9-15 16:25
For Each tb In .tables
修改为
for  i=3 to .tables.count

这样，我也试过不行。表格会空出两行，同时，我想指定的是第三页的表格而不是第三个表格。