[讨论]多列中查找重复值的最优方案

彭希仁

ygssuNgF.rar (6.61 KB, 下载次数: 537)

2007-10-25 11:07 上传

点击文件名下载附件
[讨论]多列中查找重复值的最优方案

Sub ren()     '在ABC三列中生成60000行随机数。
    ReDim arr(1 To 60000, 1 To 3)
    For i = 1 To 60000
        arr(i, 1) = Fix(Rnd() * 1000000)
        arr(i, 2) = Fix(Rnd() * 1000000)
        arr(i, 3) = Fix(Rnd() * 1000000)
    Next i
    Range(Cells(1, 1), Cells(60000, 3)) = arr
End Sub

现要求找出A列，B列，C列都重复出现的数（即A列B列C列都有这个数），并在D列显示出来。

maditate

要查一个数据在其它两列中的重复好办，要查六万个数据可需要花点时间的。

[此贴子已经被作者于2007-10-25 12:31:00编辑过]

oobird

Private Sub CommandButton1_Click()
  Dim i&, a, b, c, ds As Object, ds1 As Object, ds2 As Object
  Set ds = CreateObject("Scripting.Dictionary")
  Set ds1 = CreateObject("Scripting.Dictionary")
  Set ds2 = CreateObject("Scripting.Dictionary")

  a = [a1:a60000]
  b = [b1:b60000]
  c = [c1:c60000]
  For i = 1 To 60000
    ds(a(i, 1)) = ""
  Next i
  For i = 1 To 60000
    If ds.exists(b(i, 1)) Then ds1(b(i, 1)) = ""
  Next i
  For i = 1 To 60000
    If ds1.exists(c(i, 1)) Then ds2(c(i, 1)) = ""
  Next i
  Cells(1, 4).Resize(ds2.Count, 1) = Application.Transpose(ds2.keys)
  Set ds = Nothing
  Set ds1 = Nothing
  Set ds2 = Nothing

End Sub
先抛块砖吧。

oobird

狼版的教学没看吗？很详尽的。对教学内容有不明白的地方请针对不明白的语句提问，这样好回复，呵呵。

我相信必有更快的，搬张沙发等着瞧呢！

彭希仁

QUOTE:

以下是引用oobird在2007-10-25 13:13:18的发言：

Private Sub CommandButton1_Click()
  Dim i&, a, b, c, ds As Object, ds1 As Object, ds2 As Object
  Set ds = CreateObject("Scripting.Dictionary")
  Set ds1 = CreateObject("Scripting.Dictionary")
  Set ds2 = CreateObject("Scripting.Dictionary")

  a = [a1:a60000]
  b = [b1:b60000]
  c = [c1:c60000]
  For i = 1 To 60000
    ds(a(i, 1)) = ""
  Next i
  For i = 1 To 60000
    If ds.exists(b(i, 1)) Then ds1(b(i, 1)) = ""
  Next i
  For i = 1 To 60000
    If ds1.exists(c(i, 1)) Then ds2(c(i, 1)) = ""
  Next i
  Cells(1, 4).Resize(ds2.Count, 1) = Application.Transpose(ds2.keys)
  Set ds = Nothing
  Set ds1 = Nothing
  Set ds2 = Nothing

End Sub
先抛块砖吧。

好大一块金砖啊，哈哈

张三李四

QUOTE:

以下是引用lenghonghai在2007-10-25 12:58:39的发言：

上述代码5000个数据用了1分钟左右，如果是60000行数据真不知道程序要运行到什么时候，期待有更快的解决办法。

不知道利用ado+sql能不能更快一些呢？

这方面彭兄不是很擅长吗？

你用的是什么电脑，5000个数据用了1分钟。我的电脑还算是比较好的，500个数据还要1分钟呢。用你的代码测试的。

northwolves

针对彭先生的数据,用数组可能更快些:

Sub macro1()
Dim arr, i As Long, j As Long, n As Long, b(1000000) As Long
arr = [A1:C60000].Value
For i = 1 To 60000
b(arr(i, 1)) = 1
Next
For j = 2 To 3
For i = 1 To 60000
b(arr(i, j)) = b(arr(i, j)) * j
Next i, j
ReDim arr(1 To 65536, 1 To 1)
For i = 0 To 1000000
If b(i) > 0 Then If b(i) Mod 6 = 0 Then n = n + 1: arr(n, 1) = i
Next
[D1:D65536] = arr
End Sub

oobird

以下是引用northwolves在2007-10-25 14:32:14的发言：

针对彭先生的数据,用数组可能更快些:

Sub macro1()
Dim arr, i As Long, j As Long, n As Long, b(1000000) As Long
arr = [A1:C60000].Value
For i = 1 To 60000
b(arr(i, 1)) = 1
Next
For j = 2 To 3
For i = 1 To 60000
b(arr(i, j)) = b(arr(i, j)) * j
Next i, j
ReDim arr(1 To 65536, 1 To 1)
For i = 0 To 1000000
If b(i) > 0 Then If b(i) Mod 6 = 0 Then n = n + 1: arr(n, 1) = i
Next
[D1:D65536] = arr
End Sub

果然引出玉了。看似简单，实则暗函无穷智慧，学习中…

彭希仁

引出一座座玉山了,精采啊。

    我的方法是要建立在ABC三列排序后的前题条件下，然后再比较，方法老土，就不班门弄斧了。

TGB

说句很不好意思的话，我一看这些就要晕倒[em04]