[求助]请教数据字典的基本原理如何？

向您问好

在VBA中有一个数据字典即dictionary功能很好，运行速度比较快，掌握以后可以替代一些其他查找功能，现向老师请教数据字典即dictionary的基本原理是怎样的，它适合于哪些情况之下可以运用，在运用过程中应当注意哪些问题。

谢谢！

向您问好

“基本原理”就改为“基本思路”吧，请看一下

northwolves

Methods: VBScript Dictionary Object

VBScript Dictionary Object Add Method	Adds a key, item pair.
VBScript Dictionary Object Exists Method	Indicates if a specified key exists.
VBScript Dictionary Object Items Method	Returns an array containing all items in a Dictionary object.
VBScript Dictionary Object Keys Method	Returns an array containing all keys in a Dictionary object.
VBScript Dictionary Object Remove Method	Removes a key, item pair.
VBScript Dictionary Object RemoveAll Method	Removes all key, item pairs.

Properties: VBScript Dictionary Object

VBScript Dictionary Object CompareMode Property	The comparison mode for string keys.
VBScript Dictionary Object Count Property	The number of items in a Dictionary object.
VBScript Dictionary Object Item Property	An item for a key.
VBScript Dictionary Object Key Property	A key

northwolves

1.

Dictionary 物件

               

描述

物件，用於儲存資料關鍵字和項目對。

語法

Scripting.Dictionary

請注意

Dictionary 物件與 PERL 相關陣列全等。可以是任何型式的資料的項目被儲存在陣列中。每個項目都與一個唯一的關鍵字相關。該關鍵字用來取出單個項目，通常是整數或字串，可以是除陣列外的任何型態。

下面的程式碼舉例說明了如何建立一個 Dictionary 物件：

Dim d                   '建立一個變數
Set d = CreateObject(Scripting.Dictionary)
d.Add "a", "Athens"     '加入一些關鍵字和項目
d.Add "b", "Belgrade"d.Add "c", "Cairo"
...

2.

Key 屬性
         
描述
在一個 Dictionary 物件中設定一個 key。
語法
object.Key(key) = newkey
Key 屬性具有下列單元：
單元
描述
object
必要引數。始終是一個 Dictionary 物件的名字。
key
必要引數。被更改的 Key。
newkey
必要引數。取代指定 key 的新。

請注意
如果在更改某個 key 時，沒有找到 key，則會出現執行階段錯誤。
3.
Item 屬性
         
描述
對 Dictionary 物件中指定的Key，設定或傳回一個Item 。對於集合來說，基於指定的Key，傳回一個Item。讀取/寫入屬性。
語法
object.Item(key) [= newitem]
Item 屬性具有下列單元：
單元
描述
object
必要引數。始終是一個集合或 Dictionary 物件的名稱。
key
必要引數。與被取出或加入的項目相關的 Key 。
newitem
選擇性引數。僅用於 Dictionary 物件；沒有用於集合的應用程式。如果提供的話，newitem 是與指定的 Key 相關的新值。

請注意
如果在改變某個 item 時，沒有找到 key，則用指定的newitem建立一個新的 key。如果在試圖傳回某個已存在項目時，沒有找到 key，則建立一個新 key，且其相對的項目為無。
4.
Count 屬性
         
描述
傳回集合或 Dictionary 物件中的項目數。唯讀。
語法
object.Count
object 始終是「適用於」清單中某一項目的名稱。
請注意
下面的程式碼舉例說明了 Count 屬性的使用方法：
Dim a, d, i             '建立一些變數
Set d = CreateObject("Scripting.Dictionary")
d.Add "a", "Athens"     '加入一些關鍵字和項目。
d.Add "b", "Belgrade"
d.Add "c", "Cairo"
a = d.Keys              '獲得關鍵字
For i = 0 To d.Count -1 '遍及陣列
    Print a(i)          '列印關鍵字
Next
...
5.
CompareMode 屬性
         
描述
設定或傳回 Dictionary 物件中的比較字串關鍵字的比較模式。
語法
object.CompareMode[ = compare]
CompareMode 屬性具有下列單元：
單元
描述
object
必要引數。始終是一個 Dictionary 物件的名稱。
compare
選擇性引數。如果提供的話，compare 是一個代表比較模式的，該比較模式用於像 StrComp 這樣的函數。

設定
compare 引數可以具有下列值：
常數
 
描述
VbUseCompareOption
-1
使用 Option Compare 陳述式的設定進行比較。
vbBinaryCompare
 0
進行二進位比較。
vbTextCompare
 1
進行文字比較。
vbDatabaseCompare
 2
僅用於 Microsoft Access。進行基於您自己資料庫中資訊的比較。

