如何判断excel中的单元格是否在编辑状态

xxlzg

如何判断excel中的单元格是否在编辑状态

因为如果在编辑状态时，自定义的按钮中的宏就不能运行。

xxlzg

下面的好像没用

返回或设置“数据输入”模式，如下表所示。处于“数据输入”模式时，仅可在当前选定区域的未锁定单元格中输入数据。Long 类型，可读写。

值	含义
xlOn	“数据输入”模式处于打开状态。
xlOff	“数据输入”模式处于关闭状态。
xlStrict	“数据输入”模式处于打开状态，并且按 Esc 时不关闭数据输入模式。

示例

本示例检查“数据输入”模式是否处于打开状态，如果是，则关闭之。

If (Application.DataEntryMode = xlOn) Or _
    (Application.DataEntryMode = xlStrict) Then
        Application.DataEntryMode = xlOff
End If
	

wangminbai

用API是可以判断的，但是不知道有什么用处

xxlzg

用api怎么判断？

我用vb操作excel，如果excel的单元格在编辑状态，操作就不能进行。

而如果在excel中，只是程序不能运行，而用vb的话，就会出现部件要求挂起和部件忙

tianying

编辑状态时宏暂停运行，除非使用外部的线程监控，很麻烦

xxlzg

我找到方法了

用vb的appactivate激活excel

然后发送一个sendkey esc

tianying

QUOTE:

以下是引用xxlzg在2008-2-2 11:34:33的发言：

我找到方法了

用vb的appactivate激活excel

然后发送一个sendkey esc

那你怎么知道Excel何时处于编辑状态呢？一直sendkey吗？

taller

QUOTE:

以下是引用tianying在2008-2-2 11:26:59的发言：
编辑状态时宏暂停运行，除非使用外部的线程监控，很麻烦

正确。Excel编辑状态下，VBA代码无法运行，楼主需要考虑用VB监控OS实现

wangminbai

QUOTE:

以下是引用taller在2008-2-2 13:20:11的发言：

正确。Excel编辑状态下，VBA代码无法运行，楼主需要考虑用VB监控OS实现

使用钩子函数应该可以判断的，以下代码就是当处于编辑状态时在Excel的状态栏上显示 正处于编辑状态……

 

'**********************************************************************************************************
'**********************************************************************************************************
'//取得类名
Private Declare Function GetClassName _
    Lib "user32" _
    Alias "GetClassNameA" ( _
        ByVal hwnd As Long, _
        ByVal lpClassName As String, _
        ByVal nMaxCount As Long) _
As Long
'//设置钩子函数
Public Declare Function SetWindowsHookEx _
    Lib "user32" _
    Alias "SetWindowsHookExA" ( _
        ByVal idHook As Long, _
        ByVal lpfn As Long, _
        ByVal hmod As Long, _
        ByVal dwThreadId As Long) _
As Long
'//结束钩子
Public Declare Function UnhookWindowsHookEx _
    Lib "user32" ( _
        ByVal hHook As Long) _
As Long
'//下一个钩子
Public Declare Function CallNextHookEx _
    Lib "user32" ( _
        ByVal hHook As Long, _
        ByVal nCode As Long, _
        ByVal wParam As Long, _
        lparam As Any) _
As Long
'//取得当前线程的ID
Public Declare Function GetCurrentThreadId _
    Lib "kernel32" () _
As Long

Public Const HCBT_SETFOCUS = 9
Public Const WH_CBT = 5
Public IHook As Long
Public IThreadId As Long
Public ClassName As String
'-------设置钩子-----------
Public Sub EnableHook()
    If IHook = 0 Then
        IThreadId = GetCurrentThreadId
        IHook = SetWindowsHookEx(WH_CBT, AddressOf HookProc, Application.Hinstance, IThreadId)
    End If
End Sub
'-------取消钩子-----------
Public Sub FreeHook()
    If IHook <> 0 Then
        Call UnhookWindowsHookEx(IHook)
        IHook = 0
    End If
End Sub
'---------回调----------------
Public Function HookProc(ByVal nCode As Long, ByVal wParam As Long, ByVal lparam As Long) As Long
    If nCode < 0 Then
        HookProc = CallNextHookEx(IHook, nCode, wParam, lparam)
        Exit Function
    End If
    If nCode = HCBT_SETFOCUS Then
        ClassName = String(255, Chr(0))
        GetClassName wParam, ClassName, 255
        ClassName = Left(ClassName, InStr(ClassName, vbNullChar) - 1)
        If ClassName = "EXCEL<" Or ClassName = "EXCEL6" Then
            Application.StatusBar = "正处于编辑状态……"
        Else
            Application.StatusBar = False
        End If
    End If
    HookProc = CallNextHookEx(IHook, nCode, wParam, lparam)
End Function

 

rKpDCzYe.rar (9.79 KB, 下载次数: 278)

2008-2-2 14:25 上传

点击文件名下载附件
如何判断excel中的单元格是否在编辑状态

tianying

wangminbai兄做的好，受益了！