如何判断一个名称为“sheet1”的工作表是否存在？

抬头苦干

学习了，涨知识啊。顺便对各位的跟帖做个小结。
【问题】判定某工作表（如工作表“SheetX”）是否存在。
【尝试】用 Is Nothing 判定，报运行时错误，提示下标越界：

1. Sub IsNothingFail()
   
2. Rem 不可用 Is Nothing 直接判定，否则报下标越界错误
   
3.     If Worksheets("SheetX") Is Nothing Then
   
4.        MsgBox "工作表 'SheetX' 不存在", vbCritical
   
5.     Else
   
6.        MsgBox "工作表 'SheetX' 已存在", vbInformation
   
7.     End If
   
8. End Sub

复制代码

【报错截图】

【四种解法】
根据讨论情况，目前该问题至少有四种解法：
【解法一】For-Each 遍历

1. Sub ForEach_Traverse()
   
2. Rem 这是最基本的思路，遍历各表名称，逐一判定
   
3.     Dim ws As Worksheet, existed As Boolean
   
4.     existed = False
   
5.     For Each ws In Worksheets
   
6.         If ws.Name = "SheetX" Then existed = True: Exit For
   
7.     Next
   
8.     If existed Then
   
9.         MsgBox "工作表 'SheetX' 已存在", vbInformation
   
10.     Else
    
11.         MsgBox "工作表 'SheetX' 不存在", vbCritical
    
12.     End If
    
13. End Sub

复制代码

【解法二】On Error 捕获错误

1. Sub OnError()
   
2. Rem 根据 livewire、livewire、静静心、indexlee 代码整理
   
3.     On Error Resume Next
   
4.     If Worksheets("SheetX") Is Nothing Then:
   
5.     If Err Then
   
6.         MsgBox "工作表 'SheetX' 不存在", vbCritical
   
7.         Err.Clear
   
8.     Else
   
9.         MsgBox "工作表 'SheetX' 已存在", vbInformation
   
10.     End If
    
11.     On Error GoTo 0
    
12. End Sub

复制代码

【解法三】自定义函数辅助判定

1. Sub DIY_Function()
   
2. Rem 根据 白色GG 代码整理
   
3.     If ExistSheet("SheetX") Then
   
4.         MsgBox "工作表 'SheetX' 已存在", vbInformation
   
5.     Else
   
6.         MsgBox "工作表 'SheetX' 不存在", vbCritical
   
7.     End If
   
8. End Sub
   
9. 
   
10. Function ExistSheet(Optional ByVal sheetName As String = "SheetX") As Boolean
    
11.     Dim sh As Worksheet
    
12.     On Error GoTo Err_Handle
    
13.     Set sh = Worksheets(sheetName)
    
14.     ExistSheet = IIf(sh Is Nothing, False, True)
    
15.     Set sh = Nothing
    
16.     Exit Function
    
17. Err_Handle:
    
18.     ExistSheet = False
    
19. End Function

复制代码

【解法四】TypeName + Evaluate 判定（强烈推荐）

1. Sub TypeName_Evaluate()
   
2. Rem 根据 yaozong 代码整理（强烈推荐）
   
3.     If TypeName([SheetX]) = "Worksheet" Then
   
4.         MsgBox "工作表 'SheetX' 已存在", vbInformation
   
5.     Else
   
6.         MsgBox "工作表 'SheetX' 不存在", vbCritical
   
7.     End If
   
8. End Sub

复制代码

greatlazy

抬头苦干 发表于 2017-5-1 04:29
学习了，涨知识啊。顺便对各位的跟帖做个小结。
【问题】判定某工作表（如工作表“SheetX”）是否存在。
...

感谢辛苦总结.
但是根据我实际操作,发现第四中方法虽然好,但是不适用与中文命名的表单.
所以如果你的sheet里面有中的话,最好还是用【解法二】On Error 捕获错误

greatlazy

关于第四种解法的方括号,可以看下面的帖子.
http://www.exceltip.net/thread-25207-1-1.html

greatlazy

• Sub OnError()
• Rem 根据 livewire、livewire、静静心、indexlee 代码整理
•     On Error Resume Next
•     If Worksheets("SheetX") Is Nothing Then:          想请问这里的这个冒号是什么作用,而且代码后面应该也少了一个end if.
•     If Err Then
•         MsgBox "工作表 'SheetX' 不存在", vbCritical
•         Err.Clear
•     Else
•         MsgBox "工作表 'SheetX' 已存在", vbInformation
•     End If
•     On Error GoTo 0
• End Sub
  

我去除冒号,并再尾部添加了end if 后,发现代码没有任何反应.
求助.

抬头苦干

greatlazy 发表于 2017-7-11 16:52

Sub OnError()

Rem 根据 livewire、livewire、静静心、indexlee 代码整理

    On Error Resum ...

这里的冒号相当于一个空语句，表示【:】的左边与【Then】右边的某个单语句的结束（实际上没有任何语句执行），它也等效于在下一行写上End If：

1.     If Worksheets("SheetX") Is Nothing Then
   
2.     End If

复制代码

greatlazy

抬头苦干 发表于 2017-7-14 10:05
这里的冒号相当于一个空语句，表示【:】的左边与【Then】右边的某个单语句的结束（实际上没有任何语句执 ...

非常感谢,真是非常详细.

02761752696

学习   了    谢谢

ft4919226

on error resume next
配合if X is nothing。当初也是用遍历，感觉好累，谢谢各位大神

ruitree

总结的好， 如果用的地方多，直接用function

excel.x

抬头苦干 发表于 2017-5-1 04:29
学习了，涨知识啊。顺便对各位的跟帖做个小结。
【问题】判定某工作表（如工作表“SheetX”）是否存在。
...

很好，很棒。