WORD中选择最后一个字符至最后一个回车符号的VBA代码。怎么写。

学习VS交流

loquat 发表于 2015-1-22 21:17
以上思路只是在批量编辑时可能会效率比较明显，单个文件5楼是最好的代码。。。

感谢老师的代码，但，最后的空格不能删除！

守柔

学习VS交流 发表于 2015-1-22 22:01
感谢老师的代码，但，最后的空格不能删除！

以下代码删除文档尾部连续的空白段落,注意,是空白段落而非空格.
Sub DeleteLastBlankParagraphs()
''''功能:删除文档结尾位置的空白段落
    Dim myRange As Word.Range
    With ActiveDocument.Content.Find ''''主文字部分的查找
        .ClearFormatting ''''清除查找格式
        .Text = "^13{2,}"    ''''[^13^32]{2,}''''此要为连续2个及以上空白段落;如需包括空格,参考注释后的表达式
        .Wrap = wdFindStop ''''完成搜索后即结束
        .Forward = False ''''反向查找(从文档尾部向文档起始位置方向)
        .MatchWildcards = True ''''使用通配符
        .Replacement.ClearFormatting ''''清除替换格式
        .Replacement.Text = Empty ''''清空替换内容
        If .Execute = True Then ''''如果成功查找到时
            Set myRange = .Parent ''''返回找到的Range对象
            ''''myRange.Select
            If myRange.End = ActiveDocument.Content.End Then myRange.Delete ''''如包含文档结束标记则删除之
        End If
    End With
End Sub

学习VS交流

守柔 发表于 2015-1-23 09:57
以下代码删除文档尾部连续的空白段落,注意,是空白段落而非空格.
Sub DeleteLastBlankParagraphs()
'''' ...

守柔老师你好，非常感谢你的帮助！

如果我想删除最后一个字符后面，所有的空格和空白段落
再帮我修改下好吗，谢谢老师了！

守柔

学习VS交流 发表于 2015-1-22 22:01
感谢老师的代码，但，最后的空格不能删除！

Sub DeleteLastBlankCharacters()
''''功能:删除文档结尾位置的空白段落和空格
    With ActiveDocument.Content
        .InsertAfter Chr$(13) & Chr$(8)    ''''文档结束标记之前插入一个特殊字符(辅助定位)
        With .Find
            .ClearFormatting    ''''清除查找格式
            ''''如有需要其他空白字符,请自行添加
            .Text = "[^13^32" & ChrW$(160) & ChrW$(12288) & "]@^8"    ''''查找连续的空白段落,半角空格,全角空格,不连续空格
            .Wrap = wdFindStop    ''''完成搜索后即结束
            .Forward = True    ''''正向查找
            .MatchWildcards = True    ''''使用通配符
            .Replacement.ClearFormatting    ''''清除替换格式
            .Replacement.Text = Empty    ''''清空替换内容
            .Execute Replace:=wdReplaceAll    ''''全部替换
        End With
    End With
End Sub

学习VS交流

守柔 发表于 2015-1-23 10:43
Sub DeleteLastBlankCharacters()
''''功能:删除文档结尾位置的空白段落和空格
    With ActiveDocumen ...

老师这个完美了

如果是删除文档开始第一个字符前的空格和空白段落

麻烦老师也帮我修改一下好吧，谢谢老师了！

学习VS交流

守柔 发表于 2015-1-23 16:15
可以吐槽一下吧?
菩提本无树，明镜亦非台，本来无一物，何处惹尘埃.

谢谢老师，这个很好用！非常感谢！

EH2003

学习VS交流 发表于 2015-1-22 22:01
感谢老师的代码，但，最后的空格不能删除！

Sub 删除空行()
     Dim i As Paragraph
     For Each i In ActiveDocument.Paragraphs
         If Len(Trim(i.Range)) = 1 Then i.Range.Delete
     Next
End Sub

出差也会寂寞

413191246se 发表于 2015-1-21 00:26
明白了！楼主，我觉得你的要求似乎没有必要用代码，批量处理还是要删除全部空行的再排版，但也给你提供一下 ...

5楼的代码和10楼的我都用了试了一下。有一点不同的是，如果word文档是以表格结尾的话，在表格下面始终有一个空白段落，怎么删它都还在，这样5楼这个代码的程序按理论上讲就无法自动结束运行。如果文档末尾是文字而不是表格的话就不会出现在这个问题。10楼的代码不存在这个问题，只删除一次。

413191246se

* 刚才在查找本坛“假回车符”的问题时，刚好看到本帖。
* 确实如楼上朋友所言，如果文尾有表格的话（表格最后的回车符不能删除，否则怎么输入下一个字符呢？这和新建文档只有一个段落标记是一个道理），程序不能自动终止。如果文尾有表格，则分两种情况：一是表格后有文字；二是表格后无文字只有空格。
* 下面的宏已经更正，请各位试用：

1. Sub aaaa_DeleteBlanks_DocEnd()
   
2.     With Selection
   
3.         .EndKey 6
   
4.         Do
   
5.             If .Previous.Information(12) Then Exit Do
   
6.             CommandBars.FindControl(ID:=122).Execute
   
7.             CommandBars.FindControl(ID:=123).Execute
   
8.             If .Paragraphs(1).Range = vbCr Then .Delete Else Exit Do
   
9.         Loop
   
10.     End With
    
11. End Sub

复制代码