请教VSTO插件的多线程处理

cooloaky · 发表于 2016-1-28 14:45

用SynchronizationContext异步提取后台数据库的数据的时候是否会有效率差异？

由于数据库比较大，提取的数据也比较多。为了避免用户界面死锁的情况，写了一个DataFetcher的类，通过其来异步从后台数据库提取大量数据。测试发现提取50万的数据需要耗时2小时。但如果不采用异步方式的花，只需要15～30分钟左右。是否异步会有执行效率的差异？求高手看看代码。

Imports System.Data
Imports System.ComponentModel
Imports System.Threading
Namespace Core
''' <summary>
''' Provides data for DataFecher.Fetched event.
''' </summary>
Public Class FetchedEventArgs
Inherits CancelableEventArgs
Private _data As Object
''' <summary>
''' Gets the fetched data. Returns null if fetching failed.
''' </summary>
ReadOnly Property Data As Object
Get
Return _data
End Get
End Property
''' <summary>
''' Initializes the new instance with data object.
''' </summary>
Friend Sub New(ByVal data As Object)
MyBase.new()
_data = data
End Sub
End Class
''' <summary>
''' The delegation which occurs when trying to fetch data asynchronously.
''' </summary>
''' <param name="cnn">The connection string.</param>
''' <param name="cmd">The command text.</param>
''' <returns>The data object.</returns>
Public Delegate Function DataFetchingCallback(ByVal cnn As String, ByVal cmd As String) As Object
''' <summary>
''' Represents an object which can fetch data asynchronously.
''' </summary>
Public Class DataFetcher
Private myThread As Thread
Private _cnn As String
Private _cmd As String
Private _context As SynchronizationContext
Private _fetching As DataFetchingCallback
''' <summary>
''' Occurs when DataFetcher.Fetch method was completed no matter successfully or failed.
''' </summary>
''' <param name="sender">The DataFetcher object which raises this event.</param>
''' <param name="e">Event data.</param>
Public Event Fetched(ByVal sender As Object, ByVal e As FetchedEventArgs)
''' <summary>
''' Gets or sets the asynchronous callback to fetch data.
''' </summary>
Property FetchingHandler As DataFetchingCallback
Get
Return _fetching
End Get
Set(ByVal value As DataFetchingCallback)
_fetching = value
End Set
End Property
''' <summary>
''' Gets or sets the connection string for data fetching.
''' </summary>
Property ConnectionString As String
Get
Return _cnn
End Get
Set(ByVal value As String)
_cnn = value
End Set
End Property
''' <summary>
''' Gets or sets the command text for data fetching.
''' </summary>
Property CommandText As String
Get
Return _cmd
End Get
Set(ByVal value As String)
_cmd = value
End Set
End Property
''' <summary>
''' Indicates whether the DataFetcher is fetching data now.
''' </summary>
ReadOnly Property IsBusy As Boolean
Get
Return IsNothing(myThread) = False AndAlso myThread.IsAlive
End Get
End Property
''' <summary>
''' Gets or sets the SynchronizationContext.
''' </summary>
Property Context As SynchronizationContext
Get
Return _context
End Get
Set(ByVal value As SynchronizationContext)
_context = value
End Set
End Property
''' <summary>
''' Aborts the data fetching process.
''' </summary>
Sub Abort()
If Me.IsBusy = False Then Return
myThread.Abort()
myThread = Nothing
Dim e As New FetchedEventArgs(Nothing)
e.Cancel = True
e.Message = "Aborted"
Me.OnFetched(e)
End Sub
''' <summary>
''' Checks DataFetcher whether it is ready to be called.
''' </summary>
Protected Sub CheckForIlegal()
If IsNothing(Me.FetchingHandler) Then
Throw Exceptions.Create("{0}.FechtingHandler can't be null.", Me.GetType.FullName)
End If
If IsNothing(Me.Context) Then
Throw Exceptions.Create("{0}.Context can't be null.", Me.GetType.FullName)
End If
If String.IsNullOrEmpty(Me.ConnectionString) Then
Throw Exceptions.Create("{0}.ConnectionString can't be empty.", Me.GetType.FullName)
End If
If String.IsNullOrEmpty(Me.CommandText) Then
Throw Exceptions.Create("{0}.CommandText can't be empty.", Me.GetType.FullName)
End If
If Me.IsBusy Then
Throw Exceptions.Create("{0}.Fetch can't be executed when busy.", Me.GetType.FullName)
End If
End Sub
''' <summary>
''' Starts to fetch data asynchronously.
''' </summary>
Sub Fetch()
Me.CheckForIlegal()
myThread = New Thread(AddressOf Me.Start)
Dim ab As New AsyncBody With
{
.context = Me.Context,
.cmd = Me.CommandText,
.cnn = Me.ConnectionString,
.fetching = Me.FetchingHandler
}
myThread.Start(ab)
End Sub
''' <summary>
''' The embeded parameter passed to async thread.
''' </summary>
Private Structure AsyncBody
''' <summary>
''' The SynchronizationContext which will accept result.
''' </summary>
Public context As SynchronizationContext
''' <summary>
''' The command text.
''' </summary>
Public cmd As String
''' <summary>
''' The connection string.
''' </summary>
Public cnn As String
''' <summary>
''' The delegation of fetching data.
''' </summary>
Public fetching As DataFetchingCallback
End Structure
''' <summary>
''' The embeded parameter passed to current thread.
''' </summary>
Protected Structure AsyncResult
''' <summary>
''' If True, the fetching was failed. Otherwise, False.
''' </summary>
Public cancel As Boolean
''' <summary>
''' The description of exception.
''' </summary>
Public message As String
''' <summary>
''' The fetched data object.
''' </summary>
Public result As Object
End Structure
''' <summary>
''' Starts to fetch data on an async thread.
''' </summary>
''' <param name="obj">The AsyncBody object which will be passed DataFetcher.FetchingHandler.</param>
''' <remarks/>
Protected Sub Start(ByVal obj As Object)
Dim ab = CType(obj, AsyncBody)
Dim res = New AsyncResult With {.cancel = False, .message = ""}
Try
res.result = ab.fetching.Invoke(ab.cnn, ab.cmd)
Catch ex As Exception
res.cancel = True
res.message = ex.Message
res.result = Nothing
End Try
ab.context.Post(AddressOf Me.Post, res)
End Sub
''' <summary>
''' Returns current thread to handle fetched data.
''' </summary>
''' <param name="state">The AsyncResult object which will be used by DataFetcher.FetchedHandler.</param>
''' <remarks></remarks>
Protected Sub Post(ByVal state As Object)
Dim ar = CType(state, AsyncResult)
Dim e As New FetchedEventArgs(ar.result)
e.Cancel = ar.cancel
e.Message = ar.message
Me.OnFetched(e)
End Sub
''' <summary>
''' Raises DataFetcher.Fetched event.
''' </summary>
Protected Sub OnFetched(ByVal e As FetchedEventArgs)
RaiseEvent Fetched(Me, e)
End Sub
End Class
End Namespace

复制代码

cooloaky · 发表于 2016-1-28 14:54

代码继续

''' <summary>
''' The interface for cancelable event arguments.
''' </summary>
Public Interface ICancelable
''' <summary>
''' Indicates the subsequent process need to be cancelled or not.
''' </summary>
Property Cancel As Boolean
''' <summary>
''' The reason for cancellation.
''' </summary>
Property Message As String
End Interface
''' <summary>
''' Provides data for cancelable event.
''' </summary>
Public Class CancelableEventArgs
Inherits System.EventArgs
Implements ICancelable
Private _cancel As Boolean, _message As String
''' <summary>
''' Indicates whether next process should be cancelled or not.
''' </summary>
Public Property Cancel As Boolean Implements ICancelable.Cancel
Get
Return _cancel
End Get
Set(ByVal value As Boolean)
_cancel = value
End Set
End Property
''' <summary>
''' The reason for cancellation.
''' </summary>
Public Property Message As String Implements ICancelable.Message
Get
Return _message
End Get
Set(ByVal value As String)
_message = value
End Set
End Property
End Class
''' <summary>
''' A class to get tailor-made exception.
''' </summary>
Public Class Exceptions
''' <summary>
''' Gets an xml string which explores the attributes of an exception.
''' </summary>
Shared Function Explore(ByVal ex As Exception) As String
Dim x = <Exception Message=<%= ex.Message %>
StackTrace=<%= ex.StackTrace %>
/>
If String.IsNullOrEmpty(ex.Source) = False Then x.SetAttributeValue("Source", ex.Source)
If IsNothing(ex.TargetSite) = False Then x.SetAttributeValue("TargetSite", ex.TargetSite.Name)
If ex.InnerException IsNot Nothing Then x.Add(XElement.Parse(Explore(ex.InnerException)))
Return x.ToString(SaveOptions.OmitDuplicateNamespaces)
End Function
''' <summary>
''' Prompts the Exception to user through MsgBox.
''' </summary>
Shared Sub Prompt(ByVal ex As Exception, ByVal severity As Severity)
Select Case severity
Case Core.Severity.None
MsgBox(Extract(ex), MsgBoxStyle.Information)
Case Core.Severity.Warning
MsgBox(Extract(ex), MsgBoxStyle.Exclamation)
Case Core.Severity.Warning
MsgBox(Extract(ex), MsgBoxStyle.Critical)
End Select
End Sub
''' <summary>
''' Extracts the message and caster from an Exception.
''' </summary>
Shared Function Extract(ByVal ex As Exception) As String
Dim s As String = ""
Dim e As Exception = ex
Do While Not IsNothing(e)
If IsNothing(e.TargetSite) = False Then
s = e.TargetSite.DeclaringType.FullName.Bracket(SpecialChar.BracketType.Brace) +
SpecialChar.Dot + e.TargetSite.Name.Bracket(SpecialChar.BracketType.Brace)
Exit Do
End If
e = e.InnerException
Loop
If String.IsNullOrEmpty(s) Then Return ex.Message
Return ex.Message + vbCr + vbCr + s
End Function
''' <summary>
''' Creates an Exception with inner exception and formatting message.
''' </summary>
Shared Function Create(ByVal innerEx As Exception, ByVal format As String, ByVal ParamArray args() As Object) As Exception
Dim s = String.Format(format, args)
Return New Exception(s, innerEx)
End Function
''' <summary>
''' Creates an Exception with string format and arguments.
''' </summary>
Shared Function Create(ByVal format As String, ByVal ParamArray args() As Object) As Exception
Return New Exception(String.Format(format, args))
End Function
End Class

复制代码

excelhomesnake · 发表于 2016-1-28 16:08

多线程异步，若电脑只能使用单个cpu，系统实际只是通过时间切片来模拟…不断切换会消耗资源…这时如果你盲目增加线程，只会得不偿失…若只为空出前台界面操作线程，应只开一个取数线程即可…没看代码，但你描述说的时间差异来看，你可能因为切换线程导致性能大幅下降…

liucqa · 发表于 2016-2-4 08:12

你要是去csdn上发这种帖子，肯定会被喷。
谁告诉你多线程一定比单线程快的?

		自动登录	找回密码
密码			免费注册

[求助] 请教VSTO插件的多线程处理

浏览过的版块