数组字典实现sumifs按时间段求和

王正林

请老师看看附件里面的公式如何用字典代替，我想了一下午，做不出来，还是学艺不精，请大神帮忙！不胜感激！

约定的童话

我擦，公式没看懂啥意思

王正林

约定的童话 发表于 2020-1-16 14:46
我擦，公式没看懂啥意思

SUMIFS(B:B,A:A,A2,C:C,">="&C2-35,C:C,"<="&C2-7)对当前日期前四周汇总

Lonzo丶

能不能先详细解释一下函数的意思

王正林

Lonzo丶 发表于 2020-1-16 14:55
能不能先详细解释一下函数的意思

这只是一个普通的sumifs公式阿，以当前日期向前推一个时间段，符合A列条件的，求和区域是B列阿

一把小刀闯天下

'不会公式，特地查了一下这个公式使用帮助，大概明白是怎么回事了。输出到I列，为了比较用，，，

Option Explicit

Sub test()
  Dim arr, i, j, k, p
  arr = [a1].CurrentRegion.Offset(1).Resize(, 5)
  For i = 1 To UBound(arr, 1) - 1
    arr(i, 1) = LCase(arr(i, 1)): arr(i, 4) = 0: arr(i, 5) = i
  Next
  Call qsort(arr, 1, UBound(arr, 1) - 1, 1, UBound(arr, 2), 1)
  For i = 1 To UBound(arr, 1) - 1
    If arr(i, 1) <> arr(i + 1, 1) Then
      For j = p + 1 To i
        For k = p + 1 To i
          If arr(k, 3) >= arr(j, 3) - 35 And arr(k, 3) <= arr(j, 3) - 7 Then arr(j, 4) = arr(j, 4) + arr(k, 2)
        Next
      Next
      p = i
    End If
  Next
  Call qsort(arr, 1, UBound(arr, 1) - 1, 1, UBound(arr, 2), 5)
  [f2].Resize(UBound(arr, 1) - 1, UBound(arr, 2) - 1) = arr
End Sub

Sub qsort(arr, first, last, left, right, key)
  Dim i As Long, j As Long, k As Long, x, t
  i = first: j = last: x = arr((first + last) / 2, key)
  While i <= j
    While arr(i, key) < x: i = i + 1: Wend
    While x < arr(j, key): j = j - 1: Wend
    If i <= j Then
      For k = left To right
        t = arr(i, k): arr(i, k) = arr(j, k): arr(j, k) = t
      Next
      i = i + 1: j = j - 1
    End If
  Wend
  If first < j Then qsort arr, first, j, left, right, key
  If i < last Then qsort arr, i, last, left, right, key
End Sub

王正林

一把小刀闯天下 发表于 2020-1-16 15:17
'不会公式，特地查了一下这个公式使用帮助，大概明白是怎么回事了。输出到I列，为了比较用，，，

Option ...

麻烦您了，老师！

kuangben8

一把小刀闯天下 发表于 2020-1-16 15:17
'不会公式，特地查了一下这个公式使用帮助，大概明白是怎么回事了。输出到I列，为了比较用，，，

Option ...

热心的小刀！