ExcelHome技术论坛

 找回密码
 免费注册

QQ登录

只需一步,快速开始

快捷登录

搜索
EH技术汇-专业的职场技能充电站 妙哉!函数段子手趣味讲函数 Excel服务器-会Excel,做管理系统 Excel Home精品图文教程库
HR薪酬管理数字化实战 Excel 2021函数公式学习大典 Excel数据透视表实战秘技 打造核心竞争力的职场宝典
300集Office 2010微视频教程 数据工作者的案头书 免费直播课集锦 ExcelHome出品 - VBA代码宝免费下载
用ChatGPT与VBA一键搞定Excel WPS表格从入门到精通 Excel VBA经典代码实践指南
查看: 303204|回复: 252

[分享] countif函数的使用方法汇总

  [复制链接]

TA的精华主题

TA的得分主题

发表于 2011-4-29 20:57 | 显示全部楼层 |阅读模式
本帖已被收录到知识树中,索引项:COUNTIF
为帮助让大家更好地了解、掌握Countif函数便用方法,现罗列一些实例如下:
一、求各种类型单元格的个数
(1)   求真空单元格单个数:                =COUNTIF(data,"=")
(2)   真空+假空单元格个数:               =COUNTIF(data,"")            相当于countblank()函数
(3)   非真空单元格个数:                  =COUNTIF(data,"<>")        相当于counta()函数
(4)   文本型单元格个数:                  =COUNTIF(data,"*")           假空单元格也是文本型单元格
(5)   区域内所有单元格个数:              =COUNTIF(data,"<>""")
(6)   逻辑值为TRUE的单元格数量      =COUNTIF(data,TRUE)
小说明:
EXCEL单元格内数据主要有以下几类:数值型,文本型,逻辑型,错误值型。其中时间类型也是一种特殊的数值。文本类型的数字是文本型。
空单元格:指什么内容也没有的单元格,姑且称之为真空。
假空单元格:指0字符的空文本,一般是由网上下载来的或公式得来的,姑且称之为假空。
date指单元格区域,该参数不能是数组
二、求><=某个值的单元格个数
(1) 大于50                                    =COUNTIF(data,">50")
(2) 等于50                                    =COUNTIF(data,50)
(3) 小于50                                    =COUNTIF(data,"<50")
(4) 大于或等于50                              =COUNTIF(data,">=50")   
(5) 小于或等于50                              =COUNTIF(data,"<=50") &not;
(6) 大于E5单元格的值                          =COUNTIF(data,">"&$E$5)  
(7) 等于E5单元格的值                          =COUNTIF(data,$E$5)   
(8) 小于E5单元格的值                          =COUNTIF(data,"<"&$E$5)   
(9) 大于或等于E5单元格的值            =COUNTIF(data,">="&$E$5)
(10) 小于或等于E5单元格的值           =COUNTIF(data,"<="&$E$5)
三、等于或包含某N个特定字符的单元格个数
(1) 两个字符                                                =COUNTIF(data,"??")
(2) 两个字符并且第2个是B                       =COUNTIF(data,"?B")  
(3) 包含B                                                     =COUNTIF(data,"*B*")
(4) 第2个字符是B                                       =COUNTIF(data,"?B*")
(5) 等于“你好”                                        =COUNTIF(data,"你好")   
(6) 包含D3单元格的内容                          =COUNTIF(data,"*"&D3&"*")
(7) 第2字是D3单元格的内容                    =COUNTIF(data,"?"&D3&"*")

注:countif()函数对英文字母不区分大小写,通配符只对文本有效
四、两个条件求个数
(1)    >10并且<=15        =SUM(COUNTIF(data,">"&{10,15})*{1,-1})  
(2)    >=10并且<15        =SUM(COUNTIF(data,">="&{10,15})*{1,-1})   
(3)    >=10并且<=15      =SUM(COUNTIF(data,{">=10",">15"})*{1,-1})
(4)    >10并且<15          =SUM(COUNTIF(data,{">10",">=15"})*{1,-1})
注:一般多条件计数使用SUMPRODUCT函数,以上方法较少使用,仅供参考。
补充:三个区域计数:
  三个区域中>=60         =SUM(COUNTIF(INDIRECT({"a46:a48","b48:b50","c47:c48"}),">=60"))
