关于查找方法(Find方法)的最通俗教程

win2009

关于查找方法(Find方法)的最通俗教程

VBA_find函数.rar (145.94 KB, 下载次数: 2006)

2012-10-18 14:00 上传

点击文件名下载附件

在Excel中，选择菜单“编辑”——“查找(F)…”命令或者按“Ctrl+F”组合键，将弹出如下图01所示的“查找和替换”对话框。在“查找”选项卡中，输入需要查找的内容并设置相关选项后进行查找，Excel会将活动单元格定位在查找到的相应单元格中。如果未发现查找的内容，Excel会弹出“Excel找不到正在搜索的数据”的消息框。

图01：“查找”对话框

Excel的这个功能对查找指定的数据非常有用，特别是在含有大量数据的工作表中搜索数据时，更能体现出该功能的快速和便捷。同样，在ExcelVBA中使用与该功能对应的Find方法，提供了一种在单元格区域查找特定数据的简单方式，并且比用传统的循环方法进行查找的速度更快。

--------------------------------------------------------------------------------

1. Find方法的作用

Find方法将在指定的单元格区域中查找包含参数指定数据的单元格，若找到符合条件的数据，则返回包含该数据的单元格；若未发现相匹配的数据，则返回Nothing。该方法返回一个Range对象，在使用该方法时，不影响选定区域或活动单元格。

--------------------------------------------------------------------------------

2. Find方法的语法

[语法]

<单元格区域>.Find (What，[After]，[LookIn]，[LookAt]，[SearchOrder]，[SearchDirection]，[MatchCase]，[MatchByte]，[SearchFormat])

'__________________________________________________________________________________________________

<单元格区域>.Find (要查找的数据，开始查找的位置，查找的范围类型，完全匹配还是部分匹配，行列方式查找，向前向后查找，区分大小写，全角或半角，查找格式)

'__________________________________________________________________________________________________

[参数说明]

(1)<单元格区域>，必须指定，返回一个Range对象。

(2)参数What，必需指定。代表所要查找的数据，可以为字符串、整数或者其它任何数据类型的数据。对应于“查找与替换”对话框中，“查找内容”文本框中的内容。

(3)参数After，可选。指定开始查找的位置，即从该位置所在的单元格之后向后或之前向前开始查找(也就是说，开始时不查找该位置所在的单元格，直到Find方法绕回到该单元格时，才对其内容进行查找)。所指定的位置必须是单元格区域中的单个单元格，如果未指定本参数，则将从单元格区域的左上角的单元格之后开始进行查找。

(4)参数LookIn，可选。指定查找的范围类型，可以为以下常量之一：xlValues、xlFormulas或者xlComments，默认值为xlFormulas。对应于“查找与替换”对话框中，“查找范围”下

win2009

拉框中的选项。
(5)参数LookAt，可选。可以为以下常量之一：XlWhole或者xlPart，用来指定所查找的数据是与单元格内容完全匹配还是部分匹配，默认值为xlPart。对应于“查找与替换”对话框中，“单元格匹配”复选框。
(6)参数SearchOrder，可选。用来确定如何在单元格区域中进行查找，是以行的方式(xlByRows)查找，还是以列的方式(xlByColumns)查找，默认值为xlByRows。对应于“查找与替换”对话框中，“搜索”下拉框中的选项。
(7)参数SearchDirection，可选。用来确定查找的方向，即是向前查找(XlPrevious)还是向后查找(xlNext)，默认的是向后查找。
(8)参数MatchCase，可选。若该参数值为True，则在查找时区分大小写。默认值为False。对应于“查找与替换”对话框中，“区分大小写”复选框。
(9)参数MatchByter，可选。即是否区分全角或半角，在选择或安装了双字节语言时使用。若该参数为True，则双字节字符仅与双字节字符相匹配；若该参数为False，则双字节字符可匹配与其相同的单字节字符。对应于“查找与替换”对话框中，“区分全角/半角”复选框。
(10)参数SearchFormat，可选，指定一个确切类型的查找格式。对应于“查找与替换”对话框中，“格式”按钮。当设置带有相应格式的查找时，该参数值为True。
(11)在每次使用Find方法后，参数LookIn、LookAt、SearchOrder、MatchByte的设置将保存。如果下次使用本方法时，不改变或指定这些参数的值，那么该方法将使用保存的值。
在VBA中设置的这些参数将更改“查找与替换”对话框中的设置；同理，更改“查找与替换”对话框中的设置，也将同时更改已保存的值。也就是说，在编写好一段代码后，若在代码中未指定上述参数，可能在初期运行时能满足要求，但若用户在“查找与替换”对话框中更改了这些参数，它们将同时反映到程序代码中，当再次运行代码时，运行结果可能会产生差异或错误。若要避免这个问题，在每次使用时建议明确的设置这些参数。
3. Find方法使用示例
3.1 本示例在活动工作表中查找what变量所代表的值的单元格，并删除该单元格所在的列。
‘- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
Sub Find_Error()
  Dim rng As Range
  Dim what As String
  what = "Error"
  Do
    Set rng = ActiveSheet.UsedRange.Find(what)
    If rng Is Nothing Then
      Exit Do
    Else
       Columns(rng.Column).Delete
    End If
  Loop
