[求助]如何把所有邮件的发件人、主题等列在EXCEL内(已解决)

szwlp

请问：如何用VBA把OUTLOOK内其中之一帐户的所有邮件的发件人、主题、内容、日期、大小等列在EXCEL内，以供查询。

谢谢！

[此贴子已经被作者于2007-5-14 21:55:14编辑过]

lwxg

FYI

'=========代码部分===========

Sub test()
Dim Fillrow As Long
Dim myolApp As Object, myNameSpace As Object, myFolder As Object, x As Object
Application.ScreenUpdating = False
Sheet1.UsedRange.Clear
Cells(1, 1).Value = "序号"
Cells(1, 2).Value = "接收时间"
Cells(1, 3).Value = "发件人"
Cells(1, 4).Value = "大小"
Cells(1, 5).Value = "主题"
Cells(1, 6).Value = "正文"
Fillrow = 2

Set myolApp = CreateObject("Outlook.Application")
Set myNameSpace = myolApp.GetNamespace("MAPI")
Set myFolder = myNameSpace.GetDefaultFolder(6) 'olFolderInbox)
For Each x In myFolder.Items
    Cells(Fillrow, 1).Value = Fillrow - 1
    Cells(Fillrow, 2).Value = x.ReceivedTime '接收时间
    Cells(Fillrow, 3).Value = xSenderName '发送人
    Cells(Fillrow, 4).Value = x.Size '大小
    Cells(Fillrow, 5).Value = x.Subject '主题
    Cells(Fillrow, 6).Value = x.Body '正文
    Fillrow = Fillrow + 1
Next
Set myFolder = Nothing
Set myNameSpace = Nothing
Set myolApp = Nothing
Cells.Columns.AutoFit
End Sub

szwlp

谢谢热心的“lwxg”！

现在有一个问题是发件人一列都是空的，请问如何处理?

谢谢！！！

szwlp

OK了。“Cells(Fillrow, 3).Value = xSenderName '发送人”-》Cells(Fillrow, 3).Value = x.SenderName