[讨论]如何枚舉控件屬性？？？

lirong

例：在表單上有一個文本框控件請教如何用代碼枚舉這個控件都有那些屬性？？？

northwolves

'引用TypeLib Information

Sub listcontrols()
Cells(1, 1) = "控件"
Cells(1, 2) = "属性，方法，事件"
Cells(1, 3) = "值"
[a1:c1].Interior.ColorIndex = 3
          On Error Resume Next
          Dim ctl     As Object, n As Long
          n = 1
          For Each ctl In UserForm1.Controls
                  Dim iInf     As InterfaceInfo
                  Set iInf = InterfaceInfoFromObject(ctl)
                  If Not (iInf Is Nothing) Then
                          Dim mem     As MemberInfo
                          For Each mem In iInf.Members
                                  If mem.InvokeKind Then
                                  n = n + 1
Cells(n, 1) = ctl.Name
Cells(n, 2) = mem.Name
Cells(n, 3) = CallByName(ctl, mem.Name, VbGet)
                                  End If
                          Next
                  End If
          Next
[a1:c65536].Columns.AutoFit
End Sub

清风_ll

Test Ok!

TypeLib Information--->引用TLBINF32.Dll

Aeolian-Vox

发现 2 楼代码运行后，控件的属性值被列出两次？

控件	属性，方法，事件	值
ComboBox1	QueryInterface
ComboBox1	AddRef
ComboBox1	Release
ComboBox1	GetTypeInfoCount
ComboBox1	GetTypeInfo
ComboBox1	GetIDsOfNames
ComboBox1	Invoke
ComboBox1	Cancel
ComboBox1	Cancel
ComboBox1	ControlSource
ComboBox1	ControlSource
ComboBox1	ControlTipText
ComboBox1	ControlTipText
ComboBox1	Default
ComboBox1	Default

ComboBox1	Height	24
ComboBox1	Height	24
ComboBox1	HelpContextID	0
ComboBox1	HelpContextID	0

[此贴子已经被作者于2006-11-3 18:21:57编辑过]

northwolves

修改如下：

Sub listcontrols()
Cells(1, 1) = "控件"
Cells(1, 2) = "属性，方法，事件"
Cells(1, 3) = "值"
[a1:c1].Interior.ColorIndex = 3
          On Error Resume Next
          Dim ctl     As Object, n As Long
          n = 1
          For Each ctl In UserForm1.Controls
                  Dim iInf     As InterfaceInfo
                  Set iInf = InterfaceInfoFromObject(ctl)
                  If Not (iInf Is Nothing) Then
                          Dim mem     As MemberInfo
                          For Each mem In iInf.Members
                                  If mem.InvokeKind And INVOKE_PROPERTYGET Then
                                  n = n + 1
Cells(n, 1) = ctl.Name
Cells(n, 2) = mem.Name
Cells(n, 3) = CallByName(ctl, mem.Name, VbGet)
                                  End If
                          Next
                  End If
          Next
[a1:c65536].Columns.AutoFit
End Sub

Aeolian-Vox

另外：窗体(UserForm1)的属性等值是否可以一起列出？[em10]

qee用

[em17]
学习!

xq1234

向northwolves版主敬礼[em17][em17][em17]、献花！[em23][em23][em23][em23][em23]

northwolves

QUOTE:

以下是引用Aeolian-Vox在2006-11-3 18:40:21的发言：
另外：窗体(UserForm1)的属性等值是否可以一起列出？[em10]

http://northwolves.blog.excelhome.net/user1/northwolves/archives/2006/715.html

Sub EnumUserForms()
On Error Resume Next
    Dim i As Long, j As Long, n As Long
        With ThisWorkbook.VBProject.VBComponents
        For i = 1 To .Count
            If .Item(i).Type = 3 Then
                For j = 1 To ThisWorkbook.VBProject.VBComponents(i).Properties.Count
                n = n + 1
                    Cells(n, 1) = ThisWorkbook.VBProject.VBComponents(i).Name
                    Cells(n, 2) = ThisWorkbook.VBProject.VBComponents(i).Properties(j).Name
                    Cells(n, 3) = ThisWorkbook.VBProject.VBComponents(i).Properties(j)
                Next j
            End If
        Next
    End With
End Sub

Aeolian-Vox

谢谢northwolves版主。

需要说明的一点是使用该程序之前，先勾选 信任对于‘Visual Basic项目’的访问