End Sub
‘- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
3.2 带格式的查找
本示例在当前工作表单元格中查找字体为"Arial Unicode MS"且颜色为红色的单元格。其中，Application.FindFormat对象允许指定所需要查找的格式，此时Find方法的参数SearchFormat应设置为True。
‘- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
Sub FindWithFormat()
  With Application.FindFormat.Font
        .Name = "Arial Unicode MS"
        .ColorIndex = 3
  End With
  Cells.Find(what:="", SearchFormat:=True).Activate
End Sub
‘- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
[小结] 在使用Find方法找到符合条件的数据后，就可以对其进行相应的操作了。您可以：
(1)对该数据所在的单元格进行操作；
(2)对该数据所在单元格的行或列进行操作；
(3)对该数据所在的单元格区域进行操作。

--------------------------------------------------------------------------------
4. 与Find方法相联系的方法
可以使用FindNext方法和FindPrevious方法进行重复查找。在使用这两个方法之前，必须用Find方法指定所需要查找的数据内容。
4.1 FindNext方法
FindNext方法对应于“查找与替换”对话框中的“查找下一个”按钮。可以使用该方法继续执行查找，查找下一个与Find方法中所指定条件的数据相匹配的单元格，返回代表该单元格的Range对象。在使用该方法时，不影响选定区域或活动单元格。
4.1.1 语法
<单元格区域>.FindNext(After)
4.1.2 参数说明
参数After，可选。代表所指定的单元格，将从该单元格之后开始进行查找。开始时不查找该位置所在的单元格，直到FindNext方法绕回到该单元格时，才对其内容进行查找。所指定的位置必须是单元格区域中的单个单元格，如果未指定本参数，则将从单元格区域的左上角的单元格之后开始进行查找。
当查找到指定查找区域的末尾时，本方法将环绕至区域的开始继续查找。发生环绕后，为停止查找，可保存第一次找到的单元格地址，然后测试下一个查找到的单元格地址是否与其相同，作为判断查找退出的条件，以避免出现死循环。当然，如果在查找的过程中，将查找到的单元格数据进行了改变，也可不作此判断，如下例所示。
4.1.3 对VBA帮助系统上的一点疑问探讨
在VBA帮助系统中，介绍Find方法和FindNext方法所使用的示例好像有点问题：当在Excel中运行时，虽然运行结果正确，但是在运行到最后时，会报错误：运行时错误’91’:对象变量或With块变量未设置。究其原因，可能是对象变量c的问题，因为当进行查找并将相应的值全部改变后，最后变量c的值为Nothing。将其稍作改动后，运行通过。
原示例代码如下：(大家也可参见VBA帮助系统Find方法或FindNext方法帮助主题)
本示例在单元格区域A1:A500中查找值为2的单元格，并将这些单元格的值变为5。
With Worksheets(1).Range("a1:a500")
  Set c = .Find(2, lookin:=xlValues)
  If Not c Is Nothing Then
    firstAddress = c.Address
    Do
      c.Value = 5
      Set c = .FindNext(c)
    Loop While Not c Is Nothing And c.Address <> firstAddress
  End If
