ExcelHome技术论坛

 找回密码
 免费注册

QQ登录

只需一步,快速开始

快捷登录

搜索
EH技术汇-专业的职场技能充电站 妙哉!函数段子手趣味讲函数 Excel服务器-会Excel,做管理系统 Excel Home精品图文教程库
HR薪酬管理数字化实战 Excel 2021函数公式学习大典 Excel数据透视表实战秘技 打造核心竞争力的职场宝典
300集Office 2010微视频教程 数据工作者的案头书 免费直播课集锦 ExcelHome出品 - VBA代码宝免费下载
用ChatGPT与VBA一键搞定Excel WPS表格从入门到精通 Excel VBA经典代码实践指南
楼主: 山菊花

[Excel 函数与公式] [第20期]把数字连接起来

[复制链接]

TA的精华主题

TA的得分主题

发表于 2007-2-6 00:08 | 显示全部楼层
[广告] Excel易用宝 - 提升Excel的操作效率 · Excel / WPS表格插件       ★免费下载 ★       ★ 使用帮助

答案已发送。(我的第1500条帖子,又向前挪了一级)

====

=CONCATENATE(SUM(A2:J2),SUM(K2:T2),SUM(U2:AD2),SUM(AE2:AN2),SUM(AO2:AX2),SUM(AY2:BH2),SUM(BI2:BR2))

[此贴子已经被山菊花于2007-2-21 11:25:05编辑过]

TA的精华主题

TA的得分主题

发表于 2007-2-6 08:14 | 显示全部楼层
[广告] VBA代码宝 - VBA编程加强工具 · VBA代码随查随用  · 内置多项VBA编程加强工具       ★ 免费下载 ★      ★使用手册

答题已发送到dsjb@21cn.com

====

{=TEXT(SUM((A2:BR2)*10^(7-MATCH(COLUMN(A2:BR2),10*ROW($1:$7)-9,1))),REPT("0",7))}

[此贴子已经被山菊花于2007-2-21 11:28:43编辑过]

TA的精华主题

TA的得分主题

发表于 2007-2-6 08:23 | 显示全部楼层

答案已经发送.答案已经发送.答案已经发送.答案已经发送.答案已经发送.

====

=LARGE(A2:J2,1)&LARGE(K2:T2,1)&LARGE(U2:AD2,1)&LARGE(AE2:AN2,1)&LARGE(AO2:AX2,1)&LARGE(AY2:BH2,1)&LARGE(BI2:BR2,1)

[此贴子已经被山菊花于2007-2-21 11:29:49编辑过]

TA的精华主题

TA的得分主题

发表于 2007-2-6 15:54 | 显示全部楼层

题目和前一期的内容有点重复了,凑个热闹。

====

{=TEXT(SUM(RIGHT(LARGE(IF(A2:BR2<>"",COLUMN(A2:BR2)*10+A2:BR2),ROW($1:$7)))*10^(ROW($1:$7)-1)),"0000000")}

QUOTE:

叶相似而花不同,呵。

——山菊花

[此贴子已经被山菊花于2007-2-21 11:33:48编辑过]

TA的精华主题

TA的得分主题

发表于 2007-2-7 11:33 | 显示全部楼层
[广告] VBA代码宝 - VBA编程加强工具 · VBA代码随查随用  · 内置多项VBA编程加强工具       ★ 免费下载 ★      ★使用手册

答案已通过短消息发送。

占个位置,请老师给看看。

谢谢!

====

{=TEXT(SUM(N(INDIRECT("r"&ROW()&"c"&SMALL(IF(A2:BR2<>"",COLUMN(A2:BR2)),COLUMN($A$2:$G$2)),))*TRANSPOSE(10^(7-ROW($1:$7)))),"0000000")}

QUOTE:

“INDIRECT("r"&ROW()&"c"……)”可简化为“INDIRECT("rc"……)”,R后面没有行号,表示引用本行。

“TRANSPOSE(10^(7-ROW($1:$7)))”可用“10^(7-COLUMN(A:G))”。

公式简化为:

{=TEXT(SUM(N(INDIRECT("rc"&SMALL(IF(A2:BR2<>"",COLUMN(A2:BR2)),COLUMN($A:$G)),))*10^(7-COLUMN(A:G))),"0000000")}

——山菊花

{=TEXT(MMULT(SUBTOTAL(9,OFFSET($A$2:$J$2,ROW($A$2:$A$14)-2,(COLUMN($A$2:$G$2)-1)*10)),10^(7-ROW($1:$7))),"0000000")}

QUOTE:

