求助批量调整WORD中的表格

halsun_hu

Sub 调整表格()
'
' 调整表格 宏
'
'
    Selection.ClearFormatting
    Selection.Style = ActiveDocument.Styles("正文无缩进")
    CommandBars("Styles").Visible = False
    Selection.Tables(1).AutoFitBehavior (wdAutoFitWindow)
    Selection.Tables(1).AutoFitBehavior (wdAutoFitWindow)
    Selection.SelectCell
    Selection.ParagraphFormat.Alignment = wdAlignParagraphCenter
    Selection.Cells.VerticalAlignment = wdCellAlignVerticalCenter
End Sub

我自己录了一个宏，是先选中一个表格，然后全清格式，再将正文的缩进去掉，然后根据窗口自动调整，最后将文字设成居中。我想一次性的调整WORD中的表格，哪位能帮我写一下宏代码啊。
谢谢！

413191246se

Sub 表格排版()
    Dim t As Table, x As Long, y As Long, s As Long, j As Long, k As Long, e As Long
    For Each t In ActiveDocument.Tables
        x = t.Range.Information(wdEndOfRangeRowNumber)
        y = t.Range.Information(wdEndOfRangeColumnNumber)
        s = t.Range.Cells.Count
        If x <> 1 Then
            If s = x * y Then
                For k = 1 To y
                    For j = 1 To x - 1
                        If t.Cell(j + 1, k).Width = t.Cell(j, k).Width Then e = 1 Else e = 0
                        If e = 0 Then Exit For
                    Next j
                    If e = 0 Then Exit For
                Next k
            Else
                e = 0
            End If
        Else
            e = 1
        End If
        With t
            With .Rows
                .WrapAroundText = False
                .Alignment = wdAlignRowLeft
                .LeftIndent = CentimetersToPoints(0)
            End With
            With .Range
                .Font.Size = 12
                With .ParagraphFormat
                    .CharacterUnitFirstLineIndent = 0
                    .FirstLineIndent = CentimetersToPoints(0)
                    .LineSpacingRule = wdLineSpaceSingle
                    .Alignment = wdAlignParagraphCenter
                End With
                .Cells.VerticalAlignment = wdCellAlignVerticalCenter
            End With
            If .LeftPadding <> CentimetersToPoints(0.19) Then .LeftPadding = CentimetersToPoints(0.19)
            If .RightPadding <> CentimetersToPoints(0.19) Then .RightPadding = CentimetersToPoints(0.19)
            If e = 1 Then
                If x > 1 Then
                    With .Rows(1).Range.Font
                        .Name = "黑体"
                        .Name = "Times New Roman"
                        .Bold = True
                    End With
                End If
                With .Rows
                    .HeightRule = wdRowHeightAtLeast
                    .Height = CentimetersToPoints(0.7)
                End With
                .AutoFitBehavior (wdAutoFitContent)
                .AutoFitBehavior (wdAutoFitContent)
                .Select
            End If
            .AutoFitBehavior (wdAutoFitWindow)
            .AutoFitBehavior (wdAutoFitWindow)
            'add
            .Select
            Selection.Next(Unit:=wdParagraph, Count:=1).Select
            CommandBars.FindControl(ID:=122).Execute
            CommandBars.FindControl(ID:=123).Execute
            If Len(Selection) <> 1 Then
                Selection.HomeKey Unit:=wdLine
                Selection.InsertParagraphBefore
                Selection.Font.Size = 4
            End If
        End With
    Next
End Sub

413191246se

楼上《表格排版》宏功能：如果光标在表格中，处理当前表格；否则，处理所有表格。