End With
经修改后的示例代码如下，即在原代码中加了一句错误处理语句On Error Resume Next，忽略所发生的错误。
Sub test1()
  Dim c As Range, firstAddress As String
  On Error Resume Next
  With Worksheets(1).Range("a1:a15")
    Set c = .Find(2, LookIn:=xlValues)
    If Not c Is Nothing Then
      firstAddress = c.Address
      Do
        c.Value = 5
        Set c = .FindNext(c)
      Loop While Not c Is Nothing And c.Address <> firstAddress
    End If
  End With
End Sub
或者，将代码作如下修改，即去掉原代码中最后一个判断循环的条件c.Address <> firstAddress，因为本程序的功能是在指定区域查找值为2的单元格并替换为数值5，当程序在指定区域查找不到数值2时就会退出循环，不涉及到重复循环的问题。
Sub test2()
  Dim c As Range, firstAddress As String
  With Worksheets(1).Range("a1:a15")
    Set c = .Find(2, LookIn:=xlValues)
    If Not c Is Nothing Then
      firstAddress = c.Address
      Do
        c.Value = 5
        Set c = .FindNext(c)
      Loop While Not c Is Nothing
    End If
  End With
End Sub
您也可以试试该程序，看看我的理解是否正确，或者还有什么其它的解决办法。
4.2 FindPrevious方法
可以使用该方法继续执行Find方法所进行的查找，查找前一个与Find方法中所指定条件的数据相匹配的单元格，返回代表该单元格的Range对象。在使用该方法时，不影响选定区域或活动单元格。
4.2.1 语法

win2009

<单元格区域>.FindPrevious(After)
4.2.2 参数说明
参数After，可选。代表所指定的单元格，将从该单元格之前开始进行查找。开始时不查找该位置所在的单元格，直到FindPrevious方法绕回到该单元格时，才对其内容进行查找。所指定的位置必须是单元格区域中的单个单元格，如果未指定本参数，则将从单元格区域的左上角的单元格之前开始进行查找。
当查找到指定查找区域的起始位置时，本方法将环绕至区域的末尾继续查找。发生环绕后，为停止查找，可保存第一次找到的单元格地址，然后测试下一个查找到的单元格地址是否与其相同，作为判断查找退出的条件，以避免出现死循环。
4.2.3 示例
在工作表中输入如下图02所示的数据，至少保证在A列中有两个单元格输入了数据“excelhome”。

图02：测试的数据
在VBE编辑器中输入下面的代码测试Find方法、FindNext方法、FindPrevious方法，体验各个方法所查找到的单元格位置。
‘- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
Sub testFind()
  Dim findValue As Range
  Set findValue = Worksheets("Sheet1").Columns("A").Find(what:="excelhome")
  MsgBox "第一个数据发现在单元格:" & findValue.Address
  Set findValue = Worksheets("Sheet1").Columns("A").FindNext(After:=findValue)
  MsgBox "下一个数据发现在单元格:" & findValue.Address
  Set findValue = Worksheets("Sheet1").Columns("A").FindPrevious(After:=findValue)
  MsgBox "前一个数据发现在单元格" & findValue.Address
End Sub
‘- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
关于查找方法(Find方法)的应用(二)
--------------------------------------------------------------------------------
5. 综合示例
5.1 示例一：在当前工作表的单元格区域A1:A50中输入数据5和其它的一些数据，然后在VBE编辑器中输入下面的代码。运行后，程序将在单元格A1:A50区域中查找数值5所在的单元格，并在所找到的单元格中画一个蓝色的椭圆。
‘- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
Sub FindSample1()
  Dim Cell As Range, FirstAddress As String
  With Worksheets(1).Range("A1:A50")
    Set Cell = .Find(5)
    If Not Cell Is Nothing Then
       FirstAddress = Cell.Address
       Do
         With Worksheets(1).Ovals.Add(Cell.Left, _
                                      Cell.Top, Cell.Width, _
                                      Cell.Height)
                                 .Interior.Pattern = xlNone
                                 .Border.ColorIndex = 5
         End With
         Set Cell = .FindNext(Cell)
         Loop Until Cell Is Nothing Or Cell.Address = FirstAddress
    End If
  End With
