新版《别怕……》例题挑毛病，“5.2.7”头晕者看过来！

e表格学习

关于“5.2.7 用批注记录单元格中数据的修改情况”事件程序中的两个小毛病：
1.误将“Value”（意为“输入值”）写为“Formula”（意为“公式”）。
编者的本意是使用“Value”，而不是使用“Formula”，这从编者的声明变量“RngValue”中可以证明。
事实上，本例题中不宜使用Formula，因为Formula、Text会干扰初学者的主要学习点。
2.批注中第一行可能会出现空行，空行看起来不舒服。
添加了IF句后，避免了可能出现的空行。
下面是本人的修改程序：

1. Option Explicit
   
2. Dim RngValue As String '定义一个变量给模块，用于保存单元格中的数据
   
3. Private Sub Worksheet_SelectionChange(ByVal Target As Range)
   
4. If Target.Cells.Count <> 1 Then Exit Sub '选中多个单元格时退出程序
   
5. If Target.Value = "" Then '根据选中的单元格内容给变量RngVaue赋值
   
6. RngValue = "空"
   
7. Else
   
8. RngValue = Target.Value
   
9. End If
   
10. End Sub
    
11. Private Sub Worksheet_Change(ByVal Target As Range)
    
12. If Target.Cells.Count <> 1 Then Exit Sub
    
13. Dim Cvalue As String '定义变量保存单元格修改后的内容
    
14. If Target.Value = "" Then '判断单元格是否被修改为空单元格
    
15. Cvalue = "空"
    
16. Else
    
17. Cvalue = Target.Value
    
18. End If
    
19. If RngValue = Cvalue Then Exit Sub '如果单元格修改前后的内容一样则退出程序
    
20. Dim RngCom As Comment '定义一个批注类型的变量，名称为RngCom
    
21. Dim ComStr As String '定义变量ComStr，用来保存批注的值
    
22. Set RngCom = Target.Comment '将被修改单元格的批注赋给变量RngCom
    
23. If RngCom Is Nothing Then Target.AddComment '如果单元格中没有批注则新建批注
    
24. ComStr = Target.Comment.Text '将批注的内容保存到变量ComStr中
    
25. 
    
26. '重新修改批注的内容＝原批注内容+当前日期和时间+原内容+修改后的新内容
    
27. If ComStr = "" Then '避免批注的第一行出现空行
    
28. Target.Comment.Text Text:=Format(Now(), "yyyy-mm-dd hh:mm") & _
    
29. " 原内容: " & RngValue & _
    
30. "，修改为: " & Cvalue
    
31. Else
    
32. Target.Comment.Text Text:=ComStr & Chr(10) & _
    
33. Format(Now(), "yyyy-mm-dd hh:mm") & _
    
34. " 原内容: " & RngValue & _
    
35. "，修改为: " & Cvalue
    
36. End If
    
37. Target.Comment.Shape.TextFrame.AutoSize = True '根据批注内容自动调整批注大小
    
38. End Sub
    
39. 
    
40. 
    

复制代码

huang1314wei

我只想说value与Formula都是单元格的属性，如果单元格不是公式，二者是等效的

microyip

贴主是在学还是找茬？如果是学，非带公式类型的普通情况下，如2楼所说，等效。如果找茬，我觉得应该直接去找出书者予以说明，在这里表现你找茬能力，貌似没意义吧？

e表格学习

huang1314wei 发表于 2017-9-29 22:26
我只想说value与Formula都是单元格的属性，如果单元格不是公式，二者是等效的

您说的，我之前已经注意到了。
对于初学者（原书编者的主要面对者），本题还是使用Value为好！因为当输入为公式时，程序的表现与编程者的愿望可能会不一致！

e表格学习

microyip 发表于 2017-9-30 08:13
贴主是在学还是找茬？如果是学，非带公式类型的普通情况下，如2楼所说，等效。如果找茬，我觉得应该直接去 ...

在学，同时找茬=挑毛病，正确！（个人学习留脚印）
有意义。初学者更容易理解、学习本题想要教授的要点：自动记录。避免了初学者去学习输入值与公式的异同这个“枝节”问题！
本人找的第二个“茬”有问题吗？

e表格学习

再说原题错在哪里(兼与二楼、三楼的两位老师讨论)？
先看原程序：

Option Explicit

Dim RngValue As String     '定义一个变量给模块，用于保存单元格中的数据

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

   If Target.Cells.Count <> 1 Then Exit Sub '选中多个单元格时退出程序

   If Target.Formula = "" Then    '根据选中的单元格内容给变量RngVaue赋值

        RngValue = "空"

   Else                                          

        RngValue = Target.Text

   End If

End Sub

Private Sub Worksheet_Change(ByVal Target As Range)

    If Target.Cells.Count <> 1 Then Exit Sub

    Dim Cvalue As String     '定义变量保存单元格修改后的内容                    

    If Target.Formula = "" Then    '判断单元格是否被修改为空单元格

        Cvalue = "空"

    Else                                                                                                                                                            

           Cvalue = Target.Formula

    End If

    If RngValue = Cvalue Then Exit Sub '如果单元格修改前后的内容一样则退出程序

    Dim RngCom As Comment   '定义一个批注类型的变量，名称为RngCom

    Dim ComStr As String       '定义变量ComStr，用来保存批注的值

    Set RngCom = Target.Comment   '将被修改单元格的批注赋给变量RngCom

    If RngCom Is Nothing Then Target.AddComment    '如果单元格中没有批注则新建批注

    ComStr = Target.Comment.Text      '将批注的内容保存到变量ComStr中

   

    '重新修改批注的内容＝原批注内容+当前日期和时间+原内容+修改后的新内容

    Target.Comment.Text Text:=ComStr & Chr(10) & _

                        Format(Now(), "yyyy-mm-dd hh:mm") & _

                        " 原内容: " & RngValue & _

                        "，修改为: " & Cvalue

    End If

    Target.Comment.Shape.TextFrame.AutoSize = True '根据批注内容自动调整批注大小

End Sub

分析：

我给加粗加大的三个语句，是错误的原因！

实操证明：当之前输入为公式（即“=******”的形式）时，再双击公式所在单元格（但是不要作任何更改！）后回车，批注会增加一行，即程序错误地认为你对单元格进行了修改。

e表格学习

microyip 发表于 2017-9-30 08:13
贴主是在学还是找茬？如果是学，非带公式类型的普通情况下，如2楼所说，等效。如果找茬，我觉得应该直接去 ...

本人又研究了一下：当输入为公式时，原程序运行结果可能与编程人的愿望不一致！这是由于程序中三个语句的不协调（请见楼下本人标注）引起的！

所以，还是统一、简单Value为好！

microyip

e表格学习 发表于 2017-10-2 20:45
本人又研究了一下：当输入为公式时，原程序运行结果可能与编程人的愿望不一致！这是由于程序中三个语句 ...

不同属性有不同功能
.Value
.Value2
.Text
.Formula
.FormulaArray
……

e表格学习

已得到原著老师的指导：RNGVALUE=TARGET.TEXT应该改为RNGVALUE=TARGET.FORMULA

huaxia5qiannian

e表格学习 发表于 2017-10-2 10:43
在学，同时找茬=挑毛病，正确！（个人学习留脚印）
有意义。初学者更容易理解、学习本题想要教授的要 ...

我非常赞同5楼的说法，我第一遍看这本书的时候，看到自动生成批准这里时，确实产生疑问，为什么不直接用value,而是要用formula,然后上网查了很多资料，最后才明白，没有公式的情况下，这两者是等效的，但是对于初学者，这里用VALUE，确实更容易理解！