[讨论]树形结构

彭希仁

电脑的文件夹,家谱(生孩的关系),都是树形结构.以何种方式在EXCEL表达这种关系,以便于维护和查询呢,这就是我们所要讨论话题.我做了一个附件,有两个代码,初步满足了基本的要求,但由于第一次尝试考虑这个问题,必然存在众多的考虑不周不之处,所以拿出来晒晒.发挥大家的家聪明才智以便更加完善.谢谢

一、树形结构的存储格式

                 运行代码一可以将当前路径文件夹内的文件以树形结构的方式保存到EXCEL工作表中.

Public arr1, y%
Sub peng()
    ReDim arr1(1 To 65536, 1 To 5)
    y = 0
    Call xi(ActiveWorkbook.Path, 0)
    Cells(2, 1).Resize(y, 5) = arr1
End Sub

'a查询文件条件设置
'pt路径设置
Sub xi(pt, ByVal f)
    On Error GoTo ren
    Dim x%, i%, z%
    ReDim arr(1 To 100)
    dirs = Dir(pt & "\", vbDirectory)
    Do While dirs <> ""
        If dirs <> "." And dirs <> ".." Then
            x = x + 1
            If x > UBound(arr) Then ReDim Preserve arr(1 To UBound(arr) + 100)
            arr(x) = pt & "\" & dirs
        End If
        dirs = Dir
    Loop
    For i = 1 To UBound(arr)
        If arr(i) = "" Then Exit Sub
        y = y + 1
        arr1(y, 1) = arr(i)
        arr1(y, 2) = y  '自已ID
        arr1(y, 3) = f  '父ID
        If i = 1 And f > 0 Then arr1(f, 5) = y   '长子
        If z > 0 Then arr1(z, 4) = y   '弟
        z = y
        Call xi(arr(i), y)
    Next i
ren:
End Sub
Sub 显示()
UserForm1.Show (0)
End Sub

二、以直观的方式显示出来。
Public nodX As Node, arr
Private Sub UserForm_Initialize()
    TreeView1.LineStyle = 1
    TreeView1.Nodes.Clear
    arr = Cells(2, 1).Resize([a65536].End(xlUp).Row - 1, 5)
    Call peng(1)
End Sub
Sub peng(x)
  On Error GoTo ren
    If arr(x, 3) = 0 Then
        Set nodX = TreeView1.Nodes.Add(, , arr(x, 2) & "p", arr(x, 1))
    Else
        Set nodX = TreeView1.Nodes.Add(arr(x, 3) & "p", tvwChild, arr(x, 2) & "p", arr(x, 1))
    End If
    If arr(x, 4) > 0 Then Call peng(arr(x, 4))
    If arr(x, 5) > 0 Then Call peng(arr(x, 5))
ren:
End Sub

jLLK7AYo.rar (40.56 KB, 下载次数: 4095)

2008-5-30 11:05 上传

点击文件名下载附件
[讨论]树形结构

[此贴子已经被作者于2008-5-30 11:38:15编辑过]

彭希仁

realsoar

调用WINDOWS自己的树形结构可以吗？

彭希仁

QUOTE:

以下是引用realsoar在2008-5-30 12:09:58的发言：
调用WINDOWS自己的树形结构可以吗？

可以啊,但你要怎样才能以文档的形式存储到EXCEL中呢?

sgrshh29

这个treeview不需要把目录存到表中。也不要在打开窗体时全部加载（费时间），打开窗体时，只加载根目录，点击treeview节点时，再加载节点下一级的目录。

彭希仁

QUOTE:

以下是引用sgrshh29在2008-5-30 16:48:46的发言：
这个treeview不需要把目录存到表中。也不要在打开窗体时全部加载（费时间），打开窗体时，只加载根目录，点击treeview节点时，再加载节点下一级的目录。

你这主意不错,不过我样表中数据量太小的,为了简化工作,所以就没有这样做.

sgrshh29

QUOTE:

以下是引用彭希仁在2008-5-30 17:09:50的发言：

你这主意不错,不过我样表中数据量太小的,为了简化工作,所以就没有这样做.

以下建议供彭版参考：

因为文件和路径是会变化的（如目录和文件的增减，文件的移动等），所以把这个写入表中是没有什么实际意义的。只有动态加载的treeview才能反映实际目录的情况。

彭希仁

QUOTE:

以下是引用sgrshh29在2008-5-30 17:25:43的发言：

以下建议供彭版参考：

因为文件和路径是会变化的（如目录和文件的增减，文件的移动等），所以把这个写入表中是没有什么实际意义的。只有动态加载的treeview才能反映实际目录的情况。

我写这个贴子的意义主要是讨论以何种方式存储树形结构的数据,用目录和文件只是举个列子.

例如:要做一份电子档的祖谱,可能有上百代人,而且还会不断的增加人.

.

sgrshh29

一般情况下，比较实用的treeview界面要求能够做到：

1、可以拖拉项目，把节点通过拖拉移动到另一个节点下。

2、通过菜单（一般是右键菜单），可以增加或者删除任意一个节点下的项目。

3、要实现以上目标，一般需要有一个表格来保存数据，设计的好的话，大都数情况只要三个列就能达到目的。其中一个列记录节点内容，另外二个列分别表示这个节点的父节点与本身的id号码。也就是每个节点只要三个关键字就可以。

以上观点仅供参考。

[此贴子已经被作者于2008-5-30 19:57:55编辑过]

彭希仁

三个字段确实是可以办到,只要父节点在子节点之前,对于建立treeview是一点问题都没有.

    我一直在考虑的问题是我们的硬盘是如何记录数据的,例如:前面的数据删除了,后面存入新数据必然会存到已删除的数据那里去,那样要保留父节点在子节点之前是不可能的,那样数据全部得移动一次.而且数据用得越多必然越乱.如何有效的利用硬盘空间,并且可以快速的查找到需要的内容,而不需遍历硬个硬盘呢?我想硬盘存储的原理必然有它的高明之处.

   不好意思想得太多了,不过这个问题自从我接触电脑就开始困扰我了.到现在我也还没明白过来.