[讨论] 集合类的建立（类似WorkSheets和WorkSheet）

lee1892

VB中有大量的集合类，如Excel VBA中的WorkSheets和WorkSheet这样的，前者是后者的集合。

在实际使用中，我们会注意到这样的用法：
WorkSheets("Sheet1")
其等效于
WorkSheets.Item("Sheet1")

实际上利用的是VB中的默认属性，在VBA中这个属性是不显示的，但可以通过如下办法手动添加：
1、导出类模块文件
2、用文本编辑器编辑导出的文件，在所需要设置的默认属性段内加一行：

1. Attribute Value.VB_UserMemId = 0

复制代码

3、移除VBA中的该文件，导入编辑过的类模块文件

以本贴附件为例，在文本编辑器中打开会是这样的

1. VERSION 1.0 CLASS
   
2. BEGIN
   
3.   MultiUse = -1  'True
   
4. End
   
5. Attribute VB_Name = "CupCakes"
   
6. Attribute VB_GlobalNameSpace = False
   
7. Attribute VB_Creatable = False
   
8. Attribute VB_PredeclaredId = False
   
9. Attribute VB_Exposed = False
   
10. Option Explicit
    
11. 
    
12. Private colCakes As Collection
    
13. 
    
14. Private Sub Class_Initialize()
    
15.     Set colCakes = New Collection
    
16. End Sub
    
17. Private Sub Class_Terminate()
    
18.     Dim oCake As CupCake
    
19.     For Each oCake In colCakes
    
20.         Set oCake = Nothing
    
21.         colCakes.Remove 1
    
22.     Next
    
23.     Set colCakes = Nothing
    
24. End Sub
    
25. 
    
26. Property Get Item(Index) As CupCake
    
27.     Attribute Value.VB_UserMemId = 0
    
28.     Set Item = colCakes(Index)
    
29. End Property
    
30. 
    
31. Property Get Count() As Integer
    
32.     Count = colCakes.Count
    
33. End Property
    
34. 
    
35. Public Function Add(Optional ByVal Name As String) As CupCake
    
36.     If Len(Name) = 0 Then
    
37.         Name = "CupCake " & colCakes.Count + 1
    
38.     End If
    
39.     Set Add = New CupCake
    
40.     Add.Name = Name
    
41.     colCakes.Add Add, Name
    
42. End Function

复制代码

这样一来，就可以把 Item 属性作为默认属性，从而在实际使用中可以省略掉，比如附件中的测试过程：

1. Sub Test()
   
2.     Dim oCakes As New CupCakes, oCake As CupCake
   
3.     Dim i%
   
4.     With oCakes
   
5.         Debug.Print oCakes.Count
   
6. 
   
7.         Set oCake = .Add("MyCake")
   
8.         With oCake
   
9.             .Size = ckMiddle
   
10.             .CakeType = ckChocolate
    
11.         End With
    
12. 
    
13.         With .Add("HisCake")
    
14.             .Size = ckBig
    
15.             .CakeType = ckStrawberry
    
16.         End With
    
17.     End With
    
18. 
    
19.     With oCakes("MyCake")
    
20.         Debug.Print .Name; .Size; .CakeType
    
21.         Debug.Print
    
22.     End With
    
23.     With oCakes.Item("MyCake")
    
24.         Debug.Print .Name; .Size; .CakeType
    
25.         Debug.Print
    
26.     End With
    
27. 
    
28.     For i = 1 To oCakes.Count
    
29.         With oCakes(i)
    
30.             Debug.Print .Name; .Size; .CakeType
    
31.         End With
    
32.     Next
    
33. 
    
34.     oCakes.Remove "MyCake"
    
35.     Debug.Print oCakes.Count
    
36.     ' 下述For Each不能使用
    
37.     'For Each oCake In oCakes
    
38.     '    Debug.Print oCake.Name
    
39.     'Next
    
40.     Set oCakes = Nothing
    
41. End Sub

复制代码

但这个办法存在一个问题，就是这样的集合类是不支持 For Each 循环的。

欢迎讨论~

=============
附件加了3楼的办法
要支持 For Each 的话，需要如上述导出到文件，再用文本编辑器编辑，再导入。添加下述代码

1. Public Function NewEnum() As IUnknown
   
2.    Attribute NewEnum.VB_UserMemId = -4
   
3.    Set NewEnum = colCakes.[_NewEnum]
   
4. End Function

复制代码

此处的 colCakes 是用来存放类CupCake的内部集合对象，_NewEnum是集合对象的一个隐藏的方法需要用 [ ] 标识，前面一句设该方法的 UserMemId 为-4 是在VB中隐藏该方法，但在VBA中实际上并没有隐藏，但在VBA中必须设置才能正常使用。

gotomiss

谢谢您。这正是我想要的。太棒了！
可以解释下 Attribute Value.VB_UserMemId = 0。这句的意思吗

wcymiss

加入这些就可以for each了：

Public Function NewEnum() As IUnknown
Attribute NewEnum.VB_UserMemId = -4
   Set NewEnum = colCakes.[_NewEnum]
End Function

参考资料：
https:/ /msdn.microsoft.com/en-us/library/aa262338(v=vs.60).aspx

Moneky

谢分享，收藏备用。记得曾经做了个数三角形的文件，中间用到了，也受楼主指点，谢谢！

jpj123

先收藏，以后慢慢学习!

ak47ok

每次回帖、谢谢！辛苦了。

看天的小树

楼主精神可嘉，值得肯定

ak47ok

每次回帖、谢谢！辛苦了。

用心修炼

先打卡，以后慢慢研究，

myail

看不懂。先打卡，以后慢慢研究，