End Sub
‘- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
[参考] 参见《使VBA代码更快且更简洁的方法》一文中的“使用已有的VBA方法：Find方法”，体验使用传统的循环方法与使用该方法实现相同功能时，VBA代码速度的差异。
5.2 示例二：在一个列表中复制相关数据到另一个列表(Revised from Hansen’s Programming)
本程序的功能是，根据单元格I1中的值，在单元格区域A1:D11中的B列进行查找，每次找到相应的值，就将该单元格所在区域的行数据复制到以单元格G3(该单元格命名为found)开始的区域中。原数据如下图03所示。
   
图03：原始数据
点击工作表中的“查找”按钮，运行后的结果如下图04所示。
   
图04：运行后的结果
源程序代码清单及相关说明如下：
‘- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
Option Explicit
Sub FindSample2()
  Dim ws As Worksheet
  Dim rgSearchIn As Range
  Dim rgFound As Range
  Dim sFirstFound As String
  Dim bContinue As Boolean
  
  ReSetFoundList '初始化要复制的列表区域
  Set ws = ThisWorkbook.Worksheets("sheet1")
  bContinue = True
  Set rgSearchIn = GetSearchRange(ws) '获取查找区域
  
  '设置查找参数
  Set rgFound = rgSearchIn.Find(what:=ws.Range("I1").Value, _
             LookIn:=xlValues, LookAt:=xlWhole)

  '获取第一个满足条件的单元格地址,作为结束循环的条件
  If Not rgFound Is Nothing Then sFirstFound = rgFound.Address
  
  Do Until rgFound Is Nothing Or Not bContinue
    CopyItem rgFound
    Set rgFound = rgSearchIn.FindNext(rgFound)
    '判断循环是否中止
    If rgFound.Address = sFirstFound Then bContinue = False
  Loop

win2009

Set rgSearchIn = Nothing
  Set rgFound = Nothing
  Set ws = Nothing
End Sub

'获取查找区域,即B列中的"部位"单元格区域
Private Function GetSearchRange(ws As Worksheet) As Range
  Dim lLastRow As Long
  lLastRow = ws.Cells(65536, 1).End(xlUp).Row
  Set GetSearchRange = ws.Range(ws.Cells(1, 2), ws.Cells(lLastRow, 2))
End Function

'复制查找到的数据到found区域
Private Sub CopyItem(rgItem As Range)
  Dim rgDestination As Range
  Dim rgEntireItem As Range
  
  '获取在查找区域中的整行数据
  Set rgEntireItem = rgItem.Offset(0, -1)
  Set rgEntireItem = rgEntireItem.Resize(1, 4)
  
  Set rgDestination = rgItem.Parent.Range("found")
  '定位要复制到的found区域的第一行
  If IsEmpty(rgDestination.Offset(1, 0)) Then
    Set rgDestination = rgDestination.Offset(1, 0)
  Else
    Set rgDestination = rgDestination.End(xlDown).Offset(1, 0)
  End If
  
  '复制找到的数据到found区域
  rgEntireItem.Copy rgDestination
  
  Set rgDestination = Nothing
  Set rgEntireItem = Nothing
End Sub

'初始化要复制到的区域(found区域)
Private Sub ReSetFoundList()
  Dim ws As Worksheet
  Dim lLastRow As Long
  Dim rgTopLeft As Range
  Dim rgBottomRight As Range
  
  Set ws = ThisWorkbook.Worksheets("sheet1")
  Set rgTopLeft = ws.Range("found").Offset(1, 0)
  lLastRow = ws.Range("found").End(xlDown).Row
  Set rgBottomRight = ws.Cells(lLastRow, rgTopLeft.Offset(0, 3).Column)
  
  ws.Range(rgTopLeft, rgBottomRight).ClearContents
  
  Set rgTopLeft = Nothing
  Set rgBottomRight = Nothing
  Set ws = Nothing
