请高手们帮我看看怎么解决

yuan710825

详情请看附件,请各位高手出招

zhaogang1960

请测试：
Sub bbb()
    Dim arr, arr2, brr(), x As WorksheetFunction
    Dim lr As Long, lc As Integer, i As Long, j As Integer, k As Integer, c As Integer, r As Integer
    c = 5
    Set x = WorksheetFunction
    arr = ActiveSheet.UsedRange
    Sheets("整理后").Cells.ClearContents
    lr = 2
    For i = 1 To UBound(arr)
        lc = x.CountA(x.Index(arr, i, 0))
        If lc > 0 Then
            r = x.RoundUp(lc / c, 0)
            ReDim brr(1 To r, 1 To c)
            arr2 = x.Index(arr, i, 0)
            For j = 1 To r
                For k = 1 To c
                    If (j - 1) * c + k <= lc Then brr(j, k) = arr2((j - 1) * c + k)
                Next k
            Next j
            With Sheets("整理后")
                .Range("a" & lr).Resize(r, c) = brr
                lr = lr + r + 2
            End With
        End If
    Next
End Sub

yuan710825

还是要请教各位高手,本意是这样的,在一个人事系统里用SQL提取出数据生成一个一维数组,想输入excel工作表,但每行不超过11个数据,我用for循环嵌套了四层,结果效率就太低,更新一次大概要一分钟(数据比较多),有没有比较好的方法,望高手们赐教!帮我解决一下上面的附件,谢谢!
比较急用,想了几天还是没有眉目.

yuan710825

先谢谢zhaogong1960,我去测试一下,可能要再次麻烦你

yuan710825

Sub bbb()
    Dim arr, arr2, brr(), x As WorksheetFunction
    Dim lr As Long, lc As Integer, i As Long, j As Integer, k As Integer, c As Integer, r As Integer
    c = 5
    Set x = WorksheetFunction
    arr = ActiveSheet.UsedRange
    Sheets("整理后").Cells.ClearContents
    lr = 2
    For i = 1 To UBound(arr)
        lc = x.CountA(x.Index(arr, i, 0))
        If lc > 0 Then
            r = x.RoundUp(lc / c, 0)
            ReDim brr(1 To r, 1 To c)
            arr2 = x.Index(arr, i, 0)
            For j = 1 To r
                For k = 1 To c
                    If (j - 1) * c + k <= lc Then brr(j, k) = arr2((j - 1) * c + k)
                Next k
            Next j
            With Sheets("整理后")
                .Range("a" & lr).Resize(r, c) = brr
                lr = lr + r + 2
            End With
        End If
    Next
End Sub
zhaogong1960,您好.能否将您的代码加上注释呢,谢谢,真的有点看不懂,特别是红色的代码

[ 本帖最后由 yuan710825 于 2009-4-24 22:38 编辑 ]

zhaogang1960

注释如下:
Sub bbb()
    Dim arr, arr2, brr(), x As WorksheetFunction
    Dim lr As Long, lc As Integer, i As Long, j As Integer, k As Integer, c As Integer, r As Integer
    c = 5 '要求整理后列宽
    Set x = WorksheetFunction
    arr = ActiveSheet.UsedRange '活动工作表已经使用区域赋予数组
    Sheets("整理后").Cells.ClearContents '清除数据
    lr = 2 '从第二行开始
    For i = 1 To UBound(arr) '逐行
        lc = x.CountA(x.Index(arr, i, 0)) '第i行数据个数
        If lc > 0 Then '有数据
            r = x.RoundUp(lc / c, 0) '该行转换后最大行数
            ReDim brr(1 To r, 1 To c) '重新定义二维数组
            arr2 = x.Index(arr, i, 0) '有数据行赋予一个一维数组
            For j = 1 To r '二维数组逐行
                For k = 1 To c '二维数组逐列
                    If (j - 1) * c + k <= lc Then brr(j, k) = arr2((j - 1) * c + k) '一维数组转为二维数组
                Next k
            Next j
            Sheets("整理后").Range("a" & lr).Resize(r, c) = brr '写到"整理后"工作表
            lr = lr + r + 2 '数组插入起点+数组最大行数，再空出来两行
        End If
    Next
End Sub

yuan710825

谢谢zhaogong1960,此问题在您的帮助下解决,谢谢!

yuan710825

领教了内存数组的高效,还想请问一下,我在excel工作表中提取数据时,是用ado+sql高效(我现在是用SQL提取数据的)还是用数据字典高效?望赐教.