VBA常用技巧代码解析

caicaiw

感觉好难学啊

JC2009

今日發現貴論壇，正好想學習VBA
非常好的論壇

yuanzhuping

技巧188         VBE的操作
188-1        添加模块和过程      
       在工作簿中添加新的模块和过程，除了使用手工添加的方法外，还可以采用程序的方式自动添加，如下面的代码所示。

1. #001  Sub NowModule()
   
2. #002      Dim VBC As VBComponent
   
3. #003      Set VBC = ThisWorkbook.VBProject.VBComponents _
   
4. #004          .Add(vbext_ct_StdModule)
   
5. #005      VBC.Name = "NowModule"
   
6. #006      With VBC.CodeModule
   
7. #007          If .Lines(1, 1) <> "Option Explicit" Then
   
8. #008              .InsertLines 1, "Option Explicit"
   
9. #009          End If
   
10. #010          .InsertLines 2, "Sub Process1()"
    
11. #011          .InsertLines 3, vbTab & "MsgBox ""这是第一个过程!"""
    
12. #012          .InsertLines 4, "End Sub"
    
13. #013          .AddFromString "Sub Process2()" & Chr(13) & vbTab _
    
14. #014              & "MsgBox ""这是第二个过程!""" & Chr(13) & "End Sub"
    
15. #015      End With
    
16. #016      Set VBC = Nothing
    
17. #017  End Sub

复制代码

代码解析：
       NowModule过程在VBE中添加一个“NowModule”模块和两个过程。
       第2行代码声明变量VBC为VBComponent对象。VBComponent对象代表一个包含在工程中的部件，例如类模块或标准模块。
       第3、4行代码使用Add方法添加一个模块。应用于VBComponents集合的Add方法将一个对象添加到集合，语法如下：
       object.Add(component)
       参数object是必需的，一个有效的对象表达式。
       参数component是必需的，对于VBComponents集合，则为表示类模块、窗体、标准模块的列举常数，如表格 所示。
      
       第5行代码将新添加的模块重命名为“NowModule”。
       第7行到第12行代码使用InsertLines方法在新添加的模块中插入过程“Process1”。应用于CodeModule对象的InsertLines方法在一个代码块的某个指定位置，插入一行或多行的代码，语法如下：
       object.InsertLines(line, code)
       参数object是必需的，一个有效的对象表达式。
       参数line是必需的，Long型数据，用来指定要插入代码的位置。
       参数code是必需的，String型数据，插入的代码。
       其中第7行到第9行代码判断模块中首行代码是否为要求变量声明，如不是则添加要求变量声明语句。
       第13、14行代码使用AddFromString方法在新添加的模块中插入过程“Process2”。应用于CodeModule对象的AddFromString方法将文本添加到模块，与InsertLines方法不同的是，所插入文本的位置始终在模块中的第一个过程之前，如果模块中没有包含过程则将插入的文本放置在模块的最后。
       运行NowModule过程，在VBE中添加一个“NowModule”模块以及在模块中添加两个过程，如图所示。


[ 本帖最后由 yuanzhuping 于 2009-6-20 10:18 编辑 ]

yuanzhuping

技巧188         VBE的操作
188-2        建立事件过程
       在使用VBA代码添加工作表后，如果需要在新工作表中添加事件过程，可以使用技巧188-1中的添加代码的方法，但是事件过程一般包含参数，因此此方法容易出错，所以更好的方法是使用CreateEventProc方法，如下面的代码所示。

1. #001  Sub AddMatter()
   
2. #002      Dim Sh As Worksheet
   
3. #003      Dim i As Integer
   
4. #004      For Each Sh In Worksheets
   
5. #005          If Sh.Name = "abc" Then
   
6. #006              MsgBox "工作簿中已有""abc""工作表,不能重复添加!"
   
7. #007              Exit Sub
   
8. #008          End If
   
9. #009      Next
   
10. #010      Set Sh = Sheets.Add(After:=Sheets(Sheets.Count))
    
11. #011      Sh.Name = "abc"
    
12. #012      Application.VBE.MainWindow.Visible = True
    
13. #013      With ThisWorkbook.VBProject.VBComponents(Sh.CodeName).CodeModule
    
14. #014          i = .CreateEventProc("SelectionChange", "Worksheet")
    
15. #015          .ReplaceLine i + 1, vbTab _
    
16. #016              & "MsgBox ""你选择了"" & Target.Address(0, 0) & ""单元格!"""
    
17. #017      End With
    
18. #018      Application.VBE.MainWindow.Visible = False
    
19. #019      Set Sh = Nothing
    
20. #020  End Sub

复制代码

代码解析：
       AddMatter过程在工作簿中新建一张“abc”工作表，并在工作表的SelectionChange事件中写入事件代码。
       第4行到第11行代码使用Add方法在工作簿中新建一张工作表，请参阅技巧25 。
       第12行代码打开VBE窗口。
       第14行代码使用CreateEventProc方法在新添加的工作表中创建“SelectionChange”过程并将起始行号赋给变量i。
       应用于CodeModule对象的CreateEventProc方法创建一个事件过程，语法如下：
       object.CreateEventProc(eventname, objectname) As Long
       参数object是必需的，一个有效的对象表达式。
       参数eventname是必需的，用来指定欲添加到模块的事件名称。
       参数objectname是必需的，用来指定事件源的对象名称。
       CreateEventProc方法创建成功则返回事件过程开始行的行号，其创建的过程只包含一个空行。
       第15、16行代码使用ReplaceLine方法将空行替换为指定的代码。应用于CodeModule对象的ReplaceLine方法用特定的代码代替原代码，语法如下：
       object.ReplaceLine(line, code)
       参数object是必需的，一个有效的对象表达式。
       参数line是必需的，用来指定所要代替的行号。
       参数code是必需的，用来指定要插入的代码。
       第18行代码关闭VBE窗口。
       运行AddMatter过程在工作簿中新建一张“abc”工作表，并在工作表中写入事件代码，如图所示。
      

[ 本帖最后由 yuanzhuping 于 2009-6-23 09:02 编辑 ]

cloudpm

谢谢楼主的分享～！！！！！！！！！！！！！！！

xmi

原帖由 yuanzhuping 于 2009-6-12 17:29 发表
1-10部分的Word文档，请下完5个WinRAR压缩文件后一起解压缩。
529423
529424
529425
529427
529428

第10部分文件操作的附件
529429

第1-9部分的附件请到这里下载。（1273楼）
http://club.excelhome.ne ...

謝謝 謝謝 謝謝 謝謝 謝謝 謝謝

yecdx

辛苦了,向无私奉献的人鞠躬!

tylerli

thanks you very much

BELLCUI

非常感谢分享，打算好好的学习一下VBA

czji

太感谢了，辛苦了。如果有空请你去放松一下