[第38期]各区各组相遇时间 [已总结]

bzfhl

占位

总算作到400以下了

公式长度352:

="第"&SUBSTITUTE(TEXT(SUM(--ISTEXT($A$1:A2)),"[dbnum1]"),"一十","十")&"考区"&IF(B2="",":"," 第"&TEXT(ROW()-LARGE(ISTEXT($A$1:A2)*ROW($A$1:A2),1),"00")&"组答案 "&TEXT(TEXT(A2*100,"0\:00\:00")+(TEXT(B2*100,"0\:00\:00")-TEXT(A2*100,"0\:00\:00")+TEXT(C2*100,"00\:00")/60)/(1-TEXT(C2*100,"00\:00")/60/(TEXT(B2*100,"0\:00\:00")-TEXT(A2*100,"0\:00\:00"))),"hh时mm分ss秒"))

QUOTE:

完成了数学题,具有使用EXCEL函数来实现结果的知识,但没有进行优化,所以公式较长.

答案正确,符合答题要求,公式长度小于400字,得1分. -willin2000

[此贴子已经被willin2000于2008-8-30 23:46:52编辑过]

nocrying

答案已发至版主邮箱willin2000@yahoo.cn，谢谢！

公式长度249:

=TEXT(SUM(N(B$1:B1="")),"第[DBNum1]d考区")&IF(B1,TEXT(ROW()-MAX(NOT(B$1:B1)*ROW($1:1))+2*(TEXT(C1/1%,"0!:00")/60)^2/(SUM(TEXT(A1:B1/1%,"0!:00!:00")*{-1,1})-TEXT(C1/1%,"0!:00")/60)+TEXT(C1/1%,"0!:00")/30+TEXT(B1/1%,"0!:00!:00")," 第dd组答案 hh时mm分ss秒"),":")

QUOTE:

公式架构基本正确,而且2个主体TEX也非常正确. 只是计算时间部分还可以进一步优化.

答案正确,符合答题要求,公式长度少于280字, 得2分. -willin2000

[此贴子已经被willin2000于2008-8-30 23:50:41编辑过]

lws

答案已发送,请willin2000版主查收.

公式长度,220个字符:

=TEXT(COUNTBLANK(B$1:B1),"第[DBNUM1]D考区")&IF(B1,TEXT(ROW()-MATCH("々",A$1:A1)+PRODUCT((SUM(TEXT(A1:B1/1%,"0!:00!:00")*{-1,1})+("0:"&TEXT(C1/1%,"0!:00"))*{0,1,-1})^{1,1,-1})+TEXT(A1/1%,"0!:00!:00")," 第DD组答案 HH时MM分SS秒"),":")

QUOTE:

公式架构基本正确,2个主体TEX也非常正确.  计算时间优化的也很不错,不过还有改进的余地.

答案正确,符合答题要求,公式长度少于240字, 得3分. -willin2000

[此贴子已经被willin2000于2008-8-30 23:55:47编辑过]

jxrbz

答案已经发到 willin2000@yahoo.cn  邮箱

397字符 跟帖站位:

=TEXT(COUNTBLANK(B$1:B1),"第"&"[DBNum1]d"&"考区")&IF(B1<>"",TEXT(ROW()-MAX(ROW(B$1:B1)*(B$1:B1=""))," 第"&"00"&"组答案 ")&TEXT((TEXT(A1*100,"00!:00!:00")+(TEXT(B1*100,"00!:00!:00")-TEXT(A1*100,"00!:00!:00"))*(TEXT(B1*100,"00!:00!:00")-TEXT(A1*100,"00!:00!:00")+(INT(C1)*60+RIGHT(C1*100,2))/86400)/(TEXT(B1*100,"00!:00!:00")-TEXT(A1*100,"00!:00!:00")-(INT(C1)*60+RIGHT(C1*100,2))/86400)),"hh时mm分ss秒"),":")

QUOTE:

完成了数学题,具有使用EXCEL函数来实现结果的知识,除转标准时间格式的方式做得太复杂了,其他函数部分掌握的还不错.

答案正确,符合答题要求,公式长度小于400字,得1分. -willin2000