End Sub
‘- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
在上述程序代码中，程序FindSample2( )为主程序，首先调用子程序ReSetFoundList( )对所要复制到的数据区域初始化，即清空除标题行以外的内容；然后调用自定义函数GetSearchRange(ws As Worksheet)获取所在查找的单元格区域；在主程序中使用Find方法和FIndNext方法进行查找，调用带参数的子程序CopyItem(rgItem As Range)将查找到的单元格所在的数据行复制到相应的区域。
示例文档见 Find方法示例1.xls。UploadFiles/2006-9/928354714.rar
5.3 示例三：实现带连续单元格区域条件的查找
下面的代码提供了一种实现以连续单元格区域中的数据为查找条件进行查找的方法和思路。在本例中，所查找条件区域为D2:D4，在单元格区域A1:A21中进行查找，将结果输入到以单元格F2开始的区域中。示例程序所对应的工作表数据及结果如下图06所示。
‘- - - - - - - - - -代码清单- - - - - - - - - - - - - - - - - - - - - -
Sub FindGroup()
  Dim ToFind As Range, Found As Range, c As Range
  Dim FirstAddress As String
  Set ToFind = Range("D2:D4")
  With Worksheets(1).Range("a1:a21")
    Set c = .Find(ToFind(1), LookIn:=xlValues)
    If Not c Is Nothing Then
      FirstAddress = c.Address
      Do
        If c.Offset(1) = ToFind(2) And c.Offset(2) = ToFind(3) Then
          Set Found = Range(c.Offset(0, 1), c.Offset(0, 1).Offset(2))
          GoTo Exits
        End If
        Set c = .FindNext(c)
      Loop While Not c Is Nothing And c.Address <> FirstAddress
    End If
  End With
Exits:
  Found.Copy Range("F2")
End Sub
‘- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  图05 数据及查找结果
图05 数据及查找结果

关于查找方法(Find方法)的应用(三)
--------------------------------------------------------------------------------
5.4 示例四：本示例所列程序将在工作簿的所有工作表中查找数值，提供了采用两种方法编写的程序，一种是Find方法，另一种是SpecialCells 方法。相对来说，使用Find方法比使用SpecialCells方法要快，当然，本示例可能不明显，但对于带大量工作表和数据的工作簿来说，这种速度差异就可以看出来了。(by fanjy from vbaexpress.com)。
示例代码如下，代码中有简要的说明。
‘- - -使用Find方法 - - - - - - - - - - - - - - - - - - - - - - - - - -
Sub QuickSearch()
  Dim wks As Excel.Worksheet
  Dim rCell As Excel.Range
  Dim szFirst As String
  Dim i As Long
  '设置变量决定是否加亮显示查找到的单元格
  '该变量为真时则加亮显示
  Dim bTag As Boolean
  bTag = True
  '使用input接受查找条件的输入
  Dim szLookupVal As String
  szLookupVal = InputBox("在下面的文本框中输入您想要查找的值", "查找输入框", "")

win2009

'如果没有输入任何数据,则退出程序
  If szLookupVal = "" Then Exit Sub
   
   Application.ScreenUpdating = False
   Application.DisplayAlerts = False
        
  ' ================================================
  ' 添加一个工作表,在该工作表中放置已查找到的单元格地址
  ' 如果该工作表存在,则先删除它
    For Each wks In ActiveWorkbook.Worksheets
      If wks.Name = "查找结果" Then
        wks.Delete
      End If
    Next wks
     
  ' 添加工作表
    Sheets.Add ActiveSheet
  ' 重命名所添加的工作表
    ActiveSheet.Name = "查找结果"
  ' 在新增工作表中添加标题,指明所查找的值
    With Cells(1, 1)
      .Value = "已在下面所列出的位置找到数值" & szLookupVal
      .EntireColumn.AutoFit
      .HorizontalAlignment = xlCenter
    End With
  
  ' ================================================
  ' 定位到刚开始的工作表
    ActiveSheet.Next.Select
   
  ' ================================================
  ' 提示您是否想高亮显示已查找到的单元格
    If MsgBox("您想加阴影高亮显示所有查找到的单元格吗?", vbYesNo, _
              "加阴影高亮显示单元格") = vbNo Then
    ' 如果不想加阴影显示单元格,则将变量bTag值设置为False
      bTag = False
    End If

  ' ================================================
    i = 2
  ' 开始在工作簿的所有工作表中搜索
    For Each wks In ActiveWorkbook.Worksheets
  ' 检查所有的单元格,Find方法比SpecialCells方法更快
      With wks.Cells
        Set rCell = .Find(szLookupVal, , , xlWhole, xlByColumns, xlNext, False)
        If Not rCell Is Nothing Then
          szFirst = rCell.Address
          Do
           ' 添加找到的单元格地址到新工作表中
            rCell.Hyperlinks.Add Sheets("查找结果").Cells(i, 1), "", "'" & wks.Name & "'!" & rCell.Address
           '  检查条件判断值bTag,以决定是否加亮显示单元格
             Select Case bTag
                    Case True
                       rCell.Interior.ColorIndex = 19
             End Select
             Set rCell = .FindNext(rCell)
             i = i + 1
          Loop While Not rCell Is Nothing And rCell.Address <> szFirst
        End If
      End With
    Next wks

  ' 释放内存变量
    Set rCell = Nothing
   
  ' 如果没有找到匹配的值,则移除新增工作表
    If i = 2 Then
      MsgBox "您所要查找的数值{" & szLookupVal & "}在这些工作表中没有发现", 64, "没有匹配值"
      Sheets("查找结果").Delete
    End If
   
    Application.ScreenUpdating = True
    Application.DisplayAlerts = True
