文本数组的排序问题

qhmpv

附件里的内容为文本，我想把他们做成一个数组，但是做成数组后怎么进行排序，看了很多大多是数据的排序。

想根据，班组、用工性质、职务、年龄进行排序，请大神帮忙看看

一把小刀闯天下

'手工排序也用不了几秒。用冒泡按字符排序模拟了一个

Option Explicit

Sub test()
  Dim arr, i, j, k, p, pos, order
  pos = Array(7, 9, 8, 4) '数组中待排序的列
  order = Array(1, 1, 1, 1) '对应的升降控制（1升序）
  arr = [a1].CurrentRegion.Offset(1).Resize(, 9)
  For i = 1 To UBound(arr, 1) - 1 '年龄预处理为字符类型
    arr(i, 4) = Format(arr(i, 4), "000")
  Next
  Call bsort(arr, 1, UBound(arr, 1) - 1, 1, UBound(arr, 2), pos(0), order(0))
  For i = 1 To UBound(pos)
    p = 0
    For j = 1 To UBound(arr, 1) - 1
      For k = 0 To i - 1
        If arr(j, pos(k)) <> arr(j + 1, pos(k)) Then
          If j > p + 1 Then Call bsort(arr, p + 1, j, 1, UBound(arr, 2), pos(i), order(i))
          p = j
        End If
      Next
    Next
  Next
  [u2].Resize(UBound(arr, 1) - 1, UBound(arr, 2)) = arr
End Sub

Function bsort(arr, first, last, left, right, key, order)
  Dim i As Long, j As Long, k As Long, t, flag As Boolean
  For i = first To last - 1
    For j = first To last + first - 1 - i
      If arr(j, key) <> arr(j + 1, key) Then
       If StrComp(arr(j, key), arr(j + 1, key), vbTextCompare) = order Then
          flag = True
          For k = left To right
            t = arr(j, k): arr(j, k) = arr(j + 1, k): arr(j + 1, k) = t
          Next
        End If
      End If
    Next
    If flag = False Then Exit For Else flag = False
  Next
End Function

qhmpv

一把小刀闯天下 发表于 2020-1-12 08:46
'手工排序也用不了几秒。用冒泡按字符排序模拟了一个

Option Explicit

我……我可以拜师么

qhmpv

一把小刀闯天下 发表于 2020-1-12 08:46
'手工排序也用不了几秒。用冒泡按字符排序模拟了一个

Option Explicit

我前面想的办法是，先排序再装入数组，录了个宏，excel的sort是用的addkey，网上的是key1,key2，好像这个key1,key2最多只能有三个关键字。

microyip

http://club.excelhome.net/thread-1443182-1-1.html 二维（以下）数组排序的自定义函数，参考变通一下

qhmpv

microyip 发表于 2020-1-13 09:09
http://club.excelhome.net/thread-1443182-1-1.html 二维（以下）数组排序的自定义函数，参考变通一下

好的，谢谢！！

qhmpv

microyip 发表于 2020-1-13 09:09
http://club.excelhome.net/thread-1443182-1-1.html 二维（以下）数组排序的自定义函数，参考变通一下

这个有注解的看起来容易懂的多了

一把小刀闯天下

qhmpv 发表于 2020-1-13 07:48
我……我可以拜师么

可以啊，我是按分钟计费的

---------------
我也看到过最多支持3个key，没有试过，应该是真的，，，

qhmpv

一把小刀闯天下 发表于 2020-1-13 12:27
可以啊，我是按分钟计费的

---------------

呃！
因为我看那个参数只有key3

micch

我觉得，可以存入数组arr，然后用sort排序，再存入数组brr，然后arr输出原址，还原，就得到排序后的数组了。