[此贴子已经被willin2000于2008-8-31 0:06:06编辑过]

micohui

答案已发送!占个位先!看是否有高手用调和平均数函数HARMEAN得到结果,自己弄了半天也弄不出来.

公式长度211:

=TEXT(SUM(N(A$1:A1>="吖")),"[dbnum1]第D考区")&TEXT(ROW()-MATCH(REPT("座",255),A$1:A1)+IF(A1<"吖",TEXT(B1/1%,"0!:00!:00")+2/(60/TEXT(C1/1%,"0!:00")-1/(SUM(TEXT(A1:B1/1%,"0!:00!:00")*{-1,1})))),"[>] 第dd组答案 hh时mm分ss秒;:")

=TEXT(SUM((A$1:A1>="吖")*1),"[dbnum1]第D考区")&TEXT(ROW()-MAX((A$1:A1>="吖")*ROW($1:1))+IF(A1<"吖",TEXT(B1/1%,"0!:00!:00")+TEXT(C1/1%,"0!:00")/30*(1+1/(SUM(TEXT(A1:B1/1%,"0!:00!:00")*{-1,1})/TEXT(C1/1%,"0!:00")*60-1))),"[>] 第dd组答案 hh时mm分ss秒;:")

QUOTE:

公式整体结构完全正确, 细节和2楼一样 "[>] 第dd组答案 hh时mm分ss秒;:" 可以用" 第dd组答案 hh时mm分ss秒;;:"等等. 计算时间部分优化的更好了, 不过也是略有优化的余地.

答案正确,符合答题要求,公式长度少于240字, 得3分. -willin2000

[此贴子已经被willin2000于2008-8-31 0:11:35编辑过]

galaxy123456

发送至邮箱,跟贴占位.

公式长度240:

=TEXT(SUM(--(A$1:A1>="吖")),"第[DBNum1]d考区")&IF(B1,TEXT(ROW()-MAX((A$1:A1>="吖")*ROW($1:1))+(TEXT(B1/1%,"0!:00!:00")+TEXT(C1/1%,"0!:00")/30*(1+1/(SUM(TEXT(A1:B1/1%,"0!:00!:00")*{-1,1})/TEXT(C1/1%,"0!:00")*60-1))),"[>1]! 第dd组答案 hh时mm分ss秒"),":")

QUOTE:

公式架构除IF的位置其他部分正确,计算时间部分优化的还可以,如果其中的任何一个再优化一下就可以小于240了,现在正好是240,没有满足评分要求3,只能屈居季军.

答案正确,符合答题要求,公式长度少于280字, 得2分. -willin2000

[此贴子已经被willin2000于2008-8-31 0:18:19编辑过]

jonnni

我也做了一个，刚好399，嘿嘿。后来发现还可以短一点点。。。

公式长度399:

="第"&TEXT(COUNTIF($B$1:$B1,"="),"[dbnum1]")&"考区"&IF(B1="","："," 第"&TEXT(ROW()+SMALL(IF($B$1:$B1="",-ROW($B$1:$B1),0),1),"00")&"组答案 "&TEXT(((INT(C1)+MOD(C1,1)/0.6)+2*(INT(C1)+MOD(C1,1)/0.6)^2/(INT(B1/100)*60+INT(MOD(B1,100))+MOD(B1,1)/0.6-INT(A1/100)*60-INT(MOD(A1,100))-MOD(A1,1)/0.6-(INT(C1)+MOD(C1,1)/0.6))+(INT(C1)+MOD(C1,1)/0.6)+INT(B1/100)*60+INT(MOD(B1,100))+MOD(B1,1)/0.6)/60/24,"hh时mm分ss秒"))

数学题做对了, 时间格式转换部分没有使用TEXT的方法,造成公式很长,超过第九区后结果和示例结果不相等.

QUOTE:

结果不完全正确,不符合答题要求3, 不得分. -willin2000

[此贴子已经被willin2000于2008-8-31 0:25:00编辑过]

willin2000

本题的主要考点是为了强调除思路和方法能简化公式外,函数的不同方式组合也是优化公式的方法之一也能优化公式.

本题涉及的主要是数学表达式引用单元格次数的最小化.