End Sub

‘- - - 使用SpecialCells 方法- - - - - - - - - - - - - - - - - - - - - - - - -
Option Compare Text
Sub SlowerSearch()
    Dim wks As Excel.Worksheet
    Dim rCell As Excel.Range
    Dim i As Long
  '设置变量决定是否加亮显示查找到的单元格
  '该变量为真时则加亮显示
    Dim bTag As Boolean
    bTag = True
  '使用input接受查找条件的输入
    Dim szLookupVal As String
    szLookupVal = InputBox("在下面的文本框中输入您想要查找的值", "查找输入框", "")
  
  '如果没有输入任何数据,则退出程序
    If szLookupVal = "" Then Exit Sub
    With Application
      .ScreenUpdating = False
      .DisplayAlerts = False
      .Calculation = xlCalculationManual
         
  ' ==============================================
  ' 添加一个工作表,在该工作表中放置已查找到的单元格地址
  ' 如果该工作表存在,则先删除它
    For Each wks In ActiveWorkbook.Worksheets
      If wks.Name = "查找结果" Then
        wks.Delete
      End If
    Next wks
      
  ' 添加工作表
    Sheets.Add ActiveSheet
  ' 重命名所添加的工作表
    ActiveSheet.Name = "查找结果"
  ' 在新增工作表中添加标题,指明所查找的值
    With Cells(1, 1)
      .Value = "已在下面所列出的位置找到数值" & szLookupVal
      .EntireColumn.AutoFit
      .HorizontalAlignment = xlCenter
    End With
  
  ' ==========================================
  ' 定位到刚开始的工作表
    ActiveSheet.Next.Select
  
  ' ==========================================
    ' 提示您是否想高亮显示已查找到的单元格
    If MsgBox("您想加阴影高亮显示所有查找到的单元格吗?", vbYesNo, _
              "加阴影高亮显示单元格") = vbNo Then
    ' 如果不想加阴影显示单元格,则将变量bTag值设置为False
      bTag = False
    End If
  ' ==========================================
   i = 2
  ' 开始在工作簿的所有工作表中搜索

win2009

  On Error Resume Next
    For Each wks In ActiveWorkbook.Worksheets
      If wks.Cells.SpecialCells(xlCellTypeConstants).Count = 0 Then GoTo NoSpecCells
        For Each rCell In wks.Cells.SpecialCells(xlCellTypeConstants)
          DoEvents
          If rCell.Value = szLookupVal Then
           ' 添加找到的单元格地址到新工作表中
             rCell.Hyperlinks.Add Sheets("查找结果").Cells(i, 1), "", "'" & wks.Name & "'!" & rCell.Address
           '  检查条件判断值bTag,以决定是否加亮显示单元格
             Select Case bTag
                    Case True
                      rCell.Interior.ColorIndex = 19
             End Select
             i = i + 1
             .StatusBar = "查找到的单元格数为: " & i - 2
          End If
       Next rCell