OFFSET()引用了与结果无关的区域,造成大量多余的运算。MMULT()用得也不够灵活。公式是个普通公式,不用按三键。公式可简化为:

=TEXT(MMULT(10^(7-COLUMN($A:$G)),SUBTOTAL(9,OFFSET(A2,,(ROW($1:$7)-1)*10,,10))),"0000000")

——山菊花

{=TEXT(MMULT(SUMIF(OFFSET($A$2:$J$2,ROW($A$2:$A$14)-2,(COLUMN($A$2:$G$2)-1)*10),"<>"),10^(7-ROW($1:$7))),"0000000")}
   

QUOTE:

用SUMIF()代替SUBTOTAL(),好。不足之处同上。

——山菊花

QUOTE:

用SUMIF()代替SUBTOTAL(),好。不足之处同上。

——山菊花

[此贴子已经被山菊花于2007-2-21 11:56:07编辑过]

TA的精华主题

TA的得分主题

发表于 2007-2-7 15:35 | 显示全部楼层

凑个热闹,呵呵。

答案已发送。

====

=SUM(A2:J2)&SUM(K2:T2)&SUM(U2:AD2)&SUM(AE2:AN2)&SUM(AO2:AX2)&SUM(AY2:BH2)&SUM(BI2:BR2)

{=TEXT(SUM(SUMIF(OFFSET(A2:J2,,70-COLUMN(A:G)*10),"<>")*10^COLUMN(A:G))/10,REPT(0,7))}

[此贴子已经被山菊花于2007-2-21 11:49:45编辑过]

TA的精华主题

TA的得分主题

发表于 2007-2-7 15:37 | 显示全部楼层

吾用了超笨的方法。还没想到好办法。

=CONCATENATE(SUM(A2:J2),SUM(K2:T2),SUM(U2:AD2),SUM(AE2:AN2),SUM(AO2:AX2),SUM(AY2:BH2),SUM(BI2:BQ2))

TA的精华主题

TA的得分主题

发表于 2007-2-7 15:39 | 显示全部楼层

答案已发送

====

=SUM(A2:J2)&SUM(K2:T2)&SUM(U2:AD2)&SUM(AE2:AN2)&SUM(AO2:AX2)&SUM(AY2:BH2)&SUM(BI2:BR2)

[此贴子已经被山菊花于2007-2-21 13:40:16编辑过]

TA的精华主题

TA的得分主题

发表于 2007-2-7 21:11 | 显示全部楼层

只想到一个很笨的数组公式,不知对否

====

{=MAX(IF($A2:$J2<>"",COLUMN($A2:$J2)-1,0))&MAX(IF($K2:$T2<>"",COLUMN($A2:$J2)-1,0))&MAX(IF($U2:$AD2<>"",COLUMN($A2:$J2)-1,0))&MAX(IF($AE2:$AN2<>"",COLUMN($A2:$J2)-1,0))&MAX(IF($AO2:$AX2<>"",COLUMN($A2:$J2)-1,0))&MAX(IF($AY2:$BH2<>"",COLUMN($A2:$J2)-1,0))&MAX(IF($BI2:$BR2<>"",COLUMN($A2:$J2)-1,0))}

{=TEXT(SUM((A2:BR2<>"")*MOD(COLUMN(A2:BR2)-1,10)*(10^(6-INT((COLUMN(A2:BR2)-1)/10)))),"0000000")}

QUOTE:

用MOD(column(),10)取代区域中的数据,是一个新的角度。公式不错。

——山菊花

[此贴子已经被山菊花于2007-2-21 13:47:01编辑过]

TA的精华主题

TA的得分主题

发表于 2007-2-8 05:25 | 显示全部楼层

答案已发送。

(答案发送到论坛短信)

====

=SUM(A2:J2)&SUM(K2:T2)&SUM(U2:AD2)&SUM(AE2:AN2)&SUM(AO2:AX2)&SUM(AY2:BH2)&SUM(BI2:BR2)

[此贴子已经被山菊花于2007-2-21 13:47:51编辑过]
您需要登录后才可以回帖 登录 | 免费注册

本版积分规则

手机版|关于我们|联系我们|ExcelHome

GMT+8, 2024-3-29 19:42 , Processed in 0.044143 second(s), 13 queries , Gzip On, Redis On.

Powered by Discuz! X3.4

© 1999-2023 Wooffice Inc.

沪公网安备 31011702000001号 沪ICP备11019229号-2

本论坛言论纯属发表者个人意见,任何违反国家相关法律的言论,本站将协助国家相关部门追究发言者责任!     本站特聘法律顾问:李志群律师

快速回复 返回顶部 返回列表