請注意
如果試圖對已經包含資料的 Dictionary 物件的比較模式進行更改的話，就會出錯。
CompareMode 屬性所用的引數與 StrComp 函數所用的 compare 引數相同。可以用大於 2 的表示使用指定的 Locale IDs (LCID) 的比較。

northwolves

dictionary方法：

1

Add 方法 (目錄)

         

描述

加入一對相對應的關鍵字和項目到 Dictionary 物件。

語法

object.Add key, item

Add方法的語法有如下幾個單元：

單元	描述
Object	必要引數。一個 Dictionary 物件的名字。
Key	必要引數。與所加入的項目相關的關鍵字。
Item	必要引數。與所加入的關鍵字相關的項目。

請注意

如果該關鍵字已經存在，則產生一個錯誤。

2

Exists 方法

         

描述

如果在 Dictionary 物件中指定的關鍵字存在，傳回 True，若不存在，傳回 False。

語法

object.Exists(key)

Exists 方法語法有如下幾個單元：

單元	描述
Object	必要引數。始終是一個 Dictionary 物件的名字。
Key	必要引數。在 Dictionary 物件中搜尋的 Key 值。

3

Keys 方法

         

描述

傳回一個陣列，該陣列包含一個 Dictionary 物件中的全部既存的的關鍵字。

語法

object.Keys

object始終是一個 Dictionary 物件的名字。

請注意

下面的程式碼舉例說明了 Keys 方法的使用。

Dim a, d, i             '建立一些變數
Set d = CreateObject("Scripting.Dictionary")
d.Add "a", "Athens"     '加入一些關鍵字和項目。
d.Add "b", "Belgrade"
d.Add "c", "Cairo"
a = d.keys              '取得關鍵字
For i = 0 To d.Count -1 '重複陣列
    Print a(i)          '列印關鍵字
Next
...

4

Items 方法

         

描述

傳回一個包含 Dictionary 物件中所有項目的陣列。

語法

object.Items

object始終是一個 Dictionary 物件的名字。

請注意

下面的程式碼舉例說明了 Items 方法的使用。:

Dim a, d, i             '建立一些變數
Set d = CreateObject("Scripting.Dictionary")
d.Add "a", "Athens"     '加入一些關鍵字和項目。
d.Add "b", "Belgrade"
d.Add "c", "Cairo"
a = d.Items             '取得項目
For i = 0 To d.Count -1 '重複陣列
    Print a(i)          '列印項目
Next
...

5

Remove 方法

         

描述

從一個 Dictionary 物件中移除一個關鍵字和項目對。

語法

object.Remove(key)

Remove 方法語法有如下幾個單元：

單元	描述
Object	必要引數。始終是一個 Dictionary 物件的名字。
Key	必要引數。Key 與要從 Dictionary 物件中移除的關鍵字和項目對相關。

請注意

如果指定的關鍵字和項目對不存在，則發生一個錯誤。

下面的程式碼舉例說明了 Remove 方法的使用：

Dim a, d, i             '建立一些變數
Set d = CreateObject("Scripting.Dictionary")
d.Add "a", "Athens"     '加入一些關鍵字和項目
d.Add "b", "Belgrade"
d.Add "c", "Cairo"
...
a = d.Remove()
		

6

RemoveAll 方法
         
描述
RemoveAll 方法從 Dictionary 物件中移除所有關鍵字和項目對。
語法
object.RemoveAll
object始終是一個 Dictionary 物件的名字。
請注意
下面的程式碼舉例說明了 RemoveAll 方法的用法：
Dim a, d, i             '建立一些變數
Set d = CreateObject("Scripting.Dictionary")
d.Add "a", "Athens"     '加入一些關鍵字和項目
d.Add "b", "Belgrade"
d.Add "c", "Cairo"
...
a = d.RemoveAll
				

向您问好

太谢谢狼版主啦，真是无价之宝呀，我要好好学习一下，致敬！

northwolves

Dictinary.keys返回一维数组，因而应用比较广泛

应用实例1（顺序显示1-100）：

Sub usage()
Dim dic As Object, i As Long
Set dic = CreateObject("Scripting.Dictionary")
For i = 1 To 100
dic.Add i, ""
Next
MsgBox Join(dic.keys, ",")

Set dic=Nothing
End Sub

应用实例2（显示1-100中含3的整数）：

Sub usage2()
Dim dic As Object, i As Long
Set dic = CreateObject("Scripting.Dictionary")
For i = 1 To 100
dic.Add i, ""
Next
MsgBox Join(Filter(dic.keys, "3"), vbCrLf)

Set dic=Nothing
End Sub

