如何用宏来删除其中两科分数为0的学生

qjw9004

请高手指点~~~~~~~~~~~

huiz999

Sub 删除() '方法一
Dim i As Integer
Dim y As Integer
Dim rng As Range, arr
Application.ScreenUpdating = False
Range("f3:f" & [a65536].End(xlUp).Row).FormulaR1C1 = "=COUNTIF(RC[-4]:RC[-1],0)"

On Error Resume Next
arr = Range("f3:f" & [a65536].End(xlUp).Row).Value
For i = 1 To UBound(arr)
If arr(i, 1) = 2 Then
If rng Is Nothing Then
Set rng = Rows(i + 2)
Else
Set rng = Union(rng, Rows(i + 2))
End If
End If
Next
rng.EntireRow.Delete
Application.ScreenUpdating = True

End Sub

gyzzf

Sub 删除两科分数为0的学生()
    Dim i As Long
    Dim n%, j%, k%
    i = [a65536].End(xlUp).Row
    For j = i To 3 Step -1
        n = 0
        For k = 2 To 5
            If Cells(j, k) = 0 Then
                n = n + 1
            End If
        Next
        If n >= 2 Then
            Rows(j).Delete
        End If
    Next
End Sub

qjw9004

谢谢！~~
3楼的老师能说一下代码的含义吗？

LAOMALIN

F1是学习VBA最好的老师,因为这些已经是最简单的代码了

qjw9004

F2解释下代码好吗?

[ 本帖最后由 qjw9004 于 2009-7-5 16:20 编辑 ]

gyzzf

原帖由 qjw9004 于 2009-7-5 00:08 发表
谢谢！~~
3楼的老师能说一下代码的含义吗？

Sub 删除两科分数为0的学生()
    Dim i As Long
    Dim n%, j%, k%
    i = [a65536].End(xlUp).Row   '取得A列最后非空行号
    For j = i To 3 Step -1    '建立j的值从i到3的循环，每次步进-1
        n = 0
        For k = 2 To 5
            If Cells(j, k) = 0 Then    '查找j行科目成绩为0的单元格并记数，赋值给n
                n = n + 1
            End If
        Next
        If n >= 2 Then   '判断j行是否两科以上为0分
            Rows(j).Delete   '如果是则删除j行
        End If
    Next
End Sub

qjw9004

留个Q号~~以后多多指教!~~