判断一列中=0所在的行，并删除

xs0231221

请大神帮忙，如果判断一列中是0，并删除所在的行，数据比较大，给我个速度比较快的代码

网海遨游

没有附件，猜一下。是不是要这样的？
Sub test() '假如数据0出现在A列
Dim rg As Range
    Application.DisplayAlerts = False: Application.ScreenUpdating = False
    r = Cells(Rows.Count, "a").End(3).Row '(r表示A列有数据的最大行号）
    For i = r To 1 Step -1
        If Cells(i, 1) = 0 Then
            If rg Is Nothing Then
            Set rg = Rows(i)
            Else
            Set rg = Union(rg, Rows(i))
            End If
        End If
    Next i
    rg.Select
    rg.Delete
    Application.DisplayAlerts = True: Application.ScreenUpdating = True
    MsgBox "OK，完成！！！", 48, "温馨提示……"
End Sub

xs0231221

网海遨游 发表于 2020-1-14 15:11
没有附件，猜一下。是不是要这样的？
Sub test() '假如数据0出现在A列
Dim rg As Range

我试试啊，看看

y1983y

看看这个是不是你需要的
Sub Rowdelet()
Dim i As Long, n As Long
    With Sheet1
            iRow = .[a65536].End(xlUp).Row + 1      
        For n = irow To 3 Step -1  '3为0单元格所开始的行数
            If Cells(n, 8) = 0 Then    '8为0单元格所在的列数
                Cells(n, 8).EntireRow.Delete
            End If
        Next           
    End With
End Sub

xs0231221

y1983y 发表于 2020-1-14 15:15
看看这个是不是你需要的
Sub Rowdelet()
Dim i As Long, n As Long

对，要的就是这样

xs0231221

谢谢大神们

tigertc

最快是不要用Range.Delete方法,而改成提取出不等于零的内容.

xs0231221

tigertc 发表于 2020-1-14 19:49
最快是不要用Range.Delete方法,而改成提取出不等于零的内容.

那要如何改呢

一把小刀闯天下

'使用数组可能会快点，，，

Option Explicit

Const COL As Long = 2 '第2列，自己修改

Sub test()
  Dim arr, i As Long, j As Long, m As Long, t As Single
  t = Timer
  With ActiveSheet
    arr = .UsedRange.Value
    For i = 1 To UBound(arr, 1)
      If arr(i, COL) <> 0 Then
        m = m + 1
        For j = 1 To UBound(arr, 2)
          arr(m, j) = arr(i, j)
        Next
      End If
    Next
    Debug.Print Timer - t
    With .[a1] '假设数据是从A1开始的
      .Resize(UBound(arr, 1), UBound(arr, 2)).ClearContents '不能有合并单元格
      If m > 0 Then .Resize(m, UBound(arr, 2)) = arr
    End With
    Debug.Print Timer - t
  End With
End Sub