很复杂的问题，大神们指教，根据住址直接从

华讯商贸 · 发表于 2020-2-12 16:15

要求：根据常住地快速分出乡镇，右边为各乡镇所包含的村，左边也有村名拼写错误的，可以忽略，不能用筛选，就用公式，数组也可以，比如c4，根据东下素村，乡镇填上北罗镇

solextrade · 发表于 2020-2-12 19:30

试一下
=IFERROR(LOOKUP(1,0/MMULT(COLUMN(A:W),COUNTIF(C2,IF(G$3:Z$25>"","*"&G$3:Z$25&"*",))),G$1:Z$1),"")

丫头的 · 发表于 2020-2-12 19:56

参照罗老师的写一个=LOOKUP(1,MMULT(COLUMN(A$1:V$1),IFERROR(1/((G$3:Z$24<>"")*(COUNTIF(C2,"*"&G$3:Z$24&"*"))),)),G$1:Z$1)

gao05499 · 发表于 2020-2-12 21:03

跟一个=IFERROR(LOOKUP(1,0/MMULT(COLUMN(A:W),COUNTIF(C2,IF(G$3:Z$25>"","*"&G$3:Z$25&"*",))),G$1:Z$1),"")

1055751654 · 发表于 2020-2-12 22:35

gao05499 发表于 2020-2-12 21:03
跟一个=IFERROR(LOOKUP(1,0/MMULT(COLUMN(A:W),COUNTIF(C2,IF(G$3:Z$25>"","*"&G$3:Z$25&"*",))),G$1:Z$1), ...

=INDEX($1:$1,,6+MATCH(1,FREQUENCY(1,MMULT(N(TRANSPOSE(COUNTIF(C2,IF(G$3:Z$25>"","*"&G$3:Z$25&"*",)))),ROW(1:23)^0)),))&""

藍色DE流光 · 发表于 2020-2-12 23:19

本帖最后由藍色DE流光于 2020-2-13 08:33 编辑

常住地既然有乡镇信息，为什么非要用村来匹配呢
=INDEX($1:$1,TEXT(MAX((1-ISERR(0/IF(G$3:Z$24>0,FIND(G$3:Z$24,C2))))*COLUMN(G:Z)),"0;;27"))&""
=IFNA(LOOKUP(99,FIND(G$1:Z$1,C2),G$1:H$1),"")

mmlzh · 发表于 2020-2-13 08:35

凑一个数组
=INDEX($1:$1,MAX(IF(IFERROR(FIND(G$3:Z$24,C2)-1,),COLUMN(G:Z))))&""

华讯商贸 · 发表于 2020-2-16 17:14

都不行啊，是不是我操作错了啊，我把公式直接粘贴A2单元格，下拉，不是0，就是错误

solextrade · 发表于 2020-2-16 17:57

本帖最后由 solextrade 于 2020-2-16 18:01 编辑

数组公式，按3键

华讯商贸 · 发表于 2020-2-28 19:28

本帖最后由华讯商贸于 2020-2-28 19:40 编辑

谢谢各位大神，上次没弄好，后来又把大家的公式都试了试，都挺好用，顶礼膜拜啊，希望大家以后还是多多指教

		自动登录	找回密码
密码			免费注册

[已解决] 很复杂的问题，大神们指教，根据住址直接从

评分

评分

最新热点 /1