NoSpecCells:
    Next wks
               
  ' 如果没有找到匹配的值,则移除新增工作表
  If i = 2 Then
    MsgBox "您所要查找的数值{" & szLookupVal & "}在这些工作表中没有发现", 64, "没有匹配值"
    Sheets("查找结果").Delete
  End If
  
  .Calculation = xlCalculationAutomatic
  .DisplayAlerts = True
  .ScreenUpdating = True
  .StatusBar = Empty
  End With
End Sub
‘- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
示例文档见 Find与SpecialCells查找示例.xls。http://blog.excelhome.net/UploadFiles/2006-9/928569799.rar
--------------------------------------------------------------------------------
6. 其它一些查找方法
可以使用For Each … Next语句和Like运算符进行更精确匹配的查找。例如，下列代码在单元格区域A1:A10中查找以字符“我”开头的单元格，并将其背景色变为红色。
‘- - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
Sub test()
  Dim Cell As Range
  For Each Cell In [A1:A10]
    If Cell Like "我*" Then
        Cell.Interior.ColorIndex = 3
    End If
  Next
End Sub
‘- - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
可以输入下图06所示的数据进行测试。
  图06:测试的数据

win2009

没了。。。。。。。。。。。。。。。。。。。。。。。。

feng16888

谢谢楼主的分享

win2009

.

SQL_最佳学习资料(超级宝典).rar (91.5 KB, 下载次数: 501)

2012-10-20 23:54 上传

点击文件名下载附件

