排名方法集锦（有十多种不同的方法的附件，6月1日更新加入11种方法的单段排名集锦）

lhx120824

11种方法的单段排名集锦（分别包含升序和降序）
6月1日更新加入
单段排名方法集锦20100601.rar (35.14 KB, 下载次数: 874)

2010-6-1 14:24 上传

点击文件名下载附件

参阅本论坛中的很多大师的排名方法整理出单段内分数的排名方法(不是大全，只是一部分），仅供参考，如有错误请予指正，并给予补充。
（多段排名正在整理，随后即发）




不并列排名公式如何修改？
用公式=SUMPRODUCT((班级=P2)*(总分>=$M2))
算出的相同名次再用数学的排序区分，数学成绩高的在前，比如s列的两个21名，两个12名，根据E列的数学成绩分别改为21、20，12、11名，目的是让排名不并列。公式怎么该？
不并列排名.rar (24.49 KB, 下载次数: 924)

2010-5-10 15:58 上传

点击文件名下载附件

已解决，从论坛上学到的。加以改造，适合本表，s2公式如下：
=SUMPRODUCT(--(MMULT((班级=P2)*成绩单,10^ROW($1:$10))>SUM(D2:M2*10^COLUMN($A:$J))))+1

含有多种方法的排名（有待继续更新研究）.xls
含有多种方法的排名（有待继续更新研究）.rar (26.02 KB, 下载次数: 917)

2010-5-22 12:44 上传

点击文件名下载附件

25楼有hbhfgh4310大师的多年前的排名汇总，整理得很规范，也很全面，值得我们晚辈们拜读。

[ 本帖最后由 lhx120824 于 2010-6-1 14:24 编辑 ]

lhx120824

相当于使用工具栏中排序的主关键字和次关键字及第三关键字分别降序排列。然后在名次栏中依次输入1、2、3、……，名次不重复。

lhx120824

已解决，从论坛上学到的。加以改造，适合本表，s2公式如下：
=SUMPRODUCT(--(MMULT((班级=P2)*成绩单,10^ROW($1:$10))>SUM(D2:M2*10^COLUMN($A:$J))))+1
上面的公式不好用，

以下的两个比较简单，是不重复名次的。

=SUMPRODUCT((班级=P2)*(总分>M2))+SUMPRODUCT(($P$2:P2=P2)*($M$2:M2=M2))

=SUM(--((班级=P2)*(总分-ROW(总分)%%>M2-ROW(M2)%%)))+1  数组公式

含有5种排名方法的附件：
含有5种方法的排名.rar (20.22 KB, 下载次数: 367)

2010-5-22 10:45 上传

点击文件名下载附件

[ 本帖最后由 lhx120824 于 2010-5-22 10:46 编辑 ]

lhx120824

排名的相关帖子及方法：

多条件排名  http://club.excelhome.net/thread-577840-1-1.html
=SUMPRODUCT(($A$1:$A$7=A1)*($B$1:$B$7>B1))+1
=SUM(N(IF($A$1:$A$12=A10,B10<$B$1:$B$12)))+1

学校考试成绩多条件排名  http://club.excelhome.net/thread-502269-1-1.html
中式排名
语文年级=IF(LEFT(A2)="7",MATCH(C2,LARGE(IF(IF(LEFT(A$2:A$266)="7",MATCH(C$2:C$266,IF(LEFT(A$2:A$266)="7",C$2:C$266),),"")=ROW(C$2:C$266)-1,C$2:C$266,""),ROW(C$2:C$266)-1),),MATCH(C2,LARGE(IF(IF(LEFT(A$2:A$266)="8",MATCH(C$2:C$266,IF(LEFT(A$2:A$266)="8",C$2:C$266),),"")=ROW(C$2:C$266)-1,C$2:C$266,""),ROW(C$2:C$266)-1),))

语文班级=MATCH(C2,LARGE(IF(IF((A$2:A$266)*1=A2,MATCH(C$2:C$266,IF((A$2:A$266)*1=A2,C$2:C$266),),"")=ROW(C$2:C$266)-1,C$2:C$266,""),ROW(C$2:C$266)-1),)

如何求排名啊，高手们帮帮忙，谢谢！http://club.excelhome.net/viewth ... C5%C3%FB&page=1
大头老师给出的方法：
=MATCH(D3,LARGE(IF(ISNUMBER(1/(MATCH(B3&"@"&D$3:D$41,B$3:B$41&"@"&D$3:D$41,)=ROW($1:$39))),D$3:D$41),ROW($1:$200)),)

[ 本帖最后由 lhx120824 于 2010-5-22 11:14 编辑 ]

lhx120824

中国式排名，求生成内存数组公式  http://club.excelhome.net/viewth ... hlight=%C5%C5%C3%FB
通常公式：
=SUM(IF(A8<A$2:A$15,1/COUNTIF(A$2:A$15,A$2:A$15)))+1
内存数组公式：
=MATCH(A2:A15,LARGE(IF(FREQUENCY(A2:A15,A2:A15),A2:A15),ROW(1:14)),)

如何從成績中取得排名  http://club.excelhome.net/viewth ... hlight=%C5%C5%C3%FB
排名的五种方法：
=RANK(C2,$C$2:$C$12)
=SUM(($C$2:$C$12>C2)*1)+1  （{}）
=COUNTIF($C$2:$C$12,">"&C2)+1
=SUMPRODUCT(($C$2:$C$12>C2)*1)+1
=COUNT($C$2:$C$12)-FREQUENCY($C$2:$C$12,C2)+1

3种数组方法：
=SUM(IF(A$2:A$14>A2,1/COUNTIF(A$2:A$14,A$2:A$14)))+1
=SUM(--(FREQUENCY(A$2:A$14,IF(A$2:A$14>=A2,A$2:A$14))>0))
=SUM(--IF(A$2:A$14>=A2,MATCH(A$2:A$14,A$2:A$14,)=ROW($2:$14)-1))

[ 本帖最后由 lhx120824 于 2010-5-22 09:02 编辑 ]

lhx120824

Excel VBA排序算法
排序算法常用的有七种，分别是冒泡排序，选择排序，希尔排序，堆排序，桶排序，插入排序和快速排序。 http://club.excelhome.net/thread-542318-1-1.html



有难度，多部门内排名问题！http://club.excelhome.net/viewth ... hlight=%C5%C5%C3%FB
SUM(N(IF(A$2:A$15=A2,B$2:B$15,9^9)<B2))+SUM(N(A$1:A2&B$1:B2=A2&B2)) 数组

rank+countif
=RANK(B2,OFFSET($B$1,MATCH(A2,$A$2:$A$15,),,COUNTIF($A$2:$A$15,A2)),1)+COUNTIF($B$2:B2,B2)-1

也可以用数组公式：
D2=SUM(--(IF(A$2:A$15=A2,B$2:B$15+ROW($2:$15),4^8)<=B2+ROW(C2)))下拉

[ 本帖最后由 lhx120824 于 2010-5-22 09:17 编辑 ]

lhx120824

求助一个排名不会重复的公式 http://club.excelhome.net/viewth ... hlight=%C5%C5%C3%FB
有个以解决的方法：
例子：
项目名称        单位名称        金额        排名       
应收账款        南京卷烟厂  1000        4        4
应收账款        苏果超市        2000        2        2
应收账款        大润发          2000        2        3
应收账款        金鹰               3000        1        1
应付账款        欧尚               2500        2        2
应付账款        浦发银行        4000        1        1
应付账款        深发银行        2500        2        3
liuzequan给的公式：
=SUM(--(($B$3:$B$9=B3)*($D$3:$D$9-ROW($D$3:$D$9)%%>D3-ROW(D3)%%)))+1
这是数组公式，需将鼠标插入点放入编辑栏，再同时按下以下三键后再松手(CTRL、SHIFT、ENTER）
然后，再将公式往下拖。

[ 本帖最后由 lhx120824 于 2010-5-22 09:41 编辑 ]

如饥似渴

您的附件版本太高，无法打开，能否换个版本较低的附件传上来？谢谢您。
看了这个帖子的全部个贴，除我之外再无二人，好像您是在唱独角戏，不知为何。

[ 本帖最后由 如饥似渴 于 2010-5-22 10:06 编辑 ]

lhx120824

原帖由 如饥似渴 于 2010-5-22 09:26 发表
您的附件版本太高，无法打开，能否换个版本较低的附件传上来？谢谢您。

可以，附件：
不并列排名.rar (15.19 KB, 下载次数: 230)

2010-5-22 09:32 上传

点击文件名下载附件

slywtj123

很有启发的！谢谢分享！