教育应用贴（分班、统计、课表等）1142楼添加运动会成绩统计表20121215

ifeelnet

还有缺考好像没考虑进去，不过还是谢谢了

xjzhmxyh

学习了，谢谢

lhx120824

下图中的问题求平均值：


=AVERAGEIFS(INDIRECT($K$2),班别,J5,INDIRECT($K$2),">=0")
2007中的公式。
求平均分20110422.rar (9.64 KB, 下载次数: 238)

2011-4-22 08:21 上传

点击文件名下载附件

首行定义名称，k2设置数据有效性。

http://club.excelhome.net/viewth ... =1047974#pid4823843

[ 本帖最后由 lhx120824 于 2011-4-22 08:23 编辑 ]

guojianlin1985

好帖，收藏备用

silence198761

suqinhu

谢谢，好好学习

valleytale

http://club.excelhome.net/viewth ... e%3D1&frombbs=1
《OFFSET 函数实例（入门级）敬请方家指正》

qwe79812

内容好丰富，练习函数和数组公式的好地方

lhx120824

原帖由 valleytale 于 2011-4-27 16:30 发表
http://club.excelhome.net/viewth ... e%3D1&frombbs=1
《OFFSET 函数实例（入门级）敬请方家指正》

参考本帖430楼、41楼准考证的制作方法。
[url]http://club.excelhome.net/viewthread.php?tid=589978&page=43&fromuid=1047974#pid4523722[/url]

[ 本帖最后由 lhx120824 于 2011-5-2 08:58 编辑 ]

lhx120824

本楼是  安然祥和   的总结 ，自己觉得很好，再次作为资料与大家共享
[url=http://club.excelhome.net/viewth ... =1047974#pid4844498]http://club.excelhome.net/viewth ... =1047974#pid4844498

countif函数的使用方法汇总
为帮助让大家更好地了解、掌握Countif函数便用方法,现罗列一些实例如下:
一、求各种类型单元格的个数
(1)   求真空单元格单个数:                =COUNTIF(data,"=")
(2)   真空+假空单元格个数:               =COUNTIF(data,"")            相当于countblank()函数
(3)   非真空单元格个数:                  =COUNTIF(data,"<>")        相当于counta()函数
(4)   文本型单元格个数:                  =COUNTIF(data,"*")           假空单元格也是文本型单元格
(5)   区域内所有单元格个数:              =COUNTIF(data,"<>""")
(6)   逻辑值为TRUE的单元格数量      =COUNTIF(data,TRUE)
小说明：
EXCEL单元格内数据主要有以下几类:数值型,文本型,逻辑型,错误值型。其中时间类型也是一种特殊的数值。文本类型的数字是文本型。
空单元格：指什么内容也没有的单元格，姑且称之为真空。
假空单元格：指0字符的空文本，一般是由网上下载来的或公式得来的，姑且称之为假空。
date指单元格区域，该参数不能是数组
二、求><=某个值的单元格个数
(1) 大于50                                    =COUNTIF(data,">50")
(2) 等于50                                    =COUNTIF(data,50)
(3) 小于50                                    =COUNTIF(data,"<50")
(4) 大于或等于50                              =COUNTIF(data,">=50")   
(5) 小于或等于50                              =COUNTIF(data,"<=50") &not;
(6) 大于E5单元格的值                          =COUNTIF(data,">"&$E$5)  
(7) 等于E5单元格的值                          =COUNTIF(data,$E$5)   
(8) 小于E5单元格的值                          =COUNTIF(data,"<"&$E$5)   
(9) 大于或等于E5单元格的值            =COUNTIF(data,">="&$E$5)
(10) 小于或等于E5单元格的值           =COUNTIF(data,"<="&$E$5)
三、等于或包含某N个特定字符的单元格个数
(1) 两个字符                                                =COUNTIF(data,"??")
(2) 两个字符并且第2个是B                       =COUNTIF(data,"?B")  
(3) 包含B                                                     =COUNTIF(data,"*B*")
(4) 第2个字符是B                                       =COUNTIF(data,"?B*")
(5) 等于“你好”                                        =COUNTIF(data,"你好")   
(6) 包含D3单元格的内容                          =COUNTIF(data,"*"&D3&"*")
(7) 第2字是D3单元格的内容                    =COUNTIF(data,"?"&D3&"*")

注：countif()函数对英文字母不区分大小写，通配符只对文本有效
四、两个条件求个数
(1)    >10并且<=15        =SUM(COUNTIF(data,">"&{10,15})*{1,-1})  
(2)    >=10并且<15        =SUM(COUNTIF(data,">="&{10,15})*{1,-1})   
(3)    >=10并且<=15      =SUM(COUNTIF(data,{">=10",">15"})*{1,-1})
(4)    >10并且<15          =SUM(COUNTIF(data,{">10",">=15"})*{1,-1})
注：一般多条件计数使用SUMPRODUCT函数，以上方法较少使用，仅供参考。
补充：三个区域计数：
  三个区域中>=60         =SUM(COUNTIF(INDIRECT({"a46:a48","b48:b50","c47:c48"}),">=60"))
五、各种特殊统计要求的计算     A2：A32 为存放数据的区域
（1）非空文本（仅包括可键入文本）  =COUNTIF(A2:A32,">=!")  
（2）所有非空文本 =COUNTIF(A2:A32,">=!")+COUNTIF(A2:A32,">="&CHAR(1))-COUNTIF(A2:A32,">= ")  或  {=SUM(COUNTIF(A2:A32,">="&{"!"," "})*{1,-1})+COUNTIF(A2:A32,">="&CHAR(1))}
（3）全部可见单元格  {=SUM(N(IF(ISERROR(A2:A32),1,SUBSTITUTE(A2:A32," ",""))<>""))}
（4）有效可见单元格  =COUNTIF(A2:A32,">=!")+COUNTIF(A2:A32,">="&CHAR(1))-COUNTIF(A2:A32,">= ")+COUNT(A2:A32)
（5）全部不见单元格（真空＋空格＋空文本） =COUNTIF(A2:A32,"")-COUNTIF(A2:A32,">=!")+COUNTIF(A2:A32,">= ")
（6）空格  =COUNTIF(A2:A32,">= ")-COUNTIF(A2:A32,">=!")  
（7）空文本""  =COUNTIF(A2:A32,"")-COUNTIF(A2:A32,"=")
（8）逻辑与错误  =COUNTIF(A2:A32,"<>")-COUNTIF(A2:A32,"*")-COUNT(A2:A32)
看后是不是明白了不少？

[ 本帖最后由 lhx120824 于 2011-5-2 17:25 编辑 ]