问下EXCEL update 支持嵌套SELCET查询吗？麻烦举例明示

gtwlren

问下EXCEL update 支持嵌套SELCET查询吗？麻烦举例明示
比如：
SQL = "update [订单明细$] set [订单明细$].计划件数=(select sum(件数) as 计划件数 from [出库计划$]  where [订单明细$].订单行号=[出库计划$].订单行号 group by 订单行号)"
这句返回：操作必须使用一个可更新的查询！

笑着...两年过去

没试过，但是把合计件数先取出来，赋值给一个变量，然后set一下肯定是可以的

zhaogang1960

应该不行，但把等于号后面的查询结果复制到工作表中，可以用该表数据来更新，请参考：
Sub 更新()
    Dim cnn As New ADODB.Connection
    Dim rs As New ADODB.Recordset
    Dim SQL$, i&
    Application.ScreenUpdating = False
    Application.DisplayAlerts = False
    cnn.Open "Provider = Microsoft.Jet.Oledb.4.0;Extended Properties =Excel 8.0;Data Source =" & ThisWorkbook.FullName
    SQL = "select 订单行号,sum(件数) from [出库计划$] group by 订单行号"
    rs.Open SQL, cnn, adOpenKeyset, adLockOptimistic
    i = rs.RecordCount + 1
    With Sheets("出库计划")
        .Range("A2:B" & i).Insert Shift:=xlDown
        .Range("A2").CopyFromRecordset rs
        SQL = "update [订单明细$] a,[出库计划$a1:b" & i & "] b set a.计划件数=b.件数 where a.订单行号=b.订单行号"
        cnn.Execute SQL
        .Range("A2:B" & i).Delete Shift:=xlUp
    End With
    Application.ScreenUpdating = True
    MsgBox "更新成功。", vbInformation, "更新"
    rs.Close
    cnn.Close
    Set rs = Nothing
    Set cnn = Nothing
End Sub

zhaogang1960

刚才上传2003代码需要审核，下面图片是2010代码：

gtwlren

谢啦!!☆⌒(*＾-゜)v，我UPDATE 条件=数组变量解决了，不过数字老是成文本。

LMY123

SQL同薄更新数据

dyh酋长

zhaogang1960 发表于 2017-3-9 20:12
应该不行，但把等于号后面的查询结果复制到工作表中，可以用该表数据来更新，请参考：
Sub 更新()
    Di ...

赵老师，我有一个问题关于按照表里面的主叫号码和数据库表里面的设备号字段，数据相匹配，然后导出数据库对应字段的序号、现负责人和业务员信息，现在的问题是数据小于6万条以下可以，超过6万就没反应或者报错，这个该怎么办，麻烦您可以帮我帮我看看，有没有什么办法解决，
http://club.excelhome.net/forum. ... p;page=1#pid9658458

zhaogang1960

dyh酋长 发表于 2018-9-16 12:36
赵老师，我有一个问题关于按照表里面的主叫号码和数据库表里面的设备号字段，数据相匹配，然后导出数据库 ...

对于Excel2007及更高版本中已经打开的工作簿，如果指定数据区域，则大于65536行的数据将被忽略，解决方法删除标题行上面的多余空行，取消指定区域，直接使用工作表作为数据源：
Sub 方法1()
    Dim cnn As New ADODB.Connection
    Dim sql As String
    cnn.Open "provider=Microsoft.ACE.OLEDB.12.0;data source=" & ThisWorkbook.Path & "\异网通话清单1704开始.accdb"
    sql = "select x.主叫号码,x.施工单位,y.序号,y.业务员,x.其他数据2,y.现负责人 from [Excel 12.0;Database=" & ThisWorkbook.FullName & ";].[查询$] x left join 17909话费表 y on x.主叫号码=y.设备号"
    Range("b2").CopyFromRecordset cnn.Execute(sql)
    cnn.Close
    Set cnn = Nothing
End Sub


最新更改上传的查询.rar (1.47 MB, 下载次数: 33)

2018-9-16 13:20 上传

点击文件名下载附件

dyh酋长

zhaogang1960 发表于 2018-9-16 13:21
对于Excel2007及更高版本中已经打开的工作簿，如果指定数据区域，则大于65536行的数据将被忽略，解决方法 ...

太感谢了，问题解决了，谢谢老师您的帮助