ado筛选怎么写ComboBox有请zhaogang1960老师

望江婷

求助赵老师，这个筛选数据库的代码是在论坛找的你的代码。我想要的功能是类似于E表的高级筛选功能，这4个条件可以相互组合，又可以单独使用，比如选择年份2009年后，其余3个ComboBox为空时，就将数据库明细表内年份为2009年的数据全部提取过来，如果填入了年份2009年和施工单位赵勇施工队就将2009年内包含赵勇施工队的数据提取过来，这个变量怎么写呢，主要是ComboBox有为空的时候，请赵老师方便时给与帮助，问题在附件谢谢 新建文件夹 (2).rar (20.56 KB, 下载次数: 48)

2011-1-25 10:44 上传

点击文件名下载附件

zhaogang1960

原帖由 望江婷 于 2011-1-25 10:44 发表
求助赵老师，这个筛选数据库的代码是在论坛找的你的代码。我想要的功能是类似于E表的高级筛选功能，这4个条件可以相互组合，又可以单独使用，比如选择年份2009年后，其余3个ComboBox为空时，就将数据库明细表内年份为 ...

没有注意到，歉
不必指名求助，以免错过高手们的帮助，发个短信就可以了

zhaogang1960

Private Sub CommandButton1_Click()
    Dim cnn As New ADODB.Connection
    Dim Sql As String, i%, arr
    arr = [a2:h2&""]
    For i = 1 To 4
        If Len(Controls("ComboBox" & i).Value) Then Sql = Sql & " and " & Controls("Label" & i).Caption & "='" & Controls("ComboBox" & i).Value & "'"
    Next
    If Sql = "" Then Exit Sub
    cnn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & ThisWorkbook.Path & "\数据库.mdb"
    Sql = "select " & Join(arr, ",") & " from 明细 where " & Mid(Sql, 6)
    [a3:h65536] = ""
    [a3].CopyFromRecordset cnn.Execute(Sql)
    cnn.Close
    Set cnn = Nothing
End Sub

望江婷

呵呵，老师太谦虚了，谢谢赵老师，好好学习学习，提前恭祝赵老师春节愉快，阖家安康。

望江婷

赵老师这一句Mid(Sql, 6)是什么意思呢？

zhaogang1960

原帖由 望江婷 于 2011-1-25 11:16 发表
赵老师这一句Mid(Sql, 6)是什么意思呢？

去掉前面5个多余的字符：“ and ”

望江婷

哦明白了，就是有为空的条件时，不会出现操作字符丢失现象吧，太高了，谢谢

zhaogang1960

修改一下:
Dim cnn As ADODB.Connection

Private Sub CommandButton1_Click()
    Dim i%, arr, Sql As String
    arr = [a2:h2&""]
    For i = 1 To 4
        If Len(Controls("ComboBox" & i).Value) Then Sql = Sql & " and " & Controls("Label" & i).Caption & "='" & Controls("ComboBox" & i).Value & "'"
    Next
    [a3:h65536] = ""
    If Sql = "" Then Exit Sub
    Sql = "select " & Join(arr, ",") & " from 明细 where " & Mid(Sql, 6)
    [a3].CopyFromRecordset cnn.Execute(Sql)
End Sub

Private Sub UserForm_Initialize()
    Dim i%, arr
    Set cnn = New ADODB.Connection
    cnn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & ThisWorkbook.Path & "\数据库.mdb"
    For i = 1 To 4
        arr = cnn.Execute("select distinct " & Controls("Label" & i).Caption & " from 明细").GetRows
        Controls("ComboBox" & i).List = WorksheetFunction.Transpose(arr)
    Next
End Sub

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
    cnn.Close
    Set cnn = Nothing
End Sub

望江婷

感谢赵老师精妙的代码

chengang1982

第一次见这种写法arr = [a2:h2&""]太高了请问侠圣gang1960  
如果写成Range或Cells----应该怎么写呢，怎么表示呢