[求助]请问如何统计不重复的字数？

beibeilong

比如“哈哈大笑”里面不重复的字数为3，应该怎么统计呢？

谢谢！

[此贴子已经被作者于2005-8-28 22:32:18编辑过]

守柔

为什么要这样做？

你的原文档是如何的？

解决的方法很多，有累一些的，也要自动的，你得把所有的要求写清楚，比如，标点符号如何处理？

三个叠字如何处理？哈哈大笑的马大哈算几个字？等等

beibeilong

哈哈，是这样的：

在一个版上看到有人说统计了《红楼梦》1-40,41-80中出现的汉字大约都在3700上下 而81-120中使用的汉字只有3100左右，由此判断《红楼梦》后40回续写的可能性比较大，或者说高鹗认识的字没曹雪芹多:)

于是乎我想到怎样在word里统计，呵呵。“哈哈大笑的马大哈”里就当然只能算有1个哈字、1个大字喽～

守柔

请运行以下代码：

'* ＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋ '* Created By I Love You_Word!@ExcelHome 2005-8-30 06:57:01 '仅测试于System: Windows NT Word: 10.0 Language: 2052 '№ 0004^The Code CopyIn [ThisDocument-ThisDocument]^' '* －－－－－－－－－－－－－－－－－－－－－－－－－－－－－

Option Explicit Sub OnlyChineseCount() '统计文档中不重复汉字字数,不含中文标点 Dim i As Range, OnlyText As String ' Debug.Print Timer With ThisDocument For Each i In .Characters '遍历所有字符 If i Like "[一-龥]" Then '如果属于汉字字符(CJK统一汉字字符集) If OnlyText = "" Then OnlyText = i '为变量赋初值 ElseIf VBA.InStr(OnlyText, i) = 0 Then '如果在OnlyText变量中,没有出现过的字符,则加入该变量字符集中 OnlyText = OnlyText & i End If End If Next End With ' Debug.Print Timer ' MsgBox OnlyText MsgBox "本文中的不重复汉字数为:" & VBA.Len(OnlyText) & "个.", vbInformation End Sub '----------------------

实测：

在一篇18万字的WORD文档中，运行此代码，用时20秒不到。

CPU:P4,2.4G,内存:256M.

关于如何运行宏,请参考置顶贴子.

beibeilong

赞！！！守柔大哥真是热心的大牛啊！！！“守柔曰强”——老子《道德经》第52章。

把兄弟的测试结果发表在这里吧——

《红楼梦》程高本

1－40回总字数272619 不重复汉字数3577 共需27s

41－80回总字数315438 不重复汉字数3566 共需32s

81－120回总字数275985 不重复汉字数3129 共需27s

PM1.3G 256M

henterwu

对守柔老师的水平＆为人，已无话可说。

konggs

老大利害，今天我在老大的基础上改了下，好像速度提高一点点。

Sub 不重复字符知多少()
Dim ast As String '这个变量定义要设置的字符串
Dim arr '数组，读出字符串的每一个为数组各值
Dim i As Long, b
Dim atime As Date '定义一个时间定量，以测程式运行的时间
atime = Time
ast = ActiveDocument.Content

ReDim arr(Len(ast) - 1) '因为数组是从0开始的，所以-1才等于数组的长度
For i = 1 To Len(ast) '取每个值放到对应的数组内
arr(i - 1) = Mid(ast, i, 1) '同理，数组是0开始，所以，减0
Next
Dim OnlyText
For Each b In arr
If b Like "[一-龥]" Then '如果属于汉字字符(CJK统一汉字字符集)
If OnlyText = "" Then
OnlyText = b '为变量赋初值
ElseIf VBA.InStr(OnlyText, b) = 0 Then
'如果在OnlyText变量中,没有出现过的字符,则加入该变量字符集中
OnlyText = OnlyText & b
End If
End If

Next
MsgBox Len(OnlyText), vbOKOnly, Time - atime
End Sub

tly11233

强啊，支持，就是现在还用不到

守柔

TO KONGGS

你的修改很好。

我们再来优化一下，把二次循环变为一次循环，你看如何？

Sub 不重复字符知多少()
Dim AllText As String, B As String
Dim i As Long, StartTime As Single
Dim OnlyText As String
StartTime = Timer
AllText = ActiveDocument.Content.Text
For i = 1 To Len(AllText)
B = Mid(AllText, i, 1)
If B Like "[一-龥]" Then '如果属于汉字字符(CJK统一汉字字符集)
If OnlyText = "" Then
OnlyText = B '为变量赋初值
ElseIf VBA.InStr(OnlyText, B) = 0 Then
'如果在OnlyText变量中,没有出现过的字符,则加入该变量字符集中
OnlyText = OnlyText & B
End If
End If
Next
MsgBox Len(OnlyText), vbOKOnly, Timer - StartTime
End Sub

konggs

PFPF:

老大就是利害!

学到数组,想试练一下,结果发现老大不用数组,照样这样利害,PF之极啊

我还是不能望其项背啊[em04]

[此贴子已经被作者于2006-4-4 12:43:12编辑过]