如何获取多个工作簿中的公共名称的工作表，并显示名称

a8737461

如果在某一路径下含有3个工作簿，他们都有三个工作表，workbook（1）中的三个工作表中的名称分别为 工资，奖金，人员
                                                     workbook（2）中的三个工作表中的名称分别为 工资，奖金，人员1
                                                                                             workbook（3）中的三个工作表中的名称分别为 工资，奖金1，人员那么这三个工作簿的公共工作表就是“工资”，如果在不知道三个工作簿含有什么工作表的前提下，如何通过VBA
得出他们的公共工作表呢？例子见附表

kevinchengcw

Private Sub CommandButton1_Click()
Dim Dic, Arr
Dim Ws As Worksheet
Dim Wb As Workbook
Dim Fn As String
Dim N, I As Integer
Set Dic = CreateObject("scripting.dictionary")
Fn = Dir(ThisWorkbook.Path & "\分表\*.xls")
N = 0
Do While Fn <> ""
    Set Wb = GetObject(ThisWorkbook.Path & "\分表\" & Fn)
    For Each Ws In Wb.Worksheets
        If Not Dic.exists(Ws.Name) Then
            Dic.Add Ws.Name, 1
        Else
            Dic(Ws.Name) = Dic(Ws.Name) + 1
        End If
    Next Ws
    N = N + 1
    Wb.Close False
    Fn = Dir
Loop
Set Wb = Nothing
If N > 0 And Dic.Count > 0 Then
    Arr = Dic.keys
    For I = LBound(Arr) To UBound(Arr)
        If Dic(Arr(I)) < N Then Dic.Remove Arr(I)
    Next I
    [a2].Resize(Dic.Count, 1) = Application.Transpose(Dic.keys)
End If
Set Dic = Nothing
End Sub

美妙与夏天

一个自绘按钮类，该怎样写它的获取按钮名称函数呢?例如GetButtonText()

a8737461

谢谢 字典用法啊