如何用vba代替sumifs函数统计呢

wwin80

老师新年好，

这个excel工作文档的销售统计表工作表是用来统计订单数（数据在所有订单报表工作表的p列）和销售额的（数据在所有订单报表工作表的r列）

目前我使用了sumifs函数来进行统计，但是会造成文件体积过大，所以我想请求老师的帮助，变成vba方式

在此工作表中，每一行就是每一天的订单数和销售额（最长365天）

目前我采用了sumifs统计方式，函数解释：如何统计订单数 - 匹配所有订单报表中a列等于当天日期，f列等于shipped，h列等于amazon.fr，m列等于sku的所有p列数据并求和

请问通过vba方式，设置在销售统计表的右键代码区自动执行，怎么做到呢

非常感谢老师在新年期间提供宝贵帮助

祝老师：新年快乐，健康好运

3190496160

Sub tj()
Set d = CreateObject("scripting.dictionary")
With Sheets("销售统计表")
    rs = .Cells(Rows.Count, 1).End(xlUp).Row
    .Range("d2:e" & rs) = Empty
    ar = .Range("a1:e" & rs)
    For i = 2 To UBound(ar)
        If Trim(ar(i, 1)) <> "" And Trim(ar(i, 2)) <> "" And Trim(ar(i, 3)) <> "" Then
            s = Trim(ar(i, 1)) & "|" & Trim(ar(i, 2)) & "|" & Trim(ar(i, 3))
            d(s) = i
        End If
    Next i
    br = Sheets("所有订单报表").[a1].CurrentRegion
    For i = 2 To UBound(br)
        If Trim(br(i, 6)) = "Shipped" Then
            ss = Trim(br(i, 8)) & "|" & Trim(br(i, 13)) & "|" & Trim(br(i, 1))
            m = d(ss)
            If m <> "" Then
                ar(m, 4) = ar(m, 4) + br(i, 16)
                ar(m, 5) = ar(m, 5) + br(i, 18)
            End If
        End If
    Next i
     .Range("a1:e" & rs) = ar
End With
End Sub

3190496160

店长_市场_店铺_动态库存管理表_通用模板.zip (824.79 KB, 下载次数: 14)

2020-2-2 14:24 上传

点击文件名下载附件

wwin80

3190496160 发表于 2020-2-2 14:23
Sub tj()
Set d = CreateObject("scripting.dictionary")
With Sheets("销售统计表")

非常感谢老师在春节期间提供宝贵帮助，感谢力作

zyr2046

1. Sub test()
   
2.     Dim i&, arr, brr, crr, Str, OrderStatus
   
3.     Dim t#
   
4.     t = Timer
   
5.     Application.ScreenUpdating = False
   
6.     Dim d As Object
   
7.     Set d = CreateObject("scripting.dictionary")
   
8.     OrderStatus = Sheet3.Range("G1").Value
   
9.     Sheet3.Range("d2:e65536").ClearContents
   
10.     arr = Sheet3.Range("a2:e" & Sheet3.Cells(Rows.Count, 1).End(xlUp).Row)
    
11.     For i = 1 To UBound(arr)
    
12.         Str = arr(i, 1) & "#" & arr(i, 2) & "#" & arr(i, 3) & "#" & OrderStatus
    
13.         d(Str) = i
    
14.     Next
    
15.     brr = Sheet2.Range("a2:r" & Sheet2.Cells(Rows.Count, 1).End(xlUp).Row)
    
16.     ReDim crr(1 To UBound(brr), 1 To 1)
    
17.     For i = 1 To UBound(brr)
    
18.         crr(i, 1) = Left(brr(i, 4), 10)
    
19.     Next
    
20.     Sheet2.Range("a2").Resize(65536, 1).ClearContents
    
21.     Sheet2.Range("a2").Resize(UBound(brr), 1) = crr
    
22.     For i = 1 To UBound(brr)
    
23.         Str = brr(i, 8) & "#" & brr(i, 13) & "#" & brr(i, 1) & "#" & brr(i, 6)
    
24.         If d.exists(Str) Then
    
25.             m = d(Str)
    
26.             arr(m, 4) = arr(m, 4) + brr(i, 16)
    
27.             arr(m, 5) = arr(m, 5) + brr(i, 18)
    
28.         End If
    
29.     Next
    
30.     Sheet3.Range("a2:e65536").ClearContents
    
31.     Sheet3.Range("a2").Resize(UBound(arr), UBound(arr, 2)) = arr
    
32.    
    
33.     MsgBox "计算完成，耗时" & Format((Timer - t), "0.0") & "秒", 64, "Microsoft Excel"
    
34.     Application.ScreenUpdating = True
    
35. End Sub

复制代码

zyr2046

之前的单元格循环，效率比较低，改成数组之后，效率提升不少，详见附件。

wwin80

zyr2046 发表于 2020-2-2 14:30
之前的单元格循环，效率比较低，改成数组之后，效率提升不少，详见附件。

非常感谢老师在春节期间提供宝贵帮助，感谢力作