另外本题还复习了一下关于计数和TEXT的应用,及重温了数学中多个变量合并为一个变量解应用题的方法(x+z=xx,y+z=yy).

我的公式,190个字符:
=TEXT(SUM(N(C$1:C1=0)),"第[DBnum1]d考区")&TEXT(ROW()-MATCH("々",A$1:A1)+IF(C1,2/(60/TEXT(C1/1%,"0!:00")+1/SUM(TEXT(A1:B1/1%,"0!:00!:00")*{1,-1}))+TEXT(B1/1%,"0!:00!:00"))," 第dd组答案 hh时mm分ss秒;;:")

本题涉及到一道小学数学题,下面解释一下思路(为了不偏科,硬是凑用了苏轼的一首词,呵呵).

明月几时有？把酒问青天。
SUM(N(B$1:B1=0))=明月
计算第几区

不知天上宫阙，今夕是何年？
ROW()-MATCH("々",A$1:A1)=何年
计算第几组

我欲乘风归去，又恐琼楼玉宇，高处不胜寒。
IF(C1,...)
"高处"为0.

起舞弄清影，何似在人间？
甲乙从出发到相遇花的时间是t1=(b1-a1), 到甲丙与乙丙距离相等又花了时间是t2=c1.假使再花时间t乙丙相遇,也就是从开始出发到乙丙相遇总共花的时间是t1+t2+t.假定两地的距离为d,根据已知条件可以得到下面等式:
(1) t1x+t1z=d
(2) d-(t1+t2)z-(t1+t2)y=(t1+t2)x-(d-(t1+t2)z)
(3) (t1+t2+t)y+(t1+t2+t)z=d

分别将方程(2),(3)中的d用(1)的t1x+t1z替换.可以得到:
(2') (t1-t2)(x+z)=(t1+t2)(y+z)
(3') (y+z)t=t1(x+z)-(t1+t2)(y+z)

用(2') 求出(x+z):
(2") (x+z)=(t1+t2)(y+z)/(t1-t2)

再将(3')中的(x+z)用(2")的(t1+t2)(y+z)/(t1-t2)替换:
(y+z) t=t1(t1+t2)(y+z)/(t1-t2)-(t1+t2)(y+z)

这样(y+z)作为公约变量可以去掉了:
(3") t=t1(t1+t2)/(t1-t2)-(t1+t2)=t2(t1+t2)/(t1-t2)=c1(B1-A1+C1)/(B1-A1-C1)

转朱阁，低绮户，照无眠。不应有恨、何事长向别时圆？
相遇时刻:
=t+B1+C1=c1(B1-A1+C1)/(B1-A1-C1)+B1+C1=C1((B1-A1+C1)/(B1-A1-C1)+1)+B1=2C1(B1-A1)/(B1-A1-C1)+B1=2C1/(1-C1/(B1-A1))+B1=2/(1/C1-1/(B1-A1))+B1=2/(1/C1+1/(A1-B1)+B1
即"相遇"=2/(60/TEXT(C1/1%,"0!:00")+1/SUM(TEXT(A1:B1/1%,"0!:00!:00")*{1,-1}))+TEXT(B1/1%,"0!:00!:00")
通过改变各引用单元格在公式中的左右/上下位置,进行组合,目的是将每个单元格被引用的次数尽可能地少.这是本题的关键.也就是想通过本题让大家知道,即使思路和方法确定了,还是有可能通过不同的组合方式来简化.

人有悲欢离合，月有阴晴圆缺，此事古难全。
TEXT(明月,"第[DBnum1]d考区")
TEXT(何年+相遇," 第dd组答案 hh时mm分ss秒;;:")
还是用老朋友TEXT来照顾一下盈亏.

但愿人长久，千里共婵娟。
=TEXT(...,"第[DBnum1]d考区")&TEXT(..," 第dd组答案 hh时mm分ss秒;;:")
两个TEXT比翼双飞,完成本题的最终要求.

[此贴子已经被作者于2008-9-2 8:07:50编辑过]

gouweicao78

出题的时候做了个237字的

=TEXT(SUM(N(A$1:A2>"")),"[dbnum1]第d考区")&IF(A2<"",TEXT(ROW()-MATCH("