五、各种特殊统计要求的计算     A2:A32 为存放数据的区域
(1)非空文本(仅包括可键入文本)  =COUNTIF(A2:A32,">=!")  
(2)所有非空文本 =COUNTIF(A2:A32,">=!")+COUNTIF(A2:A32,">="&CHAR(1))-COUNTIF(A2:A32,">= ")  或  {=SUM(COUNTIF(A2:A32,">="&{"!"," "})*{1,-1})+COUNTIF(A2:A32,">="&CHAR(1))}
(3)全部可见单元格  {=SUM(N(IF(ISERROR(A2:A32),1,SUBSTITUTE(A2:A32," ",""))<>""))}
(4)有效可见单元格  =COUNTIF(A2:A32,">=!")+COUNTIF(A2:A32,">="&CHAR(1))-COUNTIF(A2:A32,">= ")+COUNT(A2:A32)
(5)全部不见单元格(真空+空格+空文本) =COUNTIF(A2:A32,"")-COUNTIF(A2:A32,">=!")+COUNTIF(A2:A32,">= ")
(6)空格  =COUNTIF(A2:A32,">= ")-COUNTIF(A2:A32,">=!")  
(7)空文本""  =COUNTIF(A2:A32,"")-COUNTIF(A2:A32,"=")
(8)逻辑与错误  =COUNTIF(A2:A32,"<>")-COUNTIF(A2:A32,"*")-COUNT(A2:A32)
看后是不是明白了不少?

评分

15

查看全部评分

TA的精华主题

TA的得分主题

发表于 2011-4-29 21:02 | 显示全部楼层

TA的精华主题

TA的得分主题

发表于 2011-4-29 21:12 | 显示全部楼层
[广告] Excel易用宝 - 提升Excel的操作效率 · Excel / WPS表格插件       ★免费下载 ★       ★ 使用帮助
=SUM(COUNTIF(data,">"&{10,15})*{1,-1})  
怎么理解,有点看不懂

TA的精华主题

TA的得分主题

发表于 2011-4-29 21:21 | 显示全部楼层
data 中大于10的个数减去大于15的个数, 得出的就是大于10且小于等于15的个数

TA的精华主题

TA的得分主题

发表于 2011-4-29 21:23 | 显示全部楼层
原帖由 sharprain 于 2011-4-29 21:12 发表
=SUM(COUNTIF(data,">"&{10,15})*{1,-1})  
怎么理解,有点看不懂

COUNTIF(data,">"&{10,15})
是统计分别大于10和大于15的个数,形成一个内存数组,我就用{A,B}表示吧
=SUM({A,B})*{1,-1})  
就等于A*1+B*(-1)=A-B
因此这个公式也就是大于10的个数减去大于15的个数,即是大于10且小于等于15的个数。

TA的精华主题

TA的得分主题

发表于 2011-4-29 21:37 | 显示全部楼层
楼主总结的确实很全,不过我还想起一种情况,就是统计文本字符串中包含“?”和“*”字符的情况
=COUNTIF(data,"*"&"~*"&"*")
?同理表示方式"~?"

还有统计日期问题和平均值问题,可以参阅
http://club.excelhome.net/thread-55123-1-7.html

TA的精华主题

TA的得分主题

发表于 2011-5-1 16:44 | 显示全部楼层

TA的精华主题

TA的得分主题

发表于 2011-5-1 20:10 | 显示全部楼层

TA的精华主题

TA的得分主题

发表于 2011-5-2 17:03 | 显示全部楼层

TA的精华主题

TA的得分主题

发表于 2011-5-2 17:13 | 显示全部楼层
楼主费心了,总结的很全面。
要是再附加上实例,那就更好理解了。

[ 本帖最后由 lhx120824 于 2011-5-2 17:18 编辑 ]
您需要登录后才可以回帖 登录 | 免费注册

本版积分规则

手机版|关于我们|联系我们|ExcelHome

GMT+8, 2024-3-29 03:36 , Processed in 0.041707 second(s), 8 queries , Gzip On, Redis On.

Powered by Discuz! X3.4

© 1999-2023 Wooffice Inc.

沪公网安备 31011702000001号 沪ICP备11019229号-2

本论坛言论纯属发表者个人意见,任何违反国家相关法律的言论,本站将协助国家相关部门追究发言者责任!     本站特聘法律顾问:李志群律师

快速回复 返回顶部 返回列表