Application.GetOpenFilename 方法解析

gvntw

以下是笔者对 Excel VBA之 Application.GetOpenFilename 方法的解析：
功能：显示标准的“打开”对话框，并获取用户文件名，而不必真正打开任何文件。
语法：Application.GetOpenFilename(FileFilter, FilterIndex, Title, ButtonText, MultiSelect)
参数及说明如下表所示：

名称        说明
FileFilter        可选参数，代表指定文件筛选条件的字符串。如果省略该参数，默认为：“所有文件(*.*),*.*”。
FilterIndex        可选参数，指定默认文件筛选条件的索引号，取值范围为 1 到由 FileFilter 所指定的筛选条件数目。如果省略该参数，或者该参数的值大于可用筛选条件数，则使用第一个文件筛选条件。
Title        可选参数，指定对话框的标题。如果省略该参数，则标题为“打开”。
ButtonText        可选参数，仅用于 Macintosh 机器。
MultiSelect        可选参数，如果为 True，则允许选择多个文件名。如果为 False，则只允许选择一个文件名。默认值为 False。

示例代码1：
Sub SelectAFile()    'MultiSelect省略默认为false,选择单个文件
    Dim filter As String
    Dim fileToOpen
   
    filter = "All Files(*.*),*.*,Word Documents(*.do*),*.do*," & _
            "Text Files(*.txt),*.txt,Excel Files(*.xl*), * .xl * "
    fileToOpen = Application.GetOpenFilename(filter, 4, "请选择文件")
   
    If fileToOpen = False Then
        MsgBox "你没有选择文件", vbOKOnly, "提示"
    Else
        MsgBox "你选择的文件是：" & fileToOpen, vbOKOnly, "提示"
    End If
End Sub

上面的代码将显示标题为“请选择文件”的对话框，只能选择一个文件，“文件类型”下拉列表框有4个选项，打开时默认为第4个（Excel Files(*.xl*)），如下图所示：

Sub SelectFiles()      'MultiSelect为true，可选择多个文件
    Dim filter As String
    Dim fileToOpen
   
    filter = "All Files(*.*),*.*,Word Documents(*.do*),*.do*," & _
            "Text Files(*.txt),*.txt,Excel Files(*.xl*), * .xl * "
    fileToOpen = Application.GetOpenFilename(filefilter:=filter, FilterIndex:=2, Title:="请选择文件", MultiSelect:=True)
   
    If Not IsArray(fileToOpen) Then
        MsgBox "你没有选择文件", vbOKOnly, "提示"
    Else
        MsgBox "你选择的文件是：" & vbCrLf & Join(fileToOpen, vbCrLf)
    End If
End Sub

上面的代码将显示标题为“请选择文件”的对话框，可以选择多个文件，“文件类型”下拉列表框有4个选项，打开时默认为第2个（Word Documents(*.do*)），如下图所示：


GetOpenFilename.zip (119.99 KB, 下载次数: 781)

2010-12-14 20:14 上传

点击文件名下载附件

camle

搬个沙发,慢慢看,多谢!

hanter007

谢谢分享,学习到知识.

wzcjzf

谢谢！解决了我的一些疑问。

baijiesnow

版主，你好，我有些问题需要请教一下，你这个帖子是获取了文件名，但不打开文件
我正在学习中，在书上看是说先通过Getopenfilename获取文件名，然后再通过Open方法打开文件，我想通过此方法实现打开被选中的多个文件，可是改完了出现错误提示，说类型不匹配，请您帮我看看吧，谢谢

gvntw

[code=vb]Sub SelectFiles()
    Dim filter As String
    Dim fileToOpen
   
    filter = "All Files(*.*),*.*,Word Documents(*.do*),*.do*," & _
            "Text Files(*.txt),*.txt,Excel Files(*.xl*), * .xl * "
    fileToOpen = Application.GetOpenFilename(filefilter:=filter, FilterIndex:=4, Title:="请选择文件", MultiSelect:=True)
   
    If Not IsArray(fileToOpen) Then
        MsgBox "你没有选择文件", vbOKOnly, "提示"
    Else
        For Each a In fileToOpen
            Workbooks.Open Filename:=a
        Next
        
    End If
End Sub

[/code]

选择多个文件，fileToOpen是个数组，你可以依次打开。

o306336202

不错，学习了，多谢了。

lcsccc

多谢，好东西啊

liuyin029

谢谢分享！学习啦！

nliang2011

谢谢分享!!