ExcelHome技术论坛

 找回密码
 免费注册

QQ登录

只需一步,快速开始

   
EH云课堂-专业的职场技能充电站 Excel转在线管理系统,怎么做看这里 Excel服务器-会Excel,做管理系统 Excel Home精品图文教程库
Excel不给力? 何不试试FoxTable! Excel 2016函数公式学习大典 高效办公必会的Office实战技巧 免费下载Excel行业应用视频
300集Office 2010微视频教程 Tableau-数据可视化工具 精品推荐-800套精选PPT模板,点击获取 ExcelHome出品 - VBA代码宝免费下载
你的Excel 2010实战技巧学习锦囊 欲罢不能, 过目难忘的 Office 新界面 Excel VBA经典代码实践指南
查看: 15635|回复: 73

[Excel 函数与公式] [第20期]把数字连接起来

[复制链接]

TA的精华主题

TA的得分主题

发表于 2007-2-4 12:06 | 显示全部楼层 |阅读模式

难度:★★


特别注意:

答案请以邮件的形式发至dsjb@21cn.com

或者把公式用短消息发送给山菊花

相关链接:
  
[公告] 紧急通知
 

[此贴子已经被作者于2007-2-28 0:38:45编辑过]
单选投票, 共有 32 人参与投票

距结束还有: 5482 天15 小时2 分钟

您所在的用户组没有投票权限

本帖子中包含更多资源

您需要 登录 才可以下载或查看,没有帐号?免费注册

x

TA的精华主题

TA的得分主题

发表于 2007-2-4 12:38 | 显示全部楼层

在BS2单元格填写下列数组公式后下拉填充:

=TEXT(SUMPRODUCT(N(OFFSET(A2,,SMALL(IF(A2:BR2<>"",COLUMN(A2:BR2)),COLUMN(A:G))-1))*10^(7-COLUMN(A:G))),"0000000")

TA的精华主题

TA的得分主题

发表于 2007-2-4 13:39 | 显示全部楼层
BS1=SUM(OFFSET($A$1,ROW()-1,0,1,10))&SUM(OFFSET($A$1,ROW()-1,10,1,10))&SUM(OFFSET($A$1,ROW()-1,20,1,10))&SUM(OFFSET($A$1,ROW()-1,30,1,10))&SUM(OFFSET($A$1,ROW()-1,40,1,10))&SUM(OFFSET($A$1,ROW()-1,50,1,10))&SUM(OFFSET($A$1,ROW()-1,60,1,10))

TA的精华主题

TA的得分主题

发表于 2007-2-4 14:03 | 显示全部楼层

碰到会做的了,试试能否赚点分。答题已发送。

====

=MAX($A2:$J2)&MAX($K2:$T2)&MAX($U2:$AD2)&MAX($AE2:$AN2)&MAX($AO2:$AX2)&MAX($AY2:$BH2)&MAX($BI2:$BR2)

=CONCATENATE(MAX($A2:$J2),MAX($K2:$T2),MAX($U2:$AD2),MAX($AE2:$AN2),MAX($AO2:$AX2),MAX($AY2:$BH2),MAX($BI2:$BR2))

[此贴子已经被山菊花于2007-2-21 10:43:52编辑过]

TA的精华主题

TA的得分主题

发表于 2007-2-4 15:27 | 显示全部楼层

答案已经发到邮箱,请查收

====

{=TEXT(SUM(N(OFFSET(A2,,LARGE(IF(A2:BR2<>"",COLUMN(A2:BR2)),ROW(INDIRECT("1:7")))-1))*(10^(ROW(INDIRECT("1:7"))-1))),"0000000")}

[此贴子已经被山菊花于2007-2-21 10:45:14编辑过]

TA的精华主题

TA的得分主题

发表于 2007-2-4 15:38 | 显示全部楼层

答案已发送,请查收!!!

====

{=IF(COUNTIF(A2:J2,0),0,"")&SUM(LARGE((A2:BR2)*10^(ROUNDUP(71-COLUMN(A2:BR2),-1)/10),ROW($A$1:$A$7)))/10}

QUOTE:

格式不正确,当前面有两个0时出错。

公式中的LARGE()多余了,除了最大的7位数以外,其余值都是0,前7位最大值的和与所有数的和,结果相等。

公式可简化为:{=TEXT(SUM(A2:BR2*10^(7-ROUNDUP(COLUMN(A2:BR2)/10,0))),"0000000")}

——山菊花

=REPT(0,7-LEN(SUM(SUMIF(OFFSET(A2:J2,,(ROW($A$1:$A$7)-1)*10,),">0")*10^(8-ROW($A$1:$A$7)))/10))&SUM(SUMIF(OFFSET(A2:J2,,(ROW($A$1:$A$7)-1)*10,),">0")*10^(8-ROW($A$1:$A$7)))/10

QUOTE:

公式中的“(……)*10^(8-ROW($A$1:$A$7)))/10”可简化为“(……)*10^(7-ROW($A$1:$A$7)))”。

用TEXT()取代前面的“REPT()&”可缩短公式。

=TEXT(SUM(SUMIF(OFFSET(A2:J2,,(ROW($1:$7)-1)*10,),">0")*10^(7-ROW($1:$7))),"0000000")

——山菊花

=REPT(0,7-LEN(SUM(LARGE((A2:BR2)*10^(ROUNDUP(71-COLUMN(A2:BR2),-1)/10),ROW($A$1:$A$7)))/10))&SUM(LARGE((A2:BR2)*10^(ROUNDUP(71-COLUMN(A2:BR2),-1)/10),ROW($A$1:$A$7)))/10

QUOTE:

该公式变化不大,参照上面意见。

——山菊花

下面是LWS2月7日的的短信,没注意到,是我的疏忽。——山菊花

