怎么给符合条件的单元格添加颜色呢？

书中苹果

以下是我的代码，目的是先检查行和列项目符合条件与否；然后在符合条件的前提下对比数据区域的单元内数据是否相等，相等就添加颜色，不相等就插入批注，标注两者之差。怎么往符合条件的单元格里添加颜色和插入备注，试了很多方法都不行，整了好几天了，都没有办法搞定这个事情，求助呀！
Sub comparision()

Dim table1, table2 As Workbook
Dim sht1, sht2 As Worksheet
Dim i&, j&, d, e, Arr, Brr, x$, y, z, Crr()
Application.ScreenUpdating = False
Set table1 = ThisWorkbook
Set table2 = Workbooks.Open(table1.Path & "\检查源表.xls")
Set sht1 = table1.Worksheets("检查表")
Set sht2 = table2.Worksheets("检查源表")

Set e = CreateObject("Scripting.Dictionary")
Arr = sht1.[a1].CurrentRegion
Brr = sht2.[a1].CurrentRegion

For i = 2 To UBound(Brr)
x = Brr(i, 9)
For j = 14 To UBound(Brr, 2)
   y = Brr(1, j)
   If e.exists(x) = False Then Set e(x) = CreateObject("Scripting.Dictionary")
     e(x)(y) = Brr(i, j)
Next
Next

table2.Close False
For i = 2 To UBound(Arr)
    x = Arr(i, 9)
  If e.exists(x) Then
    For j = 14 To (UBound(Arr, 2))
      y = Arr(1, j)
      If e(x).exists(y) Then
        z = Arr(i, j)
        If e(x)(y) = z Then
          '这里向数据区域单元格添加颜色，表示相同项
        Else
          ''这里向数据区域单元格插入备注，表示不同项目
        End If
      End If
    Next j
  End If
Next i

Application.ScreenUpdating = True   
End Sub

蓝桥玄霜

表1的第9列都是空值？

书中苹果

蓝桥老师，是的，有些日期都是空值。

书中苹果

蓝桥玄霜 发表于 2018-7-16 10:01
表1的第9列都是空值？

谢谢蓝桥老师的提醒，我把I和J都设置了从2开始起步，在本地窗口测试可以正确取到数据了

书中苹果

今天终于找到另外一种思路，使用cells的方法才能比较好的完成我的想法。附上代码以便其他人解决：
Attribute VB_Name = "模块2"
Sub comparision()

Dim table1, table2 As Workbook
Dim sht1, sht2 As Worksheet
Dim i&, j&, d, e, Arr, Brr, x$, y, z, Crr()

Set table1 = ThisWorkbook
Set table2 = Workbooks.Open(table1.Path & "\检查源表.xls")
Set sht1 = table1.Worksheets("检查表")
Set sht2 = table2.Worksheets("检查源表")

Application.ScreenUpdating = False
Set e = CreateObject("Scripting.Dictionary")
Arr = sht1.[a1].CurrentRegion
Brr = sht2.[a1].CurrentRegion

For i = 2 To UBound(Brr)
x = Brr(i, 1)
For j = 2 To UBound(Brr, 2)
   y = Brr(1, j)
   If e.exists(x) = False Then Set e(x) = CreateObject("Scripting.Dictionary")
     e(x)(y) = Brr(i, j)
Next
Next

table2.Close False
Sheets("检查表").Cells.Interior.Pattern = xlNone
Sheets("检查表").Cells.ClearComments
For i = 2 To UBound(Arr)
    x = Arr(i, 1)
  If e.exists(x) Then
    For j = 2 To (UBound(Arr, 2))
      y = Arr(1, j)
      If e(x).exists(y) And Arr(i, j) <> "" Then
        z = Arr(i, j)
        If e(x)(y) = z Then
          Sheets("检查表").Cells(i, j).Interior.ColorIndex = 6  '这里加入单元格显示颜色命令
        Else       '这里加入插入备注命令，备注按检查表日期数量减去源表数量的差额
          d = z - e(x)(y)
          Sheets("检查表").Cells(i, j).AddComment "内示：" & d
          Sheets("检查表").Cells(i, j).Comment.Visible = False
        End If
      End If
    Next j
  End If
Next i
   
Application.ScreenUpdating = True
End Sub