应用实例3（WORKSHEET中A列显示1-10000）：

Sub usage3()
Dim dic As Object, i As Long, arr
Set dic = CreateObject("Scripting.Dictionary")
For i = 1 To 10000
dic.Add i, ""
Next
arr = WorksheetFunction.Transpose(dic.keys)
[a1].Resize(UBound(arr), 1) = arr
Set dic = Nothing
End Sub

应用实例4 (WORKSHEET中A列显示1 - 10000，B列逆序显示):

Sub usage4()
Dim dic As Object, i As Long, arr
Set dic = CreateObject("Scripting.Dictionary")
For i = 1 To 10000
dic.Add i, 10001 - i
Next
arr = WorksheetFunction.Transpose(dic.keys)
[a1].Resize(UBound(arr), 1) = arr

arr = WorksheetFunction.Transpose(dic.items)
[b1].Resize(UBound(arr), 1) = arr

Set dic = Nothing
End Sub

应用实例5 (WORKSHEET中A列显示1 - 100000中被6除余1和5 的数字):

Sub usage5()
Dim dic As Object, i As Long, arr
Set dic = CreateObject("Scripting.Dictionary")
For i = 1 To 100000
dic.Add i & IIf(Abs(i Mod 6 - 3) = 2, "@", ""), ""
Next

arr = WorksheetFunction.Transpose(Filter(dic.keys, "@"))
[a1].Resize(UBound(arr), 1) = arr
[a:a].Replace "@", ""
Set dic = Nothing
End Sub

应用实例6 (跨表不重复值提取):

Sub Usage6()
Application.ScreenUpdating = False
Dim r As Range, arr
Worksheets("All").Select
With CreateObject("scripting.dictionary")
For Each r In Range("D3:D" & Range("A65536").End(xlUp).Row)
If Not .exists(r.Value) Then .Add r.Value, Nothing
Next
Worksheets("temp").Select
Cells.Clear
Range("a2").Resize(.Count, 1) = WorksheetFunction.Transpose(.keys)
End With
Application.ScreenUpdating = True
End Sub

应用实例7 (COMBOBOX赋值):

Private Sub UserForm_Initialize()
Dim dic As Object, i As Long, arr
Set dic = CreateObject("Scripting.Dictionary")
For i = 1 To 1000
dic.Add i, ""
Next
UserForm1.ComboBox1.List = dic.keys
Set dic = Nothing
End Sub

向您问好

严重向狼老师学习您的高尚品格

向您问好

狼老师的经典杰作再顶一下，我认为加精1分不多，应该加5分

northwolves

'应用实例8 (字符频率统计):

'本例统计圆周率前500位中各数字出现的频率并显示在WORKSHEET的前两行
Sub Usage8()
Const pi As String = "3.14159265358979323846264338327950288419716939937510582097494459230781640628620899862803482534211706798214808651328230664709384460955058223172535940812848111745028410270193852110555964462294895493038196442881097566593344612847564823378678316527120190914564856692346034861045432664821339360726024914127372458700660631558817488152092096282925409171536436789259036001133053054882046652138414695194151160943305727036575959195309218611738193261179310511854807446237996274956735188575272489122793818301194912"
Dim i As Long, temp As String, dic As Object
Set dic = CreateObject("scripting.dictionary")
For i = 3 To Len(pi)
temp = Mid(pi, i, 1)
If Not dic.exists(temp) Then
dic.Add temp, 1
Else
dic(temp) = dic(temp) + 1
End If
Next
[a1:a2] = WorksheetFunction.Transpose(Array("Number", "出现次数"))
[b1].Resize(1, dic.Count) = dic.keys
[b2].Resize(1, dic.Count) = dic.items
Set dic = Nothing
End Sub

'本例统计某字符串中各字符出现的频率并显示在WORKSHEET的前两行

Sub Usage8_2()
Const s As String = "在VBA中有一个数据字典即dictionary功能很好，运行速度比较快，掌握以后可以替代一些其他查找功能，现向老师请教数据字典即dictionary的基本原理是怎样的，它适合于哪些情况之下可以运用，在运用过程中应当注意哪些问题。"
Dim i As Long, temp As String, dic As Object
Set dic = CreateObject("scripting.dictionary")
For i = 1 To Len(s)
temp = Mid(s, i, 1)
If Not dic.exists(temp) Then
dic.Add temp, 1
Else
dic(temp) = dic(temp) + 1
End If
Next
[a1:a2] = WorksheetFunction.Transpose(Array("字符", "出现次数"))
[b1].Resize(1, dic.Count) = dic.keys
[b2].Resize(1, dic.Count) = dic.items
Set dic = Nothing
End Sub