求大神activex按钮代码在表单控件按钮中总是表达不对的问题，身为小白请大神求助！

zhangyan8696

求助各位大神，需要导出文件中部分区域的内容，所以做了一个按钮，用activex按钮运行代码没有问题，可以直接使用，但是在表单控件按钮中使用该代码怎么改都不行，求大神帮我看一下，应该如何改才能使用表单控件按钮运行这个宏。

表单控件按钮可以在共享表格时正常使用，但是activex按钮不能在共享表格时使用，所以想转换为使用表单控件按钮运行这个宏。

代码如下
Sub 用表单控件按钮导出()
Dim Arr, wb As Workbook
Sheets("客户价格等级").Activate
Arr = Sheets("客户价格等级").Range("A1:E7").Copy
Set wb = Workbooks.Add  '新建工作簿
With wb
    .Sheets(1).Name = [A1].Value
    With .Sheets(1)
    .Range("A1:E7").PasteSpecial (xlPasteValues)
    .Range("A1:E7").PasteSpecial (xlPasteFormats)
    .Range("A1:E7").PasteSpecial Paste:=xlPasteColumnWidths
    .Range("A1:B1").Clear
    End With
    Application.CutCopyMode = False
    .SaveAs "D:\测试\" & [B1].Value & ".xlsx"
    .Close False
End With
End Sub

zhangyan8696

顶！！！！！！！！！！！

anzequ

Sub 用表单控件按钮导出()
Dim Arr, wb As Workbook
Sheets("客户价格等级").Activate
wname = [a1]
Arr = Sheets("客户价格等级").Range("A1:E7").Copy
Set wb = Workbooks.Add  '新建工作簿
With wb
    wb.Sheets(1).Name = wname
    With .Sheets(1)
    .Range("A1:E7").PasteSpecial (xlPasteValues)
    .Range("A1:E7").PasteSpecial (xlPasteFormats)
    .Range("A1:E7").PasteSpecial Paste:=xlPasteColumnWidths
    .Range("A1:B1").Clear
    End With
    Application.CutCopyMode = False
    .SaveAs "D:\测试\" & [B1].Value & ".xlsx"
    .Close False
End With
End Sub

帮你改了一下，你试试

江南月

个人理解,ActiveX控件默认其所在表格为激活状态,故对其所在表格的单元格可以用方括号([])直接引用,表单控件依靠指定宏来运行,宏过程当中,添加工作簿时,激活状态或者说焦点自然转移到新增工作簿上,这时候如果仍然用中括号引用原来工作簿的单元格肯定会出现下标越界之类的报错,所以引用单元格的形式必须要完整,避免出现代码太长的情况,可以在新增工作簿前定义变量并将相关单元格的内容赋值给变量备用即可,以下是借鉴楼上思路修改后的代码
Sub 用表单控件按钮导出()
Dim Arr, wb As Workbook, shtname, wbname
Sheets("客户价格等级").Activate
shtname = [a1]
wbname = [b1]
Arr = Sheets("客户价格等级").Range("A1:E7").Copy

Set wb = Workbooks.Add  '新建工作簿
With wb
    wb.Sheets(1).Name = shtname
    With .Sheets(1)

    .Range("A1:E7").PasteSpecial (xlPasteValues)
    .Range("A1:E7").PasteSpecial (xlPasteFormats)
    .Range("A1:E7").PasteSpecial Paste:=xlPasteColumnWidths
    .Range("A1:B1").Clear
    End With
    Application.CutCopyMode = False
    .SaveAs "D:\测试\" & wbname & ".xlsx"
    .Close False
End With
End Sub

zhangyan8696

江南月 发表于 2018-7-29 08:30
个人理解,ActiveX控件默认其所在表格为激活状态,故对其所在表格的单元格可以用方括号([])直接引用,表单控件 ...

谢谢大神，测试成功！！！

zhangyan8696

anzequ 发表于 2018-7-28 21:09
Sub 用表单控件按钮导出()
Dim Arr, wb As Workbook
Sheets("客户价格等级").Activate

谢谢！！！！！！！