如何用vba拆分工作表！

雪儿2006

求助：如何使用VBA将“数据源”工作表拆分成多个工作表，并以“销售员”中的名称为新工表名称，拆分后的表格式和数据源原表格式相同，保存在一个工作薄里，以“子表”为工作薄命名。祥见附件表格。 未结.7z (82.85 KB, 下载次数: 74)

2016-8-10 00:08 上传

点击文件名下载附件

谢谢各位老师！！

有4地

1. Sub 如何将一个Excel工作表的数据拆分成多个工作表()
   
2.     Dim Arr, Rng As Range, Sht As Worksheet, Dic As Object
   
3.     Dim k, t, Str As String, i As Long, lc As Long
   
4.     Application.ScreenUpdating = False '关闭屏幕更新
   
5.     Arr = Range("A1").CurrentRegion.Value
   
6.     lc = UBound(Arr, 2) '求取最后一列的列号
   
7.     Set Rng = Rows(1) '标题行
   
8.     Set Dic = CreateObject("Scripting.Dictionary") '创建字典
   
9.     For i = 2 To UBound(Arr)
   
10.         Str = Arr(i, 13) '单位，关键字
    
11.         If Not Dic.Exists(Str) Then '如果字典没有关键字
    
12.             Set Dic(Str) = Cells(i, 1).Resize(, lc) '把当前行装入到字典中
    
13.         Else '否则(字典中存在关键字)
    
14.             Set Dic(Str) = Union(Dic(Str), Cells(i, 1).Resize(, lc)) '把行连合起来
    
15.         End If
    
16.     Next
    
17.     k = Dic.Keys '字典关键字集合
    
18.     t = Dic.Items '字典项目集合
    
19.     On Error Resume Next
    
20.     With Sheets
    
21.         For i = 0 To Dic.Count - 1 '循环关键字的个数
    
22.             Set Sht = .Item(k(i)) '给变量赋值(工作表名为关键字)
    
23.             If Sht Is Nothing Then '该工作表不存在则插入一个空工作表
    
24.                 .Add(After:=.Item(.Count)).Name = k(i) '新建的工作表将置于所有工作表之后，并命名为关键字
    
25.                 Set Sht = ActiveSheet '活动工作表给变量
    
26.             Else '否则
    
27.                 Sht.Cells.Clear '清除工作中所有内容和格式
    
28.             End If
    
29.             Rng.Copy Sht.Range("A1") '把标题写入第一行
    
30.             t(i).Copy Sht.Range("A2") '写入其他内容
    
31.             Sht.Cells.EntireColumn.AutoFit '自动调整全工作表单元格的列宽
    
32.             Set Sht = Nothing '变量处于初始状态
    
33.         Next
    
34.     End With
    
35.     Sheets(1).Activate '第1个工作表处于激活状态
    
36.     Application.ScreenUpdating = True '打开屏幕更新
    
37. End Sub
    

复制代码

雪儿2006

太感谢老师了！！！ 帮我解决了工作上的一个难题，也帮我节省了很多时间 。

雪儿2006

老师，我换了张表格做拆分，为何总是说“运行时错误13”类型不匹配呢？

mtxj

调整第十行代码位置就能继续用