关于用EXCEL_VBA调用Windows_API 计算MD5的问题!

老谭酸菜 · 发表于 2013-7-15 11:03

我想在EXCEL_VBA中计算MD5。虽然网上有用纯VBA实现的MD5程序，可速度还是太慢了。用API来计算应该快很多！可惜找了很久也没找到在VBA下调用API计算MD5的例子。自己试着写了一个试验程序，可就是通不过！
有哪位大佬可以帮我解决这个问题吗？
我写的试验程序如下：

Declare Function MD5Init Lib "Cryptdll.dll" (ctx As md5_ctx) As Variant
Declare Function MD5Update Lib "Cryptdll.dll" (ctx As md5_ctx, ByVal buf As String, ByVal lend As Integer) As Variant
Declare Function MD5Final Lib "Cryptdll.dll" (ctx As md5_ctx) As Variant
Type md5_ctx
i(1) As Long
buf(3) As Long
inp(63) As String
digest(15) As String
End Type

Sub aaa()
Dim ctx As md5_ctx, buf As String, lend As Integer

buf = "12334"
lend = Len(buf)
MD5Init (ctx) '此处通不过！
a = MD5Update(ctx, buf, lend)
MD5Final (ctx)
End Sub

老谭酸菜 · 发表于 2013-7-15 12:39

快沉了，自己顶一下！有高手愿意帮忙吗？

Moneky · 发表于 2013-7-15 13:12

本帖最后由 Moneky 于 2013-7-15 13:31 编辑

参考这里的代码试试：http://www.mathtool.cn/computer/system/395.htm

Option Explicit
Option Base 0
Public Type MD5_CTX
i(1) As Long
buf(3) As Long
inc(63) As Byte
digest(15) As Byte
End Type
Public Declare Sub MD5Init Lib "Cryptdll.dll" (ByVal pContex As Long)
Public Declare Sub MD5Final Lib "Cryptdll.dll" (ByVal pContex As Long)
Public Declare Sub MD5Update Lib "Cryptdll.dll" (ByVal pContex As Long, ByVal lPtr As Long, ByVal nSize As Long)
Public Function ConvBytesToBinaryString(bytesIn() As Byte) As String
Dim i As Long
Dim nSize As Long
Dim strRet As String
nSize = UBound(bytesIn)
For i = 0 To nSize
strRet = strRet & Right$("0" & Hex(bytesIn(i)), 2)
Next
ConvBytesToBinaryString = strRet
End Function
Public Function GetMD5Hash(bytesIn() As Byte) As Byte()
Dim ctx As MD5_CTX
Dim nSize As Long
nSize = UBound(bytesIn) + 1
MD5Init VarPtr(ctx)
MD5Update ByVal VarPtr(ctx), ByVal VarPtr(bytesIn(0)), nSize
MD5Final VarPtr(ctx)
GetMD5Hash = ctx.digest
End Function
Public Function GetMD5Hash_Bytes(bytesIn() As Byte) As String
GetMD5Hash_Bytes = ConvBytesToBinaryString(GetMD5Hash(bytesIn))
End Function
Public Function GetMD5Hash_String(ByVal strIn As String) As String
GetMD5Hash_String = GetMD5Hash_Bytes(StrConv(strIn, vbFromUnicode))
End Function
Public Function GetMD5Hash_File(ByVal strFile As String) As String
Dim lFile As Long
Dim bytes() As Byte
Dim lSize As Long
lSize = FileLen(strFile)
If (lSize) Then
lFile = FreeFile
ReDim bytes(lSize - 1)
Open strFile For Binary As lFile
Get lFile, , bytes
Close lFile
GetMD5Hash_File = GetMD5Hash_Bytes(bytes)
End If
End Function

复制代码

补充内容 (2020-3-12 18:06):
一晃就七年过去了，时间真是快呀

Moneky · 发表于 2013-7-15 13:37

要获取“1235”的md5可以这样调用

sub test
dim s as string
s=GetMD5Hash_String("1235")
end sub

老谭酸菜 · 发表于 2013-7-15 14:09

Moneky 发表于 2013-7-15 13:12
参考这里的代码试试：http://www.mathtool.cn/computer/system/395.htm

{:soso_e179:} 非常感谢！正是我需要的！正在调试，看看比纯VBA的快多少。

老谭酸菜 · 发表于 2013-7-15 18:30

Moneky 发表于 2013-7-15 13:37
要获取“1235”的md5可以这样调用

sub test

再次感谢！我是要用MD5码来做散列，查找重复行。刚才测试了一下，API 散列的速度是纯VBA散列速度的10倍！现在用VBA程序查找1亿1千9百万行文本重复情况耗时是45小时，网上下载的免费程序要耗时15个月！

Moneky · 发表于 2013-7-15 18:51

老谭酸菜发表于 2013-7-15 18:30
再次感谢！我是要用MD5码来做散列，查找重复行。刚才测试了一下，API 散列的速度是纯VBA散列速度的10倍！ ...

干什么的啊，那么多数据？

老谭酸菜 · 发表于 2013-7-15 19:03

Moneky 发表于 2013-7-15 18:51
干什么的啊，那么多数据？

呵呵，处理字典文件。网上找的的程序太慢了所以就自己写。算法的力量真神奇！

liucqa · 发表于 2013-7-15 21:03

本帖最后由 liucqa 于 2013-7-15 23:00 编辑

老谭酸菜发表于 2013-7-15 19:03
呵呵，处理字典文件。网上找的的程序太慢了所以就自己写。算法的力量真神奇！

没必要都做hash吧，你看看能不能分两步。

第一步简单判断，第二步hash判断
或者在建立数据的时候，就做个索引表

做hash开销很大的

老谭酸菜 · 发表于 2013-7-28 12:34

liucqa 发表于 2013-7-15 21:03
没必要都做hash吧，你看看能不能分两步。

第一步简单判断，第二步hash判断

这个方法好象行不通哦。要处理的文本行数可能很大，不能用工作表来处理，只能用程序对文件进行处理。VBA数组不能定得太大，否则必定出现溢出错误。对行进行排序比查重复行开销还大。而且要保证输出的结果和原始文件中的行顺序一致，只是去掉了重复的行。当然，可能是我水平不够，还理解不了大侠的思路。
附上的写好的程序，有兴趣的朋友可以帮助改进一下。
另：写好程序的第二天就帮单位处理了一个20多万行的文本，不过不是查重复行，是过滤出包含特定字符串的行。

文本文件截断与过滤1.51.rar (74.44 KB, 下载次数: 94)

		自动登录	找回密码
密码			免费注册

关于用EXCEL_VBA调用Windows_API 计算MD5的问题!

评分