如何提取重复单元格？

初新者 · 发表于 2020-1-14 14:23

本帖最后由初新者于 2020-1-14 14:45 编辑

一般都是提取非重复单元格，如何提取只重复的单元格

祝洪忠- · 发表于 2020-1-14 14:28

=INDEX(A:A,SMALL(IF((COUNTIF(A$2:A$14,A$2:A$14)>1)*(COUNTIF(B$1:B1,$A$2:$A$14)=0),ROW($2:$14),4^8),ROW(A1)))&""

复制代码

祝洪忠- · 发表于 2020-1-14 14:32

wps中可使用内置功能

sandays · 发表于 2020-1-14 14:32

写了一个比较长的。期待大神给个简单的解法。

dipperrrr · 发表于 2020-1-14 14:32

瞎蒙一个：

=INDEX(A:A,MIN(IF((COUNTIF(A:A,A$2:A$14)>1)*(COUNTIF(B$1:B1,A$2:A$14)=0),ROW($2:$14),4^8)))&""

复制代码

bsgn2017 · 发表于 2020-1-14 14:32

祝洪忠- 发表于 2020-1-14 14:28

如何只提取1次呢

Datous · 发表于 2020-1-14 14:46

都是二次，取巧

=IFERROR(INDEX(A:A,SMALL(MODE.MULT(MATCH(A$2:A$14,A:A,)),ROW(A1))),"")

袁勇 · 发表于 2020-1-14 15:35

非数组：

=LOOKUP(1,0/FREQUENCY(1,(COUNTIF(A:A,A$2:A14)>1)*(COUNTIF(B$1:B1,A$2:A14)=0)),A$2:A14)&""

复制代码

我的城市你来过 · 发表于 2020-1-14 15:44

=IF(COUNTIF($A$1:$A$14,A2)=1,"",MATCH(A2,$A$1:$A$14,0))
=IFERROR(SMALL(C:C,ROW(C1)),"")
=IF(MATCH(D2,$D$1:$D$14,0)=ROW(),D2,"")
=IFERROR(SMALL($E$1:$E$14,ROW(E1)),"")
=IFERROR(INDEX($A$1:$A$14,F2),"")

毛利的乖乖熊 · 发表于 2020-1-14 16:21

=IFERROR(INDEX(A$1:A$14,SMALL(IF(MATCH(A$2:A$14,A$2:A$14,)<>ROW(A$2:A$14)-1,ROW(A$2:A$14),8^8),ROW(A1))),"")
数组公式，下拉

		自动登录	找回密码
密码			免费注册

[已解决] 如何提取重复单元格？