VBA-FIND方法 的运用 [color=#999999 !important][color=#999999 !important][复制链接]

1楼 发表于 2011-1-20 20:17 |只看该作者 |倒序浏览 兰色幻想VBA基础入门和高级开发全套80集视频教程，助你成为VBA开发高手。 本帖最后由 龙猫 于 2011-1-20 20:23 编辑 为任务，天天在论坛混分 看了几个VBA代码，发现大家都特喜欢数组，还特喜欢把单元格区域整成数组，从这里找东东。 想起了一个不用数组就能找东东的方法——FIND方法 和大家分享一下： ----------------------------------------------------------------------------- F1 帮助的内容： Find 方法 应用于 Range 对象的 Find 方法。 在区域中查找特定信息，并返回 Range 对象，该对象代表用于查找信息的第一个单元格。如果未发现匹配单元格，就返回Nothing。本方法不影响选定区域或活动单元格。 有关在 Visual Basic 中使用 Find 工作表函数的详细信息，请参阅F1帮助中在 Visual Basic 中使用工作表函数。 expression.Find(What, After, LookIn, LookAt, SearchOrder, SearchDirection, MatchCase, MatchByte, SerchFormat) expression      必需。该表达式返回一个 Range 对象。 What      Variant 类型，必需。要搜索的数据。可为字符串或任意 Microsoft Excel 数据类型。 After      Variant 类型，可选。表示搜索过程将从其之后开始进行的单元格。此单元格对应于从用户界面搜索时的活动单元格位置。值得注意的是，After 必须是区域中的单个单元格。请记住搜索是从该单元格之后   开始的；直到本方法绕回到指定的单元格时，才对其进行搜索。如果未指定本参数，搜索将从区域的左上角单元格之后开始。 LookIn      Variant 类型，可选。信息类型。 LookAt      Variant 类型，可选。可为以下 XlLookAt 常量之一：xlWhole 或 xlPart。 SearchOrder      Variant 类型，可选。可为以下 XlSearchOrder 常量之一：xlByRows 或 xlByColumns。 SearchDirection      XlSearchDirection 类型，可选。搜索的方向。 XlSearchDirection 可为以下 XlSearchDirection 常量之一。 xlNext 默认值 xlPrevious MatchCase      Variant 类型，可选。若为 True，则进行区分大小写的查找。默认值为 False。 MatchByte      Variant 类型，可选。仅在选择或安装了双字节语言支持时使用。若为 True，则双字节字符仅匹配双字节字符。若为 False，则双字节字符可匹配其等价的单字节字符。 SearchFormat      Variant 类型，可选。搜索的格式。 说明每次使用本方法后，参数 LookIn、LookAt、SearchOrder 和 MatchByte 的设置将保存。如果下次调用本方法时不指定这些参数的值，就使用保存的值。设置这些参数将更改“查找和替换”对话框中的设置，如果您忽略参数，更改“查找和替换”对话框中的设置将更改使用的保存值。若要避免这种问题的出现，每次使用该方法时请明确设置这些参数。 可以使用 FindNext和 FindPrevious方法重复搜索。 当搜索到指定的搜索区域的末尾时，本方法将绕回到区域的开始继续搜索。发生绕转后，若要停止搜索，请保存第一个找到的单元格地址，然后依据该保存地址测试每个后续查找到的单元格地址。 若要进行更为复杂的模式匹配查找，请用 For Each...Next 语句和 Like 运算符。例如，下列代码在单元格区域 A1:C5 中搜索字体名称以“Cour”开始的单元格。当 Microsoft Excel 找到匹配单元格以后，就将其字体改为“Times New Roman”。 For Each c In [A1:C5]       If c.Font.Name Like "Cour*" Then        c.Font.Name = "Times New Roman"      End If Next -------------------------------------------------------- 下面是几个兰色版主以前的教学示例代码： Sub Find1() '在某列查找 Dim k k = Range("A:A").Find("A").Row MsgBox k End Sub Sub Find11() '在多列查找 Dim k k = Range("A:B").Find("BCD").Row MsgBox k End Sub Sub Find2() '查找的起始位置 Dim k k = Range("A:B").Find("A", AFTER:=Range("A5")).Row MsgBox k End Sub Sub Find3() '在值中查找 Dim k k = Range("B:B").Find("SE", LookIn:=xlValues).Row MsgBox k End Sub Sub Find31() '在公式中查找 Dim k k = Range("B:B").Find("C2", LookIn:=xlFormulas).Address MsgBox k End Sub Sub Find32() '在备注中查找 Dim k k = Range("B:C").Find("AB", LookIn:=xlComments).Address MsgBox k End Sub Sub Find41() '按模糊查找    Dim k k = Range("B:C").Find("A", LookIn:=xlValues, LOOKAT:=xlPart).Address MsgBox k End Sub Sub Find42() '匹配查找    Dim k k = Range("B:C").Find("A", LookIn:=xlValues, LOOKAT:=xlWhole).Address MsgBox k End Sub Sub Find5() '按先行后列的方式查找    Dim k k = Range("A:B").Find("AB", LookIn:=xlValues, LOOKAT:=xlWhole, SEARCHORDER:=xlByRows).Address MsgBox k End Sub Sub Find51() '按先列后行的方式查找 Dim k k = Range("A:B").Find("AB", LookIn:=xlValues, LOOKAT:=xlWhole, SEARCHORDER:=xlByColumns).Address MsgBox k End Sub Sub Find6() '查找方向(从后向前) Dim k k = Range("A:A").Find("A", , xlValues, xlWhole, xlByColumns, xlPrevious).Address MsgBox k End Sub Sub Find61() '查找方向(从前向后) Dim k k = Range("A:A").Find("A", , xlValues, xlWhole, xlByColumns, xlNext).Address MsgBox k End Sub Sub Find7() '字母大小写 Dim k k = Range("a:b").Find("a", , xlValues, xlWhole, xlByColumns, xlNext, False).Address MsgBox k End Sub Sub f7() '查找不到的情况 Dim MRG As Range Set MRG = Range("A:A").Find("D")   If MRG Is Nothing Then     MsgBox "查找不到字母D"   Else     MsgBox "查找成功,单元格地址为:" & MRG.Address   End If End Sub Sub f8() '二次查找 Dim MRG As Range Set MRG = Range("A:A").Find("A") Set mrg1 = Range("A:A").FindNext(MRG) MsgBox mrg1.Address End Sub Sub F9() '区域查找 Dim MRG As Range, AAA As String Set MRG = Range("A1:F16").Find("A") AAA = MRG.Address Do    Set MRG = Range("A1:F16").FindNext(MRG)    MsgBox MRG.Address Loop Until MRG.Address = AAAEnd Sub

jiangwh15

谢谢楼主的分享