VBA高级教程之字典篇，使用类模块实现字典一对多应用

liucqa · 发表于 2013-11-3 18:16

本帖最后由 liucqa 于 2013-11-4 19:53 编辑

字典一对多一直是初学者头疼的问题，在字典的item中不能使用type自定义类型，错误如下：
捕获.JPG

因此，在大多数的例子中，初学者都使用字典+数组的方式来实现一对多。
然而，字典+数组的替代方式会使代码的易读性显著下降，也容易给日后代码维护带来麻烦。那么，正规的做法是什么呢？

实际上，我们可以采用类模块的方式来定义一个带有多个属性的类，用这个类来代替数组实现一对多，这样的代码会变的清晰可读，方便理解。

标准模块

Sub test()
Dim dic As Object, i&
Dim item As clsItem
Set dic = CreateObject("Scripting.Dictionary") '后期绑定引用字典对象
For i = 1 To 3
Set item = New clsItem
item.name = "name" & i
item.id = "id" & i
item.idx = i
dic.Add "key" & i, item
Set item = Nothing
Next
MsgBox dic("key2").idx & vbCrLf & dic("key2").id & vbCrLf & dic("key2").name
Set dic = Nothing
End Sub

复制代码

类模块 clsItem，定义所有需要的属性

Public name As String
Public id As String
Public idx As Long

复制代码

提醒新人注意：
上述代码重点是编程思路的转变，而不仅仅是编程代码的技巧问题。

liucqa · 发表于 2013-11-3 19:09

本帖最后由 liucqa 于 2013-11-3 19:20 编辑

如果需要将数据放入数组，以方便在工作表中输出，也可以采用类模块解决。

类模块clsItem 代码

Option Explicit
Public name As String
Public id As String
Public idx As Long
Private data()
Public Sub RedimData(ByVal l As Long, ByVal r As Long)
ReDim data(l To r)
End Sub
Public Sub InputData(ByVal str As String, ByVal i As Long)
data(i) = str
End Sub
Public Property Get Outputdata() As Variant
Outputdata = data
End Property
Private Sub Class_Initialize()
End Sub
Private Sub Class_Terminate()
Erase data
End Sub

复制代码

标准模块代码

Sub testCls()
Dim dic As Object, i&, j&
Dim item As clsItem
Set dic = CreateObject("Scripting.Dictionary") '后期绑定引用字典对象
For i = 1 To 3
Set item = New clsItem
item.name = "name" & i
item.id = "id" & i
item.idx = i
'定义用于输出的数组大小
Call item.RedimData(0, 3)
For j = 0 To 3
Call item.InputData("key" & i & "data" & j, j) '给数组赋值
Next
dic.Add "key" & i, item
Set item = Nothing
Next
[A1:C1] = dic("key2").Outputdata '输出
Set dic = Nothing
End Sub

复制代码

附件下载

字典一对多，类模块.rar (19.4 KB, 下载次数: 1850)

banjinjiu · 发表于 2013-11-3 21:06

本帖最后由 banjinjiu 于 2013-11-3 21:21 编辑

1、能否请楼主给我们新手注释下，有些不懂。
2、clsItem是类模块，Set item = New clsItem，这里的 clsItem 是新工程模块？还是类模块的名字？用本地窗口看的似懂非懂。

liucqa · 发表于 2013-11-3 22:47

本帖最后由 liucqa 于 2013-11-3 23:06 编辑

什么是实例化？

这样理解，你把一个游戏程序装到电脑上，这个游戏就是一个类。没运行之前，你是不能玩的。
你双击打开它，就算是一个实例，可以玩游戏了。再打开一个，又是一个实例，还可以玩同样的游戏 --------------------- 我们都管这个叫多开。
虽然你打开两次，但是两个游戏窗口是独立的，这个游戏失败了，不影响另一个，另一个可能是赢的。

所谓类模块，和上面说的道理是一样一样的。

你建立了类模块，就相当于安装一个游戏，
类模块的实例化，就相当于打开游戏程序，类模块被加载到内存，可以操作了。
游戏可以多开，类模块也可以多次实例化。
每一个多开的游戏都是独立的，每一个实例化的类，也是独立占用内存的，可以独立操作

能理解否？如果你玩网游的话，用下副本理解也可以，具体我就不举例子了。

实在不能理解的话，过半年再来看这个帖子吧

luyibiao · 发表于 2013-11-3 22:34

感谢楼主分享，收藏、学习！

liucqa · 发表于 2013-11-3 22:38

本帖最后由 liucqa 于 2013-11-25 08:25 编辑

banjinjiu 发表于 2013-11-3 21:06
1、能否请楼主给我们新手注释下，有些不懂。
2、clsItem是类模块，Set item = New clsItem，这里的 clsIte ...

VB6的工程中可以添加2种模块，一是标准模块，二是类模块

标准模块 - 也是所谓公共模块，在其中用public声明的所有变量、对象、函数和过程，可以在整个工程中，被其它任何对象直接调用，比如，你在其中声明了上述朋友声明的那个函数：
Public Function myadd(a As Long, b As Long) As Long
myadd = a + b
End Function
它在包括窗体，类中都可以直接使用...

类模块 - 它是对象（类似Range或者Worksheet，标准模块不是对象），对象就有自己的的属性方法事件等等，对象要实例化以后才能调用其属性方法和事件。

通俗的比喻一下类（不是很严格），人类就好比一个类，人有性别，体重，年龄，技能等等，这些就是所谓属性和方法，要具体到某一个人（所谓实例化），这些属性方法才有具体内容....比如我们添加一个类模块,名称为human, 声明如下：
public name as string
public sex as string
public age as long
Public Function myadd(byval a As Long, byval b As Long) As Long
myadd = a + b
End Function

要某个地方要用这个类的时候，首先要声明并实例化：
dim man as human                                  '声明类
set man=new human       '实例化..这样就可以使用这个类了

man.name="张三" '这个人叫张三
man.sex="男"  '男性
man.age=23  '23岁
msgbox man.myadd(100,200)  '调用这个实例的方法

set man=nothing  '释放对象

以上只供参考，具体可以看书或MSDN

chhddi · 发表于 2013-11-3 23:02

跟着楼主学习字典了。谢谢！

liucqa · 发表于 2013-11-4 11:28

http://club.excelhome.net/forum. ... p;page=2#pid7278624

字典的原理

xiach · 发表于 2013-11-4 14:21

学习了,谢谢！发现自己要学的东西太多了!

4me · 发表于 2013-11-4 16:21

再有实际应用的例子就更好。

		自动登录	找回密码
密码			免费注册

VBA高级教程之字典篇，使用类模块实现字典一对多应用

评分

点评

评分