用函数公式INDEX下拉录制宏运行经常死机，想用宏解决。

hdysdd

想通过宏按汇总表D列型号快速汇总数据（D列型号为大全，实际数据来源表格的只为其中一部分，且顺序不一定与汇总表相同）。由于数据较多，用函数公式INDEX下拉录制宏经常死机，想通过宏达到快速读取数据，数据来源及效果、附件见下。

opel-wong

典型的，字典，数组，汇总数据，
论坛上有很多这样的实例，搜索一下，很多都可以借鉴的，
代码已写，请测试：

opel-wong

代码如下：

1. Sub 汇总()
   
2.     Dim arr, i As Long, j As Long, mFile As String, wb As Workbook, mStr As String
   
3.     Dim d As Object: Set d = CreateObject("Scripting.Dictionary")
   
4.     mFile = ThisWorkbook.Path & "\\基础信息.xls"
   
5.     Set wb = GetObject(mFile)
   
6.     arr = wb.Worksheets(1).UsedRange.Value
   
7.     wb.Close False
   
8.     For i = 5 To UBound(arr)
   
9.         If Len(arr(i, 4)) Then
   
10.             For j = 5 To UBound(arr, 2)
    
11.                 mStr = arr(i, 4) & arr(4, j)
    
12.                 If Not d.Exists(mStr) Then d(mStr) = arr(i, j)
    
13.             Next
    
14.         End If
    
15.     Next
    
16.     mFile = ThisWorkbook.Path & "\\加改.xls"
    
17.     Set wb = GetObject(mFile)
    
18.     arr = wb.Worksheets(1).UsedRange.Value
    
19.     wb.Close False
    
20.     For i = 5 To UBound(arr)
    
21.         If Len(arr(i, 2)) Then
    
22.             For j = 5 To UBound(arr, 2)
    
23.                 mStr = arr(i, 2) & arr(4, j)
    
24.                 If Not d.Exists(mStr) Then d(mStr) = arr(i, j)
    
25.             Next
    
26.         End If
    
27.     Next
    
28.     With ThisWorkbook.Worksheets("汇总数据")
    
29.         .Activate
    
30.         .Range("E5:T65536").ClearContents
    
31.         arr = .UsedRange.Value
    
32.         For i = 5 To UBound(arr)
    
33.             If Len(arr(i, 4)) Then
    
34.                 For j = 5 To UBound(arr, 2)
    
35.                     mStr = arr(i, 4) & arr(4, j)
    
36.                     If d.Exists(mStr) Then arr(i, j) = d(mStr)
    
37.                 Next
    
38.             End If
    
39.         Next
    
40.         .UsedRange.Value = arr
    
41.     End With
    
42.     Set d = Nothing: Set wb = Nothing
    
43. End Sub
    

复制代码

hdysdd

opel-wong 发表于 2020-3-14 08:13
典型的，字典，数组，汇总数据，
论坛上有很多这样的实例，搜索一下，很多都可以借鉴的，
代码已写，请测 ...

D列型号为大全，实际数据来源表格的只为其中一部分，且顺序不一定与汇总表相同，如何修改（我附件没有考虑周全，没完全说明白，对不起）。

opel-wong

hdysdd 发表于 2020-3-14 08:17
能否把代码放上来让我测试吗？谢谢！

请看3楼，代码上放出，刚才在审核。
路径那里，多了一个反斜杠，请自行去掉。

hdysdd

谢谢opel-wong老师。