LWS的答案 (20070207)在昨天的基础上增加2种方法,就把他们一起贴出来,以这次答案为准.

如果允许自定义格式,就自定义格式"0000000",用下面的公式

1、{=SUM(LARGE((A2:BR2)*10^(ROUNDUP(71-COLUMN(A2:BR2),-1)/10),ROW($A$1:$A$7)))/10}

2、{=SUM(SUMIF(OFFSET(A2:J2,,(ROW($A$1:$A$7)-1)*10,),">0")*10^(8-ROW($A$1:$A$7)))/10}

不允许自定义格式,就用下面的公式

1、{=TEXT(SUM(LARGE((A2:BR2)*10^(ROUNDUP(71-COLUMN(A2:BR2),-1)/10),ROW(A$1:A$7)))/10,"0000000")}

2、=TEXT(SUM(SUMIF(OFFSET(A2:J2,,(ROW(A$1:A$7)-1)*10,),">0")*10^(8-ROW(A$1:A$7)))/10,"0000000")

3、{=REPT(0,7-LEN(SUM(LARGE((A2:BR2)*10^(ROUNDUP(71-COLUMN(A2:BR2),-1)/10),ROW($A$1:$A$7)))/10))&SUM(LARGE((A2:BR2)*10^(ROUNDUP(71-COLUMN(A2:BR2),-1)/10),ROW($A$1:$A$7)))/10}

4、{=REPT(0,7-LEN(SUM(SUMIF(OFFSET(A2:J2,,(ROW($A$1:$A$7)-1)*10,),">0")*10^(8-ROW($A$1:$A$7)))/10))&SUM(SUMIF(OFFSET(A2:J2,,(ROW($A$1:$A$7)-1)*10,),">0")*10^(8-ROW($A$1:$A$7)))/10}

[此贴子已经被山菊花于2007-2-21 13:38:33编辑过]

TA的精华主题

TA的得分主题

发表于 2007-2-4 16:24 | 显示全部楼层

答案已发送。  答案已发送。                

====

=TEXT(SUM(A2:J2),"0")&TEXT(SUM(K2:T2),"0")&TEXT(SUM(U2:AD2),"0")&TEXT(SUM(AE2:AN2),"0")&TEXT(SUM(AO2:AX2),"0")&TEXT(SUM(AY2:BH2),"0")&TEXT(SUM(BI2:BR2),"0")

QUOTE:

TEXT()多余了,使用了连接符&,结果就是一个文本。

——山菊花

[此贴子已经被山菊花于2007-2-21 11:00:40编辑过]

TA的精华主题

TA的得分主题

发表于 2007-2-4 16:41 | 显示全部楼层

答案已发送到dsjb@21cn.com,请山菊花版主审阅.

====

{=TEXT(SUM(SUBTOTAL(9,OFFSET(A2:J2,,ROW($1:$7)*COLUMNS(A2:BR2)/7-COLUMNS(A2:BR2)/7,))*10^(7-ROW($1:$7))),"0000000")}

{=TEXT(SUM(LOOKUP(SMALL(IF(A2:BR2<>"",COLUMN(A2:BR2)),ROW($1:$7)),COLUMN(A2:BR2),A2:BR2)*10^(7-ROW($1:$7))),"0000000")}

{=TEXT(SUM(RIGHT(SMALL(IF(A2:BR2<>"",COLUMN(A2:BR2)*10^5+A2:BR2),ROW($1:$7)))*10^(7-ROW($1:$7))),"0000000")}

QUOTE:

几个公式都写得很好。

——山菊花

[此贴子已经被山菊花于2007-2-21 11:11:18编辑过]

TA的精华主题

TA的得分主题

发表于 2007-2-4 16:42 | 显示全部楼层
QUOTE:
以下是引用山菊花在2007-2-4 14:32:16的发言:

答案已发送。

(答案发送到dsjb@21cn.com,不要上传到这里。这里只是占个位,等审核后在这里给你评分。)

发送答案时别忘了注明你的ID。


====

=TEXT(SUM(MOD(SMALL(IF(A2:BR2<>"",A2:BR2+COLUMN(A:BR)*100),ROW($1:$7)),100)*10^(7-ROW($1:$7))),"0000000")

[此贴子已经被山菊花于2007-2-21 11:15:34编辑过]

TA的精华主题

TA的得分主题

发表于 2007-2-5 15:08 | 显示全部楼层

答案已发送.

未要求公式长度?

====

=SUM(A2:J2)&SUM(K2:T2)&SUM(U2:AD2)&SUM(AE2:AN2)&SUM(AO2:AX2)&SUM(AY2:BH2)&SUM(BI2:BR2)

QUOTE:

本来出题时附加了一些条件的,但发表题目时,还是把这些约束删去,大过年的,街上猜灯迷几乎所有的人都能拿奖,我们为什么不能?别坏了大家的好兴致,祝大家来年一切顺利。

——山菊花

[此贴子已经被山菊花于2007-2-21 11:22:58编辑过]
您需要登录后才可以回帖 登录 | 免费注册

本版积分规则

关闭

最新热点上一条 /1 下一条

关注官方微信,每天学会一个新技能

手机版|关于我们|联系我们|ExcelHome

GMT+8, 2019-6-17 21:04 , Processed in 0.181065 second(s), 20 queries , Gzip On, MemCache On.

Powered by Discuz! X3.4

© 2001-2017 Wooffice Inc.

   

沪公网安备 31011702000001号 沪ICP备11019229号

本论坛言论纯属发表者个人意见,任何违反国家相关法律的言论,本站将协助国家相关部门追究发言者责任!     本站特聘法律顾问:徐怀玉律师 李志群律师

快速回复 返回顶部 返回列表