撤消上一步的代码是什么

eassjay

请问各位大侠，EXCEL的撤消上一步的代码是什么，我用了录制的方式但是什么也没有。为什么没有呢？有谁知道吗？望不吝赐教。

99253415

貌似VBA代码执行后没有默认撤消功能。

山菊花

Application.Undo

eassjay

Sub dkal()
Range("a1").Value = 100
Application.Undo
End Sub
失败了。。。。

山菊花

不能撤销VBA对工作表的操作。

eassjay

额。俺知道了，谢谢

335081548

问题3：可以撤销宏所执行的操作吗？
解答：可以，但不能通过Excel内置的功能自动实现。您可以使用VBA代码记录下运行宏程序前单元格或单元格区域原先的内容，在“撤销”命令中调用以恢复程序运行前的状态。
您可以使用Application对象的OnUndo方法作为宏程序结束前的最后一个代码，该方法允许您指定出现在“撤销”菜单项中的文本以及点击该文本后所运行的过程。如下面的代码所示：
Application.Onundo “撤销最后一个宏”，”恢复宏程序”
为说明上述方法，下面列出了一个完整的示例。示例的完整代码以及代码说明如下：
‘**************************************************
Type RangeCellInfo '自定义类型存储宏运行所作出的改变
    CellContent As Variant
    CellAddress As String
End Type

Public OrgWB As Workbook
Public OrgWS As Worksheet
Public OrgCells() As RangeCellInfo
‘**************************************************
Sub EditRange()
  ' 在所有被选取的单元格中插入X
  Dim i As Integer, cl As Range
  If TypeName(Selection) <> "Range" Then Exit Sub
  Application.ScreenUpdating = False
  ReDim OrgCells(Selection.Count)
  Set OrgWB = ActiveWorkbook
  Set OrgWS = ActiveSheet
  i = 1
  ‘记录下宏程序对工作表作出改变前的状态
  For Each cl In Selection
    OrgCells(i).CellContent = cl.Formula
    OrgCells(i).CellAddress = cl.Address
    i = i + 1
  Next cl
  ‘在所选单元格中填允X
  Selection.Formula = "X"
  ‘指定在“撤销”菜单项中的文字及选择该命令时所执行的宏程序
  Application.OnUndo "撤销最后运行的宏过程操作", "UndoEditRange"
End Sub
‘**************************************************
‘恢复工作表原先的状态
Sub UndoEditRange()
  Dim i As Integer
  Application.ScreenUpdating = False
  On Error GoTo NoWBorWS
  OrgWB.Activate
  OrgWS.Activate
  On Error GoTo 0
  '恢复宏运行所作的改变
  For i = 1 To UBound(OrgCells)
      Range(OrgCells(i).CellAddress).Formula = OrgCells(i).CellContent
  Next i
  Set OrgWB = Nothing
  Set OrgWS = Nothing
  Erase OrgCells
NoWBorWS:
End Sub

eassjay

SORRY,我很久没来，才发现居然还有人回帖，对不起啊。谢谢啦。。。

hacker0007

如果是通过宏 或者手工更改的那么用一下代码就可以解决的
Application.ActiveDocument.Undo
如果是通过vba 编程做的更改就貌似就只能通过 类似